tools/mkcaniuse

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4
   5 use Data::Dump 'pp';
   6 use JSON::PP;
   7 use File::stat;
   8 use Time::Piece;
   9
  10 our $VERSION = '1.03';
  11
  12 my %BROWSERJOIN = (
  13         edge    => 'ie',
  14         and_chr => 'android',
  15 );
  16
  17 local $/;  # slurp
  18 my $source = readline;
  19
  20 $JSON::PP::false = 0;
  21 $JSON::PP::true  = 1;
  22
  23 my $data = decode_json($source);
  24 $data->{-date} = Time::Piece->new($_)->datetime
  25         for delete $data->{updated} || ();
  26
  27 delete $data->{eras};
  28 for (values %{ $data->{data} }) {
  29         delete @{$_}{qw[ usage_perc_a usage_perc_y ]};
  30 }
  31 for (values %{ $data->{agents} }) {
  32         delete $_->{usage_global};
  33 }
  34
  35 while (my ($browser, $target) = each %BROWSERJOIN) {
  36         my $agent1 = delete $data->{agents}->{$browser} or next;
  37         my $agent2 =        $data->{agents}->{$target}  or next;
  38         push @{ $agent2->{version_list} }, @{ $agent1->{version_list} };
  39         $agent2->{browser} = sprintf '%s (former %s)',
  40                 $agent1->{browser}, $agent2->{browser};
  41
  42         for (values %{ $data->{data} }) {
  43                 my $stats = delete $_->{stats}->{$browser} or next;
  44                 $_ = { %{$_}, %{$stats} } for $_->{stats}->{$target};
  45         }
  46 }
  47
  48 for my $feature (values %{ $data->{data} }) {
  49         while (my ($attr, $row) = each %{$feature}) {
  50                 delete $feature->{$attr} if ref $row eq '' and $row eq '';
  51         }
  52 }
  53
  54 say "# automatically generated by $0";
  55 print '+', pp($data);
  56
  57 __END__
  58
  59 =head1 NAME
  60
  61 mkcaniuse - Turn Javascript data into an equivalent Perl structure
  62
  63 =head1 SYNOPSIS
  64
  65         tools/mkcaniuse data.json >browser-support.inc.pl
  66