Shiar's Git - sc2-widget/blob - getsc2clan

   1 #!/usr/bin/env perl
   2 use 5.024;
   3 use warnings;
   4 use utf8;
   5
   6 use Data::Dump qw( pp );
   7 use LWP::Authen::OAuth2;
   8 use JSON qw( decode_json );
   9 use List::MoreUtils qw( all part sort_by nsort_by );
  10
  11 if (@ARGV and all { m[/] } @ARGV) {
  12         say pp blizget($_) for @ARGV;
  13         exit;
  14 }
  15
  16 my ($profiles, $clanmatches) = part { /\D/ } @ARGV;  # separate numbers
  17 $profiles && @{$profiles}
  18         or die "Usage: $0 <profile id>... [<clan name>...]\n";
  19 my ($clanmatch) = map { $_ && qr/\A(?:$_)\z/i } join '|', @{$clanmatches || []};
  20
  21 sub blizget {
  22         state $bliz = do {
  23                 my @authdata = do './.blizzard.passwd.pl' and not $@ || $!
  24                         or die "No auth setup: ", $@ || $!, "\n";
  25                 my %auth = @authdata;
  26                 my $bliz = LWP::Authen::OAuth2->new(%auth,
  27                         token_endpoint          => 'https://eu.battle.net/oauth/token',
  28                         request_required_params => [qw( client_id client_secret grant_type )],
  29                 );
  30                 $bliz->request_tokens(grant_type => 'client_credentials');
  31                 $bliz;
  32         };
  33
  34         my $args = join('/', @_);
  35         my $res = $bliz->get("https://eu.api.blizzard.com/sc2/$args");
  36         $res->is_success or die $res->status_line;
  37         my $json = $res->decoded_content;
  38         return decode_json($json);
  39 }
  40
  41 # prefer deprecated interface to prevent costly ladder search
  42 my @ladderdata = map {
  43         blizget(legacy => profile => 2 => 1 => $_ => 'ladders')
  44 } @{$profiles};
  45
  46 # merge relevant ladder data of all users
  47 my %ladders;
  48 for my $season (qw[ currentSeason previousSeason ]) {
  49         for my $row (map { $_->{$season}->@* } @ladderdata) {
  50                 $row->{ladder}->[0]->{division} or next;
  51                 $row->{season} = $season;
  52                 $ladders{ $row->{ladder}->[0]->{ladderId} } //= $row;
  53         }
  54 }
  55
  56 my @ladders = (
  57         sort_by { $_->{season} } # season
  58         nsort_by {
  59                 -($_->{ladder}->[0]->{wins} + $_->{ladder}->[0]->{losses})
  60         } # activity desc
  61         nsort_by { $_->{ladder}->[0]->{ladderId} } # stable order
  62         grep {
  63                 !$clanmatch or
  64                 all { $_->{clanName} =~ $clanmatch } $_->{characters}->@*
  65         } # members
  66         values %ladders
  67 ) or die "No matching groups found\n";
  68
  69 my (@members, %memberidx);
  70 $memberidx{ $_->{id} } //= push(@members, $_) && $#members
  71         for map { $_->{characters}->@* } @ladders;
  72
  73 say JSON->new->canonical->pretty->encode({
  74         name     => $members[0]->{clanName},
  75         tag      => $members[0]->{clanTag},
  76         ladders  => [map {{
  77                 league   => lc $_->{ladder}->[0]->{league},
  78                 division => $_->{ladder}->[0]->{ladderName},
  79                 rank     => $_->{ladder}->[0]->{rank},
  80                 members  => [map { $memberidx{$_->{id}} } $_->{characters}->@*],
  81                 wins     => $_->{ladder}->[0]->{wins},
  82                 losses   => $_->{ladder}->[0]->{losses},
  83                 (season  => -1) x ($_->{season} eq 'previousSeason'),
  84         }} @ladders],
  85         members  => [map {
  86                 blizget(metadata => profile => 2 => 1 => $_->{id})
  87                 # lacks mmr, fav race (available in new api)
  88         } @members],
  89 }) =~ s/(?: \G \d,? | \[ ) \K \s+ (?=\d|\])/ /grx; # concat arrays of single digits