#!/usr/bin/env perl
use 5.014;
use warnings;

use Data::Dump 'pp';
use JSON::PP;
use File::stat;
use Time::Piece;
use List::Util 'uniq';

our $VERSION = '1.04';

my %BROWSERJOIN = (
	edge    => 'ie',
	and_chr => 'android',
);

local $/;  # slurp
my $source = readline;

$JSON::PP::false = 0;
$JSON::PP::true  = 1;

my $data = decode_json($source);
$data->{-date} = Time::Piece->new($_)->datetime
	for delete $data->{updated} || ();

delete $data->{eras};
for (values %{ $data->{data} }) {
	delete @{$_}{qw[ usage_perc_a usage_perc_y ]};
}
while (my ($browser, $alias) = each %BROWSERJOIN) {
	my $agent =        $data->{agents}->{$browser} or next;
	my $amend = delete $data->{agents}->{$alias}   or next;
	unless ($agent->{prefix} eq $amend->{prefix}) {
		$_->{prefix} ||= $amend->{prefix} for @{ $amend->{version_list} };
	}
	unshift @{ $agent->{version_list} }, @{ $amend->{version_list} };
	$agent->{browser} = sprintf '%s (former %s)',
		$agent->{browser}, $amend->{browser};

	# prefer deprecated name if newer is convoluted (Chr/And.)
	$agent->{abbr} = $amend->{abbr} if $agent->{abbr} =~ m{/};

	for (values %{ $data->{data} }) {
		my $stats = delete $_->{stats}->{$alias} or next;
		$_ = { %{$_}, %{$stats} } for $_->{stats}->{$browser};
	}
}

for my $feature (values %{ $data->{data} }) {
	while (my ($attr, $row) = each %{$feature}) {
		delete $feature->{$attr} if ref $row eq '' and $row eq '';
	}
}

while (my ($agent, $row) = each %{ $data->{agents} }) {
	delete $row->{usage_global};
	delete $row->{prefix_exceptions};  # duplicate of version_list->prefix
	$row->{versions} = [ uniq map { $_->{version} } @{ $row->{version_list} } ];

	# convert metadata list into (cleaned) lookup table
	my %version_lookup;
	for (@{ $row->{version_list} }) {
		delete $_->{era};
		delete $_->{prefix} unless $_->{prefix};
		$version_lookup{ delete $_->{version} } = $_;
	}
	$row->{version_list} = \%version_lookup;

	# omit identical values from subsequent versions
	for my $feature (values %{ $data->{data} }) {
		my $cmp;  # same value to be omitted
		my $verstats = $feature->{stats}->{$agent};
		for my $version (@{ $row->{versions} }) {
			defined $verstats->{$version}
				or warn "missing feature $feature->{title} for $agent $version";
			if (defined $cmp and $verstats->{$version} eq $cmp) {
				delete $verstats->{$version};
			}
			else {
				$cmp = $verstats->{$version};
			}
		}
	}
}

say "# automatically generated by $0";
print '+', pp($data);

__END__

=head1 NAME

mkcaniuse - Turn Javascript data into an equivalent Perl structure

=head1 SYNOPSIS

	tools/mkcaniuse data.json >browser-support.inc.pl