tools/mkcaniuse

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4
   5 use Data::Dump 'pp';
   6 use JSON::PP;
   7 use File::stat;
   8 use Time::Piece;
   9 use List::Util 'uniq';
  10
  11 our $VERSION = '1.04';
  12
  13 my %BROWSERJOIN = (
  14         edge    => 'ie',
  15         and_chr => 'android',
  16 );
  17
  18 local $/;  # slurp
  19 my $source = readline;
  20
  21 $JSON::PP::false = 0;
  22 $JSON::PP::true  = 1;
  23
  24 my $data = decode_json($source);
  25 $data->{-date} = Time::Piece->new($_)->datetime
  26         for delete $data->{updated} || ();
  27
  28 delete $data->{eras};
  29 for (values %{ $data->{data} }) {
  30         delete @{$_}{qw[ usage_perc_a usage_perc_y ]};
  31 }
  32 while (my ($browser, $alias) = each %BROWSERJOIN) {
  33         my $agent =        $data->{agents}->{$browser} or next;
  34         my $amend = delete $data->{agents}->{$alias}   or next;
  35         unless ($agent->{prefix} eq $amend->{prefix}) {
  36                 $_->{prefix} ||= $amend->{prefix} for @{ $amend->{version_list} };
  37         }
  38         unshift @{ $agent->{version_list} }, @{ $amend->{version_list} };
  39         $agent->{browser} = sprintf '%s (former %s)',
  40                 $agent->{browser}, $amend->{browser};
  41
  42         # prefer deprecated name if newer is convoluted (Chr/And.)
  43         $agent->{abbr} = $amend->{abbr} if $agent->{abbr} =~ m{/};
  44
  45         for (values %{ $data->{data} }) {
  46                 my $stats = delete $_->{stats}->{$alias} or next;
  47                 $_ = { %{$_}, %{$stats} } for $_->{stats}->{$browser};
  48         }
  49 }
  50
  51 for my $feature (values %{ $data->{data} }) {
  52         while (my ($attr, $row) = each %{$feature}) {
  53                 delete $feature->{$attr} if ref $row eq '' and $row eq '';
  54         }
  55 }
  56
  57 while (my ($agent, $row) = each %{ $data->{agents} }) {
  58         delete $row->{usage_global};
  59         delete $row->{prefix_exceptions};  # duplicate of version_list->prefix
  60         $row->{versions} = [ uniq map { $_->{version} } @{ $row->{version_list} } ];
  61
  62         # convert metadata list into (cleaned) lookup table
  63         my %version_lookup;
  64         for (@{ $row->{version_list} }) {
  65                 delete $_->{era};
  66                 delete $_->{prefix} unless $_->{prefix};
  67                 $version_lookup{ delete $_->{version} } = $_;
  68         }
  69         $row->{version_list} = \%version_lookup;
  70
  71         # omit identical values from subsequent versions
  72         for my $feature (values %{ $data->{data} }) {
  73                 my $cmp;  # same value to be omitted
  74                 my $verstats = $feature->{stats}->{$agent};
  75                 for my $version (@{ $row->{versions} }) {
  76                         defined $verstats->{$version}
  77                                 or warn "missing feature $feature->{title} for $agent $version";
  78                         if (defined $cmp and $verstats->{$version} eq $cmp) {
  79                                 delete $verstats->{$version};
  80                         }
  81                         else {
  82                                 $cmp = $verstats->{$version};
  83                         }
  84                 }
  85         }
  86 }
  87
  88 say "# automatically generated by $0";
  89 print '+', pp($data);
  90
  91 __END__
  92
  93 =head1 NAME
  94
  95 mkcaniuse - Turn Javascript data into an equivalent Perl structure
  96
  97 =head1 SYNOPSIS
  98
  99         tools/mkcaniuse data.json >browser-support.inc.pl
 100