tools/mksitemap

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4
   5 our $VERSION = '1.02';
   6
   7 use File::stat;
   8 use Time::Piece;
   9
  10 my @pages = (
  11         [qw( index )],
  12         [qw( vi digraphs charset browser writing sc/lotv termcol dieren )],
  13         [qw( readline latin unicode countries emoji perl keyboard/altgr )],
  14         [qw(
  15                 vimperator mutt nethack mplayer/mpv font codec
  16                 keyboard/altgr/windows keyboard/altgr/macos
  17                 dieren/uitgebreid dieren/beknopt
  18         )],
  19         [qw(
  20                 apl less screen digits sc/bw sc/hots termcol/legacy mplayer
  21                 keyboard/altgr/macos-abc keyboard/altgr/msx keyboard/altgr/ukext
  22         )],
  23         [qw( chars/table/html sample source plan )],
  24 );
  25
  26 my %freq = (
  27         (map { $_ => 'yearly' } qw[ readline nethack mplayer apl ]),
  28         (map { $_ => 'weekly' } qw[ browser ]),
  29 );
  30
  31 my %known = map { s{/.*}{}r => 1 } map { @{$_} } @pages;
  32 $known{$_} or warn "page $_ undeclared\n"
  33         for grep { !/\./ } map { s/\.plp\z//r } glob '*.plp';
  34
  35 say '<?xml version="1.0" encoding="UTF-8"?>';
  36 say '<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9">';
  37 for my $group (@pages) {
  38         state $prio = 1;
  39         for my $file (@{$group}) {
  40                 (my $page = $file) =~ s/\Aindex\z//;
  41                 $file =~ s{/.*}{};
  42                 $file .= '.plp';
  43                 my $stat = stat $file or do {
  44                         warn "missing file $file\n";
  45                         next;
  46                 };
  47
  48                 print '<url>';
  49                 print "<loc>http://sheet.shiar.nl/$page</loc>";
  50                 printf '<changefreq>%s</changefreq>', $freq{$page} // 'monthly';
  51                 printf '<priority>%.2f</priority>', $prio;
  52                 printf '<lastmod>%s</lastmod>', localtime($stat->mtime)->date;
  53                 say '</url>';
  54         }
  55         $prio -= .1;
  56 }
  57 say '</urlset>';
  58