parse-wormedit

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use 5.010;
   5
   6 use Data::Dumper;
   7 use Getopt::Long 2.33 qw(HelpMessage :config bundling);
   8
   9 our $VERSION = '1.03';
  10
  11 GetOptions(\my %opt,
  12         'raw|r',  # full output
  13         'version=i',  # force version
  14 ) or HelpMessage(-exitval => 2);
  15
  16
  17 package Shiar_Parse::WormEdit;
  18
  19 use strict;
  20 use warnings;
  21
  22 our %MAGICID = (
  23         "WormEdit053\000LVL" => 53,
  24         "WormEdit\34195\000LVL" => 95,
  25         "WormEdit\34194\000LVL" => 94,
  26         "WormEdit\34193\000LVL" => 93,
  27 );
  28
  29 my @FORMAT = (
  30         magic       => 'a15',
  31         version     => 'C',
  32         name        => 'Ca32',
  33         description => 'Ca64x256',
  34         levelcount  => [1,
  35                 single => 'C',
  36                 multi  => 'C',
  37                 race   => 'C',
  38                 ctf    => 'C',
  39                 total  => 'C',
  40         ],
  41         moderef     => [1,
  42                 map { (start => $_, end => $_) } [1,
  43                         single     => 'C',
  44                         peaworm    => 'C',
  45                         tron       => 'C',
  46                         deathmatch => 'C',
  47                         foodmatch  => 'C',
  48                         multifood  => 'C',
  49                         timematch  => 'C',
  50                         race       => 'C',
  51                         ctf        => 'Cx',
  52                 ],
  53         ],
  54         sprite     => ['8C',
  55                 line => 'B8',
  56         ],
  57         finish      => [1,
  58                 type    => 's',
  59                 message => 'Ca255',
  60                 code    => 'Ca255x256',
  61         ],
  62         hiname      => 'a3',
  63         levels      => ['*', # levelcount->total actually
  64                 id         => 'Ca22',
  65                 name       => 'Ca22',
  66                 size       => 'C',
  67                 peas       => 'C',
  68                 delay      => 'C',
  69                 growth     => 'C',
  70                 bsize      => 'C',
  71                 sprite     => ['8C',
  72                         line => 'B8',
  73                 ],
  74                 balls      => ['32C',
  75                         y   => 'C',
  76                         x   => 'C',
  77                         dir => 'C',
  78                 ],
  79                 worms      => [4,
  80                         d => 'C',
  81                         y => 'C',
  82                         x => 'C',
  83                 ],
  84                 width      => 'C',
  85                 height     => 'C',
  86                 flags      => [2,
  87                         y => 'C',
  88                         x => 'C',
  89                 ],
  90                 objects    => ['128C',
  91                         type => 'C',
  92                         x1   => 'C',
  93                         y1   => 'C',
  94                         x2   => 'C',
  95                         y2   => 'C',
  96                 ],
  97         ],
  98 );
  99
 100 sub read {
 101         my ($self, $input) = @_;
 102         my ($id, $version) = (substr($input, 0, 15), ord substr($input, 15, 1));
 103         my $fileversion = $MAGICID{$id}
 104                 or die "File does not match any known WormEdit level header\n";
 105
 106         if ($opt{version}) {
 107                 warn "Override version $version to $opt{version}\n";
 108                 $version = $opt{version};
 109         }
 110         elsif ($version != $fileversion) {
 111                 warn "Unexpected version $version (expecting $fileversion)\n";
 112         }
 113         elsif ($version == 95) {
 114                 # auto-detect exact variant
 115                 if (ord substr($input, 70, 1) ~~ [1 .. 8]) {
 116                         # valid sprite length instead of description byte
 117                         # (which is usually a letter or nul)
 118                         $version = 94;
 119                 }
 120                 elsif (ord substr($input, 147, 1) == 0) {
 121                         # nul of finish type is 2 bytes later (unlike first char of message)
 122                         $version = 96;
 123                 }
 124                 warn "Ambiguous file version 95; guessing subversion $version\n";
 125         };
 126
 127         $fileversion += 100 if $fileversion < 90;  # 93..95 came before 50..53
 128         given ($fileversion) {
 129                 when (153) { } # current @FORMAT
 130                         $FORMAT[7] = 'Ca64'; # no reserved space after description
 131                         $FORMAT[15]->[-1] = 'Ca255'; # enddata
 132                         $FORMAT[-1]->[-1]->[0] = '32C'; # less objects
 133                 when ($version == 96) {
 134                         ref $_ and $_->[-1] = 'C' for @{ $FORMAT[11] }; # 9 moderefs
 135                 }
 136                         ref $_ and pop @$_ for @{ $FORMAT[11] }; # only 8 moderefs
 137                         splice @FORMAT, 6, 2 if $version <= 94;  # earlier version without description
 138                 when (95) { }
 139                         splice @{ $FORMAT[7] }, 4, 2;  # no race
 140                         splice @{ $FORMAT[13] }, 4, 2; # no enddata
 141                         splice @{ $FORMAT[-1] }, 1, 2; # no name
 142                 when (94) { }
 143                         splice @FORMAT, 14, 2; # no hiname
 144                         $FORMAT[-1]->[0] = 64; # constant amount of levels
 145                 when (93) { }
 146                 default {
 147                         die "Cannot parse data for Wormedit $fileversion/$version\n";
 148                 }
 149         }
 150
 151         # convert to an easily accessible hash
 152         my @values = unpack Shiar_Parse::Nested->template(\@FORMAT).'a*', $input;
 153         my $data = Shiar_Parse::Nested->convert(\@FORMAT, \@values);
 154         warn "Trailing data left unparsed\n" if grep {length} @values;
 155         $data->{format} = 'WormEdit';
 156         return $data;
 157 }
 158
 159
 160 package Shiar_Parse::WormyLevel;
 161
 162 use strict;
 163 use warnings;
 164
 165 use List::Util qw(sum min max);
 166
 167 sub read {
 168         my ($self, $input) = @_;
 169         my ($psize, $ptype, $size, $type, $vsize, $dsize, $id, $subid) = unpack q{
 170                 x11 x42    # file signature and comment
 171                 S a2 S a2  # file size, type; data size, type
 172                 x8         # var name
 173                 S S        # var size; content size
 174                 CC         # wormy header
 175         }, $input;
 176         $ptype eq "\014\000"
 177                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 178         $size == $psize - 16
 179                 or warn "File size ($size) does not correspond with data size ($psize)\n";
 180         $type eq "\014\010"
 181                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 182         $size == $vsize and $vsize == $dsize+2
 183                 or warn "Mismatch in string data size declarations\n";
 184 #       substr($input, -2) eq $CHECKSUM
 185
 186         $input = substr $input, 73, -2;
 187         $id eq ord 'w'
 188                 or die "Wormy level identifier not found\n";
 189         my @FORMAT = (
 190                 magic       => 'a1',
 191                 version     => 'C',
 192                 name        => 'Z*',
 193                 description => 'Z*',
 194                 levelcount  => [1,
 195                         total  => 'S',
 196                 ],
 197                 moderef     => [1,
 198                         map { (
 199                                 offset => [1, map {$_ => 'S'} @$_], # byte location of start
 200                                 end    => [1, map {$_ => 'C'} @$_],
 201                         ) }
 202                         [qw/single peaworm tron deathmatch foodmatch multifood timematch race ctf/]
 203                 ],
 204                 theanswer => 'C', # 42
 205                 sprite     => ['C',
 206                         line => 'B8',
 207                 ],
 208                 leveldata => 'a*',
 209         );
 210         my @LEVELFORM = (
 211                 peas       => 'C',
 212                 delay      => 'C',
 213                 growth     => 'C',
 214                 bsize      => 'C',
 215                 sprite     => ['C',
 216                         line => 'B8',
 217                 ],
 218                 balls      => ['C',
 219                         y   => 'C',
 220                         x   => 'C',
 221                         dir => 'C',
 222                 ],
 223                 worms      => [1,
 224                         d => 'C',
 225                         y => 'C',
 226                         x => 'C',
 227                 ],
 228                 width      => 'C',
 229                 height     => 'C',
 230                 flags      => [0,
 231                         y => 'C',
 232                         x => 'C',
 233                 ],
 234                 #levels
 235                 #finish code
 236                 #levels-multi
 237                 #hinames
 238         );
 239         my @OBJECTFORM = (
 240                         type => 'C',
 241                         x1   => 'C',
 242                         y1   => 'C',
 243                         x2   => 'C',
 244                         y2   => 'C',
 245         );
 246
 247         given ($subid) {
 248                 when (97) {
 249                         # current @FORMAT
 250                 }
 251                 when (95) {
 252                         ref $_ and splice @$_, -2 for @{ $FORMAT[11] }; # only 8 moderefs
 253                         splice @FORMAT, 12, 2;  # no reserved byte
 254                 }
 255                 default {
 256                         die "Unsupported level version $subid\n";
 257                 }
 258         }
 259
 260         my $data = Shiar_Parse::Nested->unpack(\@FORMAT, $input);
 261         my $offset = 0;
 262         my $offsetbase = 0xF080 + @{ $data->{sprite} } + 1;
 263         $data->{moderef}->{offset}->{single} == $offsetbase
 264                 or warn "First singleplayer level is not in front\n";
 265
 266         my @VARMODES = (
 267                 [qw'single  single'],
 268                 [qw'multi   peaworm tron deathmatch foodmatch multifood timematch'],
 269                 [qw'race    race'],
 270                 [qw'ctf     ctf'],
 271         );
 272
 273         $data->{levels} = [];
 274         for my $modes (@VARMODES) {
 275                 my $variant = shift @$modes;
 276                 $offset = min(map { $data->{moderef}->{offset}->{$_} } @$modes) - $offsetbase;
 277                 my $amount = $variant eq 'single' ? 100 : max(map { $data->{moderef}->{end}->{$_} } @$modes);
 278
 279                 my @varform = @LEVELFORM;
 280                 $varform[13]->[0] = $variant eq 'single' ? 1 : 4;
 281                 unshift @varform, name => 'Z*' unless $variant eq 'single';
 282                 $varform[-1]->[0] = 1 if $variant eq 'race';
 283                 $varform[-1]->[0] = 2 if $variant eq 'ctf';
 284
 285                 while ($offset < length $data->{leveldata}) {
 286                         last if substr($data->{leveldata}, $offset, 1) eq chr(255);
 287
 288                         # find references to this level offset, and set start number to matching modes
 289                         while (my ($mode, $location) = each %{ $data->{moderef}->{offset} }) {
 290                                 $location == $offset + $offsetbase or next;
 291                                 $data->{moderef}->{start}->{$mode} = 1 + scalar @{ $data->{levels} };
 292                         }
 293
 294                         my $level = Shiar_Parse::Nested->unpack(
 295                                 [@varform], substr $data->{leveldata}, $offset
 296                         );
 297                         my $size = 8  # unpack length (ugh, ugly recalculation)
 298                                 + (defined $level->{name} ? 1 + length $level->{name} : 0)
 299                                 + 3 * (ref $level->{worms} eq 'ARRAY' ? scalar @{$level->{worms}} : 1)
 300                                 + 2 * ($level->{flags} ? ref $level->{flags} eq 'ARRAY' ? scalar @{$level->{flags}} : 1 : 0)
 301                                 + ($level->{sprite} ? scalar @{$level->{sprite}} : 0)
 302                                 + ($level->{balls} ? 3 * scalar @{$level->{balls}} : 0);
 303                         $level->{size} = $size;
 304                         $level->{offset} = $offset + $offsetbase;
 305
 306                         # add objects until terminator
 307                         $level->{objects} = [];
 308                         while (my $object = ord substr($data->{leveldata}, $offset+$size, 1)) {
 309                                 push @{ $level->{objects} }, Shiar_Parse::Nested->unpack(
 310                                         [@OBJECTFORM], substr($data->{leveldata}, $offset+$size, 5)
 311                                 );
 312                                 $size += 5;
 313                         }
 314
 315                         # add parsed level and advance
 316                         push @{ $data->{levels} }, $level;
 317                         $offset += ++$size;
 318                         last if ++$data->{levelcount}->{$variant} >= $amount;
 319                 }
 320         }
 321
 322         my $slots = sum(
 323                 $data->{moderef}->{end}->{single} > 0,  # singleplayer slot if any levels
 324                 $data->{moderef}->{end}->{peaworm},     # one for each peaworm arena
 325                 $data->{moderef}->{end}->{tron},        # idem for tron
 326         );
 327         $data->{hinames} = [ unpack '(x2a3)*', substr($data->{leveldata}, -5 * $slots) ];
 328         $data->{finish}->{code} = substr delete($data->{leveldata}), $offset, -5 * $slots; #XXX
 329         $data->{format} = '86s';
 330         return $data;
 331 }
 332
 333
 334 package Shiar_Parse::Nested;
 335
 336 sub template {
 337         my ($self, $format) = @_;
 338         # total (flattened) unpack template from nested format definitions
 339         return join '', map {
 340                 my $value = $format->[-($_ << 1) - 1];
 341                 if (ref $value eq 'ARRAY') {
 342                         my $count = $value->[0];
 343                         $value = $self->template($value);
 344                         $value = $count =~ s/^([*\d]+)// ? "$count($value)$1"
 345                                 : $count."X[$count]$count/($value)";
 346                 }
 347                 else {
 348                         $value =~ s/^C(a)(\d+)/$1 . ($2 + 1)/e;  # length prefix
 349                 }
 350                 $value;
 351         } reverse 0 .. ($#$format - 1) >> 1;
 352 }
 353
 354 sub convert {
 355         my ($self, $format, $data) = @_;
 356         # map flat results into a named and nested hash
 357         my %res;
 358         while (my ($field, $template) = splice @$format, 0, 2) {
 359                 if (ref $template eq 'ARRAY') {
 360                         my ($count, @subformat) = @$template;
 361                         my $max = $count =~ s/^(\d+)// ? $1 : 0;
 362                         $count = !$count ? $max
 363                                 : $count eq '*' ? $res{levelcount}->{total} : shift @$data;
 364                         $res{$field}->[$_] = $self->convert([@subformat], $data) for 0 .. ($max || $count)-1;
 365                         splice @{ $res{$field} }, $count if $max > $count;
 366                         $res{$field} = $res{$field}->[0] if $max == 1;
 367                         next;
 368                 }
 369                 elsif ($template =~ /^Ca/) {
 370                         $data->[0] = CORE::unpack 'C/a', $data->[0];
 371                 }
 372                 $res{$field} = shift @$data;
 373         }
 374         return \%res;
 375 }
 376
 377 sub unpack {
 378         my ($self, $format, $input) = @_;
 379         my @data = CORE::unpack $self->template($format), $input;
 380         return $self->convert($format, \@data);
 381 }
 382
 383
 384 package main;
 385
 386 my @OBJTYPE = ('none', 'line', 'fat line', 'bar', 'circle');
 387 my @ENDTYPE = ('none', 'message', 'small message');
 388
 389 sub objsummary {
 390         my ($objects) = @_;
 391         my @objtypes = map { $_->{type} } @$objects;
 392         my %count;
 393         $count{$_}++ for @objtypes;
 394         return (@objtypes > 1 && keys %count == 1 && 'all ') . join(', ',
 395                 map { $OBJTYPE[$_] ? $OBJTYPE[$_] . ($count{$_} > 1 && 's') : $_ }
 396                 sort keys %count
 397         );
 398 }
 399
 400 # read and parse all input data
 401 my $data;
 402 local $/;
 403 my $rawdata = readline;
 404 if (substr($rawdata, 0, 11) eq "**TI86**\032\012\000") {
 405         # compiled calculator file
 406         $data = Shiar_Parse::WormyLevel->read($rawdata);
 407 }
 408 elsif (substr($rawdata, 0, 8) eq 'WormEdit') {
 409         # original wormedit source
 410         $data = Shiar_Parse::WormEdit->read($rawdata);
 411 }
 412 else {
 413         die "Unrecognised file type\n";
 414 }
 415
 416 # output with user-preferred formatting
 417 if ($opt{raw}) {
 418         # full data in yaml (human-readable) formatting
 419         require YAML;
 420         local $YAML::CompressSeries;
 421               $YAML::CompressSeries = 0;
 422         my $yml = "# Wormy levelset\n" . YAML::Dump($data);
 423
 424         # inline format of short hashes
 425         $yml =~ s{
 426                 ^(\ *) - \n                          # array indicator
 427                 ((?:\1\ \ [a-z0-9]{1,5}:\ *\d+\n)+)  # simple hash declaration
 428                 (?!\1\ )                             # no further children
 429         }[
 430                 my ($indent, $value) = ($1, $2);
 431                 chop $value;
 432                 $value =~ s/^ +//gm;
 433                 $value =~ s/\n/, /g;
 434                 "$indent- {$value}\n";
 435         ]egmx;
 436
 437         print $yml;
 438 }
 439 else {
 440         print $data->{name};
 441         print " ($data->{description})" if defined $data->{description};
 442         print "\n";
 443         printf "File version: %s\n", "$data->{format} v$data->{version}";
 444         printf "Defaults: %s\n", join('; ',
 445                 'sprite ' . scalar @{ $data->{sprite} },
 446                 defined $data->{hiname} ? 'hiscore by ' . $data->{hiname} : (),
 447         );
 448
 449         my $startnr = 0;
 450         for my $variant (qw/single multi race ctf/) {
 451                 my $count = $data->{levelcount}->{$variant};
 452                 print "\n";
 453                 printf '%s (%s)', ucfirst $variant, $count // 'invalid';
 454                 $count or next;
 455                 print ":";
 456                 for (0 .. $count - 1) {
 457                         my $level = $data->{levels}->[$_ + $startnr];
 458                         printf("\n- %-22s%4s:%3s+%2s%3s %3sx%-3s%s",
 459                                 $level->{id} || $level->{name} || '#'.($_+1),
 460                                 @$level{qw/size bsize growth/},
 461                                 $variant eq 'single' && "x$level->{peas}",
 462                                 @$level{qw/width height/},
 463                                 join(';', map {" $_"} grep {$_}
 464                                         @{$level->{objects}} && sprintf('%2d object%s (%s)',
 465                                                 scalar @{$level->{objects}}, @{$level->{objects}} != 1 && 's',
 466                                                 objsummary($level->{objects}),
 467                                         ),
 468                                         $level->{sprite} && @{$level->{sprite}} && sprintf('sprite %d',
 469                                                 scalar @{$level->{sprite}},
 470                                         ),
 471                                         $level->{balls} && @{$level->{balls}} && sprintf('%d bounc%s',
 472                                                 scalar @{$level->{balls}}, @{$level->{balls}} == 1 ? 'y' : 'ies',
 473                                         ),
 474                                 ),
 475                         );
 476                 }
 477                 $startnr += $count;
 478         }
 479         continue {
 480                 print "\n";
 481                 printf("-- %-21s%4s: %s (%s)\n",
 482                         '(ending)',
 483                         defined $data->{finish}->{code}
 484                                 ? length $data->{finish}->{code} : '?',
 485                         defined $data->{finish}->{type}
 486                                 ? $ENDTYPE[$data->{finish}->{type}] || 'unknown' : 'code',
 487                         $data->{finish}->{message} // '?',
 488                 ) if $variant eq 'single';
 489         }
 490 }
 491
 492 __END__
 493
 494 =head1 NAME
 495
 496 parse-wormedit - Wormy level data parser
 497
 498 =head1 SYNOPSIS
 499
 500  parse-wormedit [--raw] <input.lvl>
 501
 502 =head1 DESCRIPTION
 503
 504 Reads Wormy levels (either original WormEdit source or compiled TI-86 string)
 505 from STDIN or given file, and outputs contents, summarised or in full.
 506
 507 =head1 AUTHOR
 508
 509 Mischa POSLAWSKY <wormy@shiar.org>
 510
 511 =head1 LICENSE
 512
 513 GPL version 3.
 514