tools/mkcaniuse

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4
   5 use Data::Dump 'pp';
   6 use JSON::PP;
   7 use File::stat;
   8 use Time::Piece;
   9 use List::Util 'uniq';
  10
  11 our $VERSION = '1.04';
  12
  13 my %BROWSERJOIN = (
  14         edge    => 'ie',
  15         and_chr => 'android',
  16 );
  17
  18 local $/;  # slurp
  19 my $source = readline;
  20
  21 $JSON::PP::false = 0;
  22 $JSON::PP::true  = 1;
  23
  24 my $data = decode_json($source);
  25 $data->{-date} = Time::Piece->new($_)->datetime
  26         for delete $data->{updated} || ();
  27
  28 delete $data->{eras};
  29 for (values %{ $data->{data} }) {
  30         delete @{$_}{qw[ usage_perc_a usage_perc_y ]};
  31 }
  32 for (values %{ $data->{agents} }) {
  33         delete $_->{usage_global};
  34         for (@{ $_->{version_list} }) {
  35                 delete $_->{era};
  36                 delete $_->{prefix} unless $_->{prefix};
  37         }
  38 }
  39
  40 while (my ($browser, $target) = each %BROWSERJOIN) {
  41         my $agent1 = delete $data->{agents}->{$browser} or next;
  42         my $agent2 =        $data->{agents}->{$target}  or next;
  43         push @{ $agent2->{version_list} }, @{ $agent1->{version_list} };
  44         $agent2->{browser} = sprintf '%s (former %s)',
  45                 $agent1->{browser}, $agent2->{browser};
  46
  47         for (values %{ $data->{data} }) {
  48                 my $stats = delete $_->{stats}->{$browser} or next;
  49                 $_ = { %{$_}, %{$stats} } for $_->{stats}->{$target};
  50         }
  51 }
  52
  53 for my $feature (values %{ $data->{data} }) {
  54         while (my ($attr, $row) = each %{$feature}) {
  55                 delete $feature->{$attr} if ref $row eq '' and $row eq '';
  56         }
  57 }
  58
  59 while (my ($agent, $row) = each %{ $data->{agents} }) {
  60         $row->{versions} = [ uniq map { $_->{version} } @{ $row->{version_list} } ];
  61
  62         # omit identical values from subsequent versions
  63         for my $feature (values %{ $data->{data} }) {
  64                 my $cmp;  # same value to be omitted
  65                 my $verstats = $feature->{stats}->{$agent};
  66                 for my $version (@{ $row->{versions} }) {
  67                         defined $verstats->{$version}
  68                                 or warn "missing feature $feature->{title} for $agent $version";
  69                         if (defined $cmp and $verstats->{$version} eq $cmp) {
  70                                 delete $verstats->{$version};
  71                         }
  72                         else {
  73                                 $cmp = $verstats->{$version};
  74                         }
  75                 }
  76         }
  77 }
  78
  79 say "# automatically generated by $0";
  80 print '+', pp($data);
  81
  82 __END__
  83
  84 =head1 NAME
  85
  86 mkcaniuse - Turn Javascript data into an equivalent Perl structure
  87
  88 =head1 SYNOPSIS
  89
  90         tools/mkcaniuse data.json >browser-support.inc.pl
  91