Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6 no  warnings 'uninitialized';  # save some useless checks for more legible code
   7 use Carp;
   8
   9 our $VERSION = '2.07';
  10
  11 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  12 my @rowdesc = qw(numeric top home bottom);
  13 my %keyrows = do 'keys.inc.pl';
  14 # add first two cases of each row again with each char prepended by + (alt)
  15 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  16
  17 my %keytrans = qw(
  18         ^@ NUL ^a SOH ^b STX ^c ETX  ^d EOT ^e ENQ ^f ACK ^g BEL
  19         ^h BS  ^i tab ^j LF  ^k VT   ^l FF  ^m CR  ^n SO  ^o SI
  20         ^p DLE ^q DC1 ^r DC2 ^s DC3  ^t DC4 ^u NAK ^v SYN ^w ETB
  21         ^x CAN ^y EM  ^z SUB ^[ ESC  ^\ FS  ^] GS  ^^ RS  ^_ US
  22         ^? DEL
  23 );
  24
  25 sub new {
  26         my $class = shift;
  27         my ($self) = @_;
  28
  29         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  30         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  31         $self->{map} ||= 'qwerty';
  32
  33         $self->{sign} ||= do {
  34                 require Shiar_Sheet::KeySigns;
  35                 Shiar_Sheet::KeySigns->VERSION(1.04);
  36                 \%Shiar_Sheet::KeySigns::sign;
  37         };
  38
  39         $self->{showkeys} = $PLP::Script::showkeys;
  40         $self->{style   } = $PLP::Script::style;
  41
  42         bless $self, $class;
  43 }
  44
  45 sub map {
  46         my $self = shift;
  47         my ($mapname) = @_;
  48
  49         return $self->{map} = $mapname if defined $keyrows{$mapname};
  50         return undef;
  51 }
  52
  53 sub escapeclass {
  54         local $_ = shift;
  55         s/\^/_c/g;
  56         s/\+/_m/g;
  57         s/\[/_sbo/g;
  58         s/\]/_sbc/g;
  59         s/^$/_/;
  60         return $_;
  61 }
  62
  63 sub escapehtml {
  64         local $_ = shift;
  65         s/</&lt;/g;
  66         s/>/&gt;/g;
  67         s/  / &nbsp;/g;
  68         return $_;
  69 }
  70
  71 sub escapedesc {
  72         my $self = shift;
  73         local $_ = shift;
  74         s{ (< ([^>]*) >) }{ $self->{sign}->{$2} // $1 }xeg;
  75         return $_;
  76 }
  77
  78 sub keyunalias {
  79         my $self = shift;
  80         my ($key, $ancestry) = @_;
  81
  82         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  83         my $mode = $1;
  84         my $keyinfo = $self->{def}->{$mode}->{$key};
  85
  86         return unless defined $keyinfo;
  87         $keyinfo =~ s/^=// or return $keyinfo;
  88         return '' if $ancestry->{$key}++;  # endless loop failsafe
  89         return $self->keyunalias($keyinfo, $ancestry);
  90 }
  91
  92 sub print_key {
  93         my $self = shift;
  94         my ($mode, $key, $flags) = @_;
  95         my ($desc, $mnem);
  96
  97         if (not defined $flags) {
  98                 $flags = $key eq '^0' ? 'ni' : 'no';
  99         }
 100         elsif ($flags =~ s/^=//) { # alias
 101                 $desc = $self->{sign}->{alias};
 102                 $desc .= $flags eq "\e" ? 'esc' : $flags;
 103                 $flags = $self->keyunalias($flags) . ' alias';
 104         }
 105         if (my $txt = $self->{key}->{$mode.$key}) {
 106                 ($desc, $mnem) = split /\n/, $self->escapedesc($txt);
 107         }
 108
 109 #       $key = $keytrans{$key} if defined $keytrans{$key};
 110         my $keytxt = $key eq "\e" ? 'Esc' : $self->{def}{$mode}{lead} . escapehtml($key) if $key ne '^0';
 111            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 112            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 113            $keytxt =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 114            $keytxt =~ s{\+(?=.)}{<small>+</small>};  # meta
 115         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 116            $keytxt  = "<b$keyhint>$keytxt</b>";
 117            $keytxt .= ' '.$desc if defined $desc;
 118            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 119         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 120                 ' onclick="setmode(%s)"',
 121                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 122         );
 123         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 124
 125         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 126         print "\n";
 127 }
 128
 129 sub print_rows {
 130         my $self = shift;
 131         my ($rowsspec, $defrows) = @_;
 132         $defrows ||= [2, 1, 0];
 133         my %moderows = (
 134                 -DEFAULT => defined $rowsspec && $rowsspec ne '' &&
 135                         split(/\s* ([^=\s]*) = \s*/x, $rowsspec),
 136                 # plus specific mode overrides prefixed by '='
 137         );
 138         my @modes = sort keys %{ $self->{def} };
 139
 140         print '<table id="rows" class="keys">'."\n\n";
 141
 142         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 143                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 144
 145                 printf qq{<tbody class="row row%d">\n}, $row+1;
 146                 for my $basemode (@modes) {
 147                         my @moderows = split /\s+/,
 148                                 $row < 0 ? '1' : # top row (esc key) always unshifted
 149                                 $moderows{$basemode} // $moderows{-DEFAULT};
 150
 151                 for my $submode (@moderows ? @moderows : '') {
 152                         my $mode = $basemode . $submode;
 153                         my @caserows = $mode =~ s/(\d+)(?:-(\d+))?$//
 154                                 ? (map {$_ - 1} split //, $row == 0 && $2 || $1)  # user override
 155                                 : @$defrows;  # default
 156                         my $modekeys = $self->{def}{$mode};
 157
 158                         for my $case (@caserows) {
 159                                 my $keycase = $keyrow->[$case] or next;
 160                                   @$keycase or next;
 161                                 my @caseclass;
 162                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 163                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 164                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 165
 166                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 167                                         ' class="%s"', join ' ', @caseclass
 168                                 );
 169                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 170                                                 $self->escapedesc($self->{mode}->{$mode} || "mode $basemode"),
 171                                                 "$rowdesc[$row] row $casedesc[$case]"
 172                                 ) unless $row < 0;
 173                                 print "\n";
 174                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 175                                 print qq{\t\t</tr>\n};
 176                         } # case
 177
 178                 } # submode
 179
 180                 } # basemode
 181                 print qq{\t</tbody>\n};
 182         } # row
 183
 184         print "</table>\n";
 185 }
 186
 187 sub print_legend {
 188         my $self = shift;
 189         my ($class, $flags) = @_;
 190
 191         say qq{\t\t<dl class="legend $class">};
 192         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s'."\n",
 193                 $_, map { $self->escapedesc($_) } @{ $self->{flag}->{$_} || ["($_)", '...'] }
 194         ) for @$flags;
 195         say "\t\t</dl>";
 196 }
 197
 198 sub print_legends {
 199         my $self = shift;
 200         my ($input) = @_;
 201
 202         say "<hr/>\n";
 203         say '<div class="help">';
 204
 205         say "\t", '<div class="left">';
 206         my @groups = sort grep {/^g\d/} keys %{ $self->{flag} };
 207         $self->print_legend('legend-types', \@groups);
 208         say "\t</div>\n";
 209
 210         say "\t", '<div class="right">';
 211         my @attr = sort grep {!/^g\d/} keys %{ $self->{flag} };
 212         $self->print_legend('legend-options', \@attr);
 213         say '';
 214
 215         say "\t\t", '<ul class="legend legend-set">';
 216
 217         say "\t\t<li>keyboard <strong>map</strong> is ",
 218                 ($input->{map} ? 'set to ' : ''), "<em>$self->{map}</em>";
 219         say "\t\t<li><strong>keys</strong> are ",
 220                 "<em>", ($self->{showkeys} ? 'always shown' : 'hidden if unassigned'), "</em>",
 221                 (!defined $self->{showkeys} && ' by default');
 222         say "\t\t<li>default <strong>style</strong> is ",
 223                 (defined $input->{style} && 'set to '), "<em>$self->{style}</em>";
 224
 225         say "\t\t</ul>";
 226         say "\t</div>\n";
 227         say "</div>\n";
 228 }
 229
 230 1;
 231
 232 =head1 NAME
 233
 234 Shiar_Sheet::Keyboard - Output HTML for key sheets
 235
 236 =head1 SYNOPSIS
 237
 238         our %sign = (alias => 'see: ');
 239
 240         my $keys = Shiar_Sheet::Keyboard({
 241                 def => {
 242                         'lead' => {
 243                                 'A' => '=a', # alias
 244                                 'a' => 'classes',
 245                         },
 246                 },
 247                 key => {
 248                         'leada' => ['description', 'comments (on hover)'],
 249                 },
 250                 mode => {
 251                         'lead' => 'mode description',
 252                 },
 253         });
 254         $keys->map('dvorak') or die "Keyboard map not found";
 255
 256         $keys->print_rows;
 257
 258 =head1 DESCRIPTION
 259
 260 Used by http://sheet.shiar.nl to display keyboard sheets.
 261 Assumes specific stylesheets and javascript from this site,
 262 so probably not of much use elsewhere.
 263
 264 =head1 AUTHOR
 265
 266 Mischa POSLAWSKY <perl@shiar.nl>
 267
 268 =head1 LICENSE
 269
 270 Licensed under the GNU Affero General Public License version 3.
 271