Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6 no  warnings 'uninitialized';  # save some useless checks for more legible code
   7 use Carp;
   8
   9 our $VERSION = '2.10';
  10
  11 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  12 my @rowdesc = qw(numeric top home bottom);
  13 my %keyrows = do 'keys.inc.pl';
  14 # add first two cases of each row again with each char prepended by + (alt)
  15 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  16
  17 my %keytrans = (
  18         '^h' => "\x{232B}", # BS
  19         '^i' => "\x{21E5}", # TAB
  20         '^m' => "\x{21B5}", # CR
  21         '^?' => "\x{2326}", # DEL
  22         '^[' => "\x{238B}", # ESC
  23 );
  24
  25 sub new {
  26         my $class = shift;
  27         my ($self) = @_;
  28
  29         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  30         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  31         $self->{map} ||= 'qwerty';
  32
  33         $self->{sign} ||= do {
  34                 require Shiar_Sheet::KeySigns;
  35                 Shiar_Sheet::KeySigns->VERSION(1.04);
  36                 \%Shiar_Sheet::KeySigns::sign;
  37         };
  38
  39         $self->{showkeys} = $PLP::Script::showkeys;
  40         $self->{style   } = $PLP::Script::style;
  41
  42         bless $self, $class;
  43 }
  44
  45 sub map {
  46         my $self = shift;
  47         my ($mapname) = @_;
  48
  49         return $self->{map} = $mapname if defined $keyrows{$mapname};
  50         return undef;
  51 }
  52
  53 sub escapeclass {
  54         local $_ = shift;
  55         s/\^/_c/g;
  56         s/\+/_m/g;
  57         s/\[/_sbo/g;
  58         s/\]/_sbc/g;
  59         s/\\/_b/g;
  60         s/^$/_/;
  61         return $_;
  62 }
  63
  64 sub escapehtml {
  65         local $_ = shift;
  66         s/</&lt;/g;
  67         s/>/&gt;/g;
  68         s/  / &nbsp;/g;
  69         return $_;
  70 }
  71
  72 sub escapedesc {
  73         my $self = shift;
  74         local $_ = shift;
  75         s{ (< ([^>]*) >) }{ $self->{sign}->{$2} // $1 }xeg;
  76         return $_;
  77 }
  78
  79 sub keyunalias {
  80         my $self = shift;
  81         my ($key, $ancestry) = @_;
  82
  83         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  84         my $mode = $1;
  85         my $keyinfo = $self->{def}->{$mode}->{$key};
  86
  87         return unless defined $keyinfo;
  88         $keyinfo =~ s/^=// or return $keyinfo;
  89         return '' if $ancestry->{$key}++;  # endless loop failsafe
  90         return $self->keyunalias($keyinfo, $ancestry);
  91 }
  92
  93 sub print_letter {
  94         my $self = shift;
  95         my ($key, $mode) = @_;
  96
  97         return if $key eq '^0';
  98         return 'Esc' if $key eq "\e";
  99         return $keytrans{$key} if defined $keytrans{$key};
 100         my $html = $self->{def}{$mode}{lead} . escapehtml($key);
 101            $html =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 102            $html =~ s{\+(?=.)}{<small>+</small>};  # meta
 103         return $html;
 104 }
 105
 106 sub print_key {
 107         my $self = shift;
 108         my ($mode, $key, $flags) = @_;
 109         my ($desc, $mnem);
 110
 111         if (not defined $flags) {
 112                 $flags = $key eq '^0' ? 'ni' : 'no';
 113         }
 114         elsif ($flags =~ s/^=(\S+)\s?//) { # alias
 115                 my $ref = $1;
 116                 $desc = $self->{sign}->{alias} . ($ref eq "\e" ? 'esc' : $ref);
 117                 $flags = join ' ', $self->keyunalias($ref), 'alias', $flags;
 118         }
 119         if (my $txt = $self->{key}->{$mode.$key}) {
 120                 ($desc, $mnem) = split /\n/, $self->escapedesc($txt);
 121         }
 122
 123         my $keytxt = $self->print_letter($key, $mode);
 124            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 125            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 126         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 127            $keytxt  = "<b$keyhint>$keytxt</b>";
 128            $keytxt .= ' '.$desc if defined $desc;
 129            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 130         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 131                 ' onclick="setmode(%s)"',
 132                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 133         );
 134         $flags =~ s/\bx\w+/ext/;
 135         $flags =~ s/\bv\d+/new/;
 136         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 137
 138         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 139         print "\n";
 140 }
 141
 142 sub print_rows {
 143         my $self = shift;
 144         my ($rowsspec, $defrows) = @_;
 145         $defrows ||= [2, 1, 0];
 146         my %moderows = (
 147                 -DEFAULT => defined $rowsspec && $rowsspec ne '' &&
 148                         split(/\s* ([^=\s]*) = \s*/x, $rowsspec),
 149                 # plus specific mode overrides prefixed by '='
 150         );
 151         my @modes = sort keys %{ $self->{def} };
 152
 153         printf '<table id="rows" class="%s">'."\n\n", $self->{tableclass} // 'keys';
 154
 155 print_row:
 156         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 157                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 158
 159 #               grep {
 160 #                       defined $self->{def}->{''}->{$_} or defined $self->{def}->{g}->{$_}
 161 #               } map { @{$_} } @{$keyrow} or next;
 162
 163                 printf qq{<tbody class="row row%d">\n}, $row+1;
 164                 for my $basemode (@modes) {
 165                         my @moderows = split /\s+/,
 166                                 $row < 0 ? '1' : # top row (esc key) always unshifted
 167                                 $moderows{$basemode} // $moderows{-DEFAULT};
 168
 169                 for my $submode (@moderows ? @moderows : '') {
 170                         my $mode = $basemode . $submode;
 171                         my @caserows = $mode =~ s/(\d+)(?:-(\d*))?$//
 172                                 ? (map {$_ - 1} split //, $row == 0 ? $2 // $1 : $1)  # user override
 173                                 : @$defrows;  # default
 174                         my $modekeys = $self->{def}{$mode};
 175
 176                         for my $case (@caserows) {
 177                                 my $keycase = $keyrow->[$case] or next;
 178                                   @$keycase or next;
 179                                 my @caseclass;
 180                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 181                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 182                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 183
 184                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 185                                         ' class="%s"', join ' ', @caseclass
 186                                 );
 187                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 188                                                 $self->escapedesc($self->{mode}->{$mode} || "mode $basemode"),
 189                                                 "$rowdesc[$row] row $casedesc[$case]"
 190                                 ) unless $row < 0;
 191                                 print "\n";
 192                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 193                                 print qq{\t\t</tr>\n};
 194                         } # case
 195
 196                 } # submode
 197
 198                 } # basemode
 199                 print qq{\t</tbody>\n};
 200         } # row
 201
 202         print "</table>\n";
 203 }
 204
 205 sub print_legend {
 206         my $self = shift;
 207         my ($class, $flags) = @_;
 208
 209         say qq{\t\t<dl class="legend $class">};
 210         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s</dd>'."\n",
 211                 $_, map { $self->escapedesc($_) } @{ $self->{flag}->{$_} || ["($_)", '...'] }
 212         ) for @$flags;
 213         say "\t\t</dl>";
 214 }
 215
 216 1;
 217
 218 =head1 NAME
 219
 220 Shiar_Sheet::Keyboard - Output HTML for key sheets
 221
 222 =head1 SYNOPSIS
 223
 224         our %sign = (alias => 'see: ');
 225
 226         my $keys = Shiar_Sheet::Keyboard({
 227                 def => {
 228                         'lead' => {
 229                                 'A' => '=a', # alias
 230                                 'a' => 'classes',
 231                         },
 232                 },
 233                 key => {
 234                         'leada' => ['description', 'comments (on hover)'],
 235                 },
 236                 mode => {
 237                         'lead' => 'mode description',
 238                 },
 239         });
 240         $keys->map('dvorak') or die "Keyboard map not found";
 241
 242         $keys->print_rows;
 243
 244 =head1 DESCRIPTION
 245
 246 Used by https://sheet.shiar.nl to display keyboard sheets.
 247 Assumes specific stylesheets and javascript from this site,
 248 so probably not of much use elsewhere.
 249
 250 =head1 AUTHOR
 251
 252 Mischa POSLAWSKY <perl@shiar.nl>
 253
 254 =head1 LICENSE
 255
 256 Licensed under the GNU Affero General Public License version 3.
 257