tools/mksitemap

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4
   5 our $VERSION = '1.04';
   6
   7 use File::stat;
   8 use Time::Piece;
   9
  10 my @pages = (
  11         [qw( index )],
  12         [qw( vi digraphs charset browser writing sc/lotv termcol dieren )],
  13         [qw( readline latin unicode countries emoji perl keyboard/altgr )],
  14         [qw(
  15                 vimperator mutt nethack mplayer/mpv font codec
  16                 keyboard/altgr/windows keyboard/altgr/macos
  17                 dieren/uitgebreid dieren/beknopt
  18         )],
  19         [qw(
  20                 apl less screen digits sc/bw sc/hots termcol/legacy mplayer
  21                 digraphs/xorg
  22                 keyboard/altgr/macos-abc keyboard/altgr/msx keyboard/altgr/ukext
  23                 keyboard/altgr/eurkey keyboard/altgr/apl keyboard/altgr/spacecadet
  24                 keyboard/altgr/ipa keyboard/altgr/boyeg keyboard/altgr/drix
  25                 keyboard/altgr/symbolics keyboard/altgr/msx-graph
  26         )],
  27         [qw( chars/table/html sample source plan )],
  28 );
  29
  30 my %freq = (
  31         (map { $_ => 'yearly' } qw[ readline nethack mplayer apl ]),
  32         (map { $_ => 'weekly' } qw[ browser ]),
  33 );
  34
  35 my %known = map { s{/.*}{}r => 1 } map { @{$_} } @pages;
  36 $known{$_} or warn "page $_ undeclared\n"
  37         for grep { !/\./ } map { s/\.plp\z//r } glob '*.plp';
  38
  39 say '<?xml version="1.0" encoding="UTF-8"?>';
  40 say '<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9">';
  41 for my $group (@pages) {
  42         state $prio = 1;
  43         for my $file (@{$group}) {
  44                 (my $page = $file) =~ s/\Aindex\z//;
  45                 if (-e "$file.eng.inc.pl") {
  46                         $file .= '.eng.inc.pl';
  47                 }
  48                 else {
  49                         $file =~ s{/.*}{};
  50                         $file .= '.plp';
  51                 }
  52                 my $stat = stat $file or do {
  53                         warn "missing file $file\n";
  54                         next;
  55                 };
  56
  57                 print '<url>';
  58                 print "<loc>https://sheet.shiar.nl/$page</loc>";
  59                 printf '<changefreq>%s</changefreq>', $freq{$page} // 'monthly';
  60                 printf '<priority>%.2f</priority>', $prio;
  61                 printf '<lastmod>%s</lastmod>', localtime($stat->mtime)->date;
  62                 say '</url>';
  63         }
  64         $prio -= .1;
  65 }
  66 say '</urlset>';
  67