Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6 no  warnings 'uninitialized';  # save some useless checks for more legible code
   7 use Carp;
   8
   9 our $VERSION = '2.09';
  10
  11 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  12 my @rowdesc = qw(numeric top home bottom);
  13 my %keyrows = do 'keys.inc.pl';
  14 # add first two cases of each row again with each char prepended by + (alt)
  15 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  16
  17 my %keytrans = (
  18         '^h' => "\x{232B}", # BS
  19         '^i' => "\x{21E5}", # TAB
  20         '^m' => "\x{21B5}", # CR
  21         '^?' => "\x{2326}", # DEL
  22         '^[' => "\x{238B}", # ESC
  23 );
  24
  25 sub new {
  26         my $class = shift;
  27         my ($self) = @_;
  28
  29         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  30         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  31         $self->{map} ||= 'qwerty';
  32
  33         $self->{sign} ||= do {
  34                 require Shiar_Sheet::KeySigns;
  35                 Shiar_Sheet::KeySigns->VERSION(1.04);
  36                 \%Shiar_Sheet::KeySigns::sign;
  37         };
  38
  39         $self->{showkeys} = $PLP::Script::showkeys;
  40         $self->{style   } = $PLP::Script::style;
  41
  42         bless $self, $class;
  43 }
  44
  45 sub map {
  46         my $self = shift;
  47         my ($mapname) = @_;
  48
  49         return $self->{map} = $mapname if defined $keyrows{$mapname};
  50         return undef;
  51 }
  52
  53 sub escapeclass {
  54         local $_ = shift;
  55         s/\^/_c/g;
  56         s/\+/_m/g;
  57         s/\[/_sbo/g;
  58         s/\]/_sbc/g;
  59         s/^$/_/;
  60         return $_;
  61 }
  62
  63 sub escapehtml {
  64         local $_ = shift;
  65         s/</&lt;/g;
  66         s/>/&gt;/g;
  67         s/  / &nbsp;/g;
  68         return $_;
  69 }
  70
  71 sub escapedesc {
  72         my $self = shift;
  73         local $_ = shift;
  74         s{ (< ([^>]*) >) }{ $self->{sign}->{$2} // $1 }xeg;
  75         return $_;
  76 }
  77
  78 sub keyunalias {
  79         my $self = shift;
  80         my ($key, $ancestry) = @_;
  81
  82         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  83         my $mode = $1;
  84         my $keyinfo = $self->{def}->{$mode}->{$key};
  85
  86         return unless defined $keyinfo;
  87         $keyinfo =~ s/^=// or return $keyinfo;
  88         return '' if $ancestry->{$key}++;  # endless loop failsafe
  89         return $self->keyunalias($keyinfo, $ancestry);
  90 }
  91
  92 sub print_letter {
  93         my $self = shift;
  94         my ($key, $mode) = @_;
  95
  96         return if $key eq '^0';
  97         return 'Esc' if $key eq "\e";
  98         return $keytrans{$key} if defined $keytrans{$key};
  99         my $html = $self->{def}{$mode}{lead} . escapehtml($key);
 100            $html =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 101            $html =~ s{\+(?=.)}{<small>+</small>};  # meta
 102         return $html;
 103 }
 104
 105 sub print_key {
 106         my $self = shift;
 107         my ($mode, $key, $flags) = @_;
 108         my ($desc, $mnem);
 109
 110         if (not defined $flags) {
 111                 $flags = $key eq '^0' ? 'ni' : 'no';
 112         }
 113         elsif ($flags =~ s/^=(\S+)\s?//) { # alias
 114                 my $ref = $1;
 115                 $desc = $self->{sign}->{alias} . ($ref eq "\e" ? 'esc' : $ref);
 116                 $flags = join ' ', $self->keyunalias($ref), 'alias', $flags;
 117         }
 118         if (my $txt = $self->{key}->{$mode.$key}) {
 119                 ($desc, $mnem) = split /\n/, $self->escapedesc($txt);
 120         }
 121
 122         my $keytxt = $self->print_letter($key, $mode);
 123            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 124            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 125         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 126            $keytxt  = "<b$keyhint>$keytxt</b>";
 127            $keytxt .= ' '.$desc if defined $desc;
 128            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 129         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 130                 ' onclick="setmode(%s)"',
 131                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 132         );
 133         $flags =~ s/\bx\w+/ext/;
 134         $flags =~ s/\bv\d+/new/;
 135         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 136
 137         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 138         print "\n";
 139 }
 140
 141 sub print_rows {
 142         my $self = shift;
 143         my ($rowsspec, $defrows) = @_;
 144         $defrows ||= [2, 1, 0];
 145         my %moderows = (
 146                 -DEFAULT => defined $rowsspec && $rowsspec ne '' &&
 147                         split(/\s* ([^=\s]*) = \s*/x, $rowsspec),
 148                 # plus specific mode overrides prefixed by '='
 149         );
 150         my @modes = sort keys %{ $self->{def} };
 151
 152         print '<table id="rows" class="keys">'."\n\n";
 153
 154 print_row:
 155         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 156                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 157
 158 #               grep {
 159 #                       defined $self->{def}->{''}->{$_} or defined $self->{def}->{g}->{$_}
 160 #               } map { @{$_} } @{$keyrow} or next;
 161
 162                 printf qq{<tbody class="row row%d">\n}, $row+1;
 163                 for my $basemode (@modes) {
 164                         my @moderows = split /\s+/,
 165                                 $row < 0 ? '1' : # top row (esc key) always unshifted
 166                                 $moderows{$basemode} // $moderows{-DEFAULT};
 167
 168                 for my $submode (@moderows ? @moderows : '') {
 169                         my $mode = $basemode . $submode;
 170                         my @caserows = $mode =~ s/(\d+)(?:-(\d*))?$//
 171                                 ? (map {$_ - 1} split //, $row == 0 ? $2 // $1 : $1)  # user override
 172                                 : @$defrows;  # default
 173                         my $modekeys = $self->{def}{$mode};
 174
 175                         for my $case (@caserows) {
 176                                 my $keycase = $keyrow->[$case] or next;
 177                                   @$keycase or next;
 178                                 my @caseclass;
 179                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 180                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 181                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 182
 183                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 184                                         ' class="%s"', join ' ', @caseclass
 185                                 );
 186                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 187                                                 $self->escapedesc($self->{mode}->{$mode} || "mode $basemode"),
 188                                                 "$rowdesc[$row] row $casedesc[$case]"
 189                                 ) unless $row < 0;
 190                                 print "\n";
 191                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 192                                 print qq{\t\t</tr>\n};
 193                         } # case
 194
 195                 } # submode
 196
 197                 } # basemode
 198                 print qq{\t</tbody>\n};
 199         } # row
 200
 201         print "</table>\n";
 202 }
 203
 204 sub print_legend {
 205         my $self = shift;
 206         my ($class, $flags) = @_;
 207
 208         say qq{\t\t<dl class="legend $class">};
 209         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s</dd>'."\n",
 210                 $_, map { $self->escapedesc($_) } @{ $self->{flag}->{$_} || ["($_)", '...'] }
 211         ) for @$flags;
 212         say "\t\t</dl>";
 213 }
 214
 215 1;
 216
 217 =head1 NAME
 218
 219 Shiar_Sheet::Keyboard - Output HTML for key sheets
 220
 221 =head1 SYNOPSIS
 222
 223         our %sign = (alias => 'see: ');
 224
 225         my $keys = Shiar_Sheet::Keyboard({
 226                 def => {
 227                         'lead' => {
 228                                 'A' => '=a', # alias
 229                                 'a' => 'classes',
 230                         },
 231                 },
 232                 key => {
 233                         'leada' => ['description', 'comments (on hover)'],
 234                 },
 235                 mode => {
 236                         'lead' => 'mode description',
 237                 },
 238         });
 239         $keys->map('dvorak') or die "Keyboard map not found";
 240
 241         $keys->print_rows;
 242
 243 =head1 DESCRIPTION
 244
 245 Used by http://sheet.shiar.nl to display keyboard sheets.
 246 Assumes specific stylesheets and javascript from this site,
 247 so probably not of much use elsewhere.
 248
 249 =head1 AUTHOR
 250
 251 Mischa POSLAWSKY <perl@shiar.nl>
 252
 253 =head1 LICENSE
 254
 255 Licensed under the GNU Affero General Public License version 3.
 256