tools/mkcaniuse

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4
   5 use Data::Dump 'pp';
   6 use JSON::PP;
   7 use File::stat;
   8 use Time::Piece;
   9 use List::Util 'uniq';
  10
  11 our $VERSION = '1.04';
  12
  13 my %BROWSERJOIN = (
  14         edge    => 'ie',
  15         and_chr => 'android',
  16 );
  17
  18 local $/;  # slurp
  19 my $source = readline;
  20
  21 $JSON::PP::false = 0;
  22 $JSON::PP::true  = 1;
  23
  24 my $data = decode_json($source);
  25 $data->{-date} = Time::Piece->new($_)->datetime
  26         for delete $data->{updated} || ();
  27
  28 delete $data->{eras};
  29 for (values %{ $data->{data} }) {
  30         delete @{$_}{qw[ usage_perc_a usage_perc_y ]};
  31 }
  32 while (my ($browser, $target) = each %BROWSERJOIN) {
  33         my $agent1 = delete $data->{agents}->{$browser} or next;
  34         my $agent2 =        $data->{agents}->{$target}  or next;
  35         push @{ $agent2->{version_list} }, @{ $agent1->{version_list} };
  36         $agent2->{browser} = sprintf '%s (former %s)',
  37                 $agent1->{browser}, $agent2->{browser};
  38
  39         for (values %{ $data->{data} }) {
  40                 my $stats = delete $_->{stats}->{$browser} or next;
  41                 $_ = { %{$_}, %{$stats} } for $_->{stats}->{$target};
  42         }
  43 }
  44
  45 for my $feature (values %{ $data->{data} }) {
  46         while (my ($attr, $row) = each %{$feature}) {
  47                 delete $feature->{$attr} if ref $row eq '' and $row eq '';
  48         }
  49 }
  50
  51 while (my ($agent, $row) = each %{ $data->{agents} }) {
  52         delete $row->{usage_global};
  53         $row->{versions} = [ uniq map { $_->{version} } @{ $row->{version_list} } ];
  54
  55         # convert metadata list into (cleaned) lookup table
  56         my %version_lookup;
  57         for (@{ $row->{version_list} }) {
  58                 delete $_->{era};
  59                 delete $_->{prefix} unless $_->{prefix};
  60                 $version_lookup{ delete $_->{version} } = $_;
  61         }
  62         $row->{version_list} = \%version_lookup;
  63
  64         # omit identical values from subsequent versions
  65         for my $feature (values %{ $data->{data} }) {
  66                 my $cmp;  # same value to be omitted
  67                 my $verstats = $feature->{stats}->{$agent};
  68                 for my $version (@{ $row->{versions} }) {
  69                         defined $verstats->{$version}
  70                                 or warn "missing feature $feature->{title} for $agent $version";
  71                         if (defined $cmp and $verstats->{$version} eq $cmp) {
  72                                 delete $verstats->{$version};
  73                         }
  74                         else {
  75                                 $cmp = $verstats->{$version};
  76                         }
  77                 }
  78         }
  79 }
  80
  81 say "# automatically generated by $0";
  82 print '+', pp($data);
  83
  84 __END__
  85
  86 =head1 NAME
  87
  88 mkcaniuse - Turn Javascript data into an equivalent Perl structure
  89
  90 =head1 SYNOPSIS
  91
  92         tools/mkcaniuse data.json >browser-support.inc.pl
  93