browser.plp

   1 <(common.inc.plp)><:
   2 use List::Util qw(sum max first);
   3 no if $] >= 5.018, warnings => 'experimental::smartmatch';
   4
   5 Html({
   6         title => 'browser compatibility cheat sheet',
   7         version => '1.5',
   8         description => [
   9                 "Compatibility table of new web features (HTML5, CSS3, SVG, Javascript)",
  10                 "comparing support and usage share for all popular browser versions.",
  11         ],
  12         keywords => [qw'
  13                 web browser support compatibility usage matrix available feature
  14                 html html5 css css3 svg javascript js dom mobile
  15                 ie internet explorer firefox chrome safari webkit opera
  16         '],
  17         stylesheet => [qw'circus dark mono red light'],
  18         data => ['data/browser/support.inc.pl'],
  19 });
  20
  21 say "<h1>Browser compatibility</h1>\n";
  22
  23 my $caniuse = do 'data/browser/support.inc.pl' or die $@ || $!;
  24
  25 my %CSTATS = (
  26         'n'   => 'l1',
  27         'n d' => 'l2',
  28         'n x d' => 'l2 ex',
  29         'p d' => 'l2',
  30         'a d' => 'l2',
  31         'y'   => 'l5',
  32         'y #' => 'l4',
  33         'y x' => 'l5 ex',
  34         'y x #' => 'l4 ex',
  35         'a'   => 'l3',
  36         'a x' => 'l3 ex',
  37         'p'   => 'l2',
  38         'u'   => 'l0',
  39         'u d' => 'l2',
  40 );
  41 my %DSTATS = (
  42         u => 'unknown',
  43         n => 'unsupported',
  44         p => 'plugin required',
  45         a => 'partial',
  46         y => 'supported',
  47         d => '(disabled by default)',
  48         x => sub {
  49                 join(' ',
  50                         'with prefix',
  51                         map {"-$_-"}
  52                         ($caniuse->{agents}->{$_[0]}->{prefix_exceptions} // {})->{$_[1]}
  53                         // $caniuse->{agents}->{$_[0]}->{prefix} // (),
  54                 );
  55         },
  56 );
  57 my %PSTATS = (  # score percentage
  58         y => 1,  'y x' => .9,
  59         a => .5, 'a x' => .5, 'a d' => .2,
  60         p => .2, 'p d' => .1,
  61         n => 0,  'n d' => .2, 'n x d' => .2,
  62         u => 0,
  63 );
  64 my %CSTATUS = (
  65         unoff => 'l1', # unofficial
  66         wd    => 'l2', # draft
  67         cr    => 'l3', # candidate
  68         pr    => 'l3', # proposed
  69         rec   => 'l5', # recommendation
  70         ls    => 'l4', # whatwg
  71         ietf  => 'l0', # standard
  72         other => 'l0', # non-w3
  73 );
  74 my %versions;
  75 while (my ($browser, $row) = each %{ $caniuse->{agents} }) {
  76         $versions{$browser} = [
  77                 sort { paddedver($a) cmp paddedver($b) } grep { defined }
  78                 @{ $row->{versions} }
  79         ];
  80 }
  81
  82 my $ref = showlink('Can I use', 'https://caniuse.com/');
  83 $ref =~ s/(?=>)/ title="updated $_"/
  84         for map { s/[\sT].*//r } $caniuse->{-date} || ();
  85 $ref = "Fyrd's $ref page";
  86 say '<p id="intro">Alternate rendition of '.$ref;
  87
  88 my ($canihas, $usage);
  89 my $minusage = $get{threshold} // 1;
  90 given ($get{usage} // 'wm') {
  91         when (!$_) {
  92                 # none
  93         }
  94         when (!m{ \A [a-z]\w+ (?:/\d[\d-]*\d)? \z }x) {
  95                 Alert([
  96                         'Invalid browser usage data request',
  97                         'Identifier must be alphanumeric name or <q>0</q>.',
  98                 ]);
  99         }
 100         $canihas = do "data/browser/usage-$_.inc.pl" or do {
 101                 Alert('Browser usage data not found', $@ || $!);
 102                 break;
 103         };
 104         $usage = $_;
 105         my $ref = $canihas->{-title} || 'unknown';
 106         $ref = showlink($ref, $_)
 107                 for $canihas->{-site} || $canihas->{-source} || ();
 108         $ref =~ s/(?=>)/ title="updated $_"/ for $canihas->{-date} || ();
 109         print "\nwith $ref browser usage statistics";
 110 }
 111
 112 my @browsers;
 113 if ($usage) { # first() does not work inside given >:(
 114         # adapt version usage to actual support data
 115         my %engineuse;  # prefix => usage sum
 116         for my $browser (keys %versions) {
 117                 my $row = $canihas->{$browser} // {};
 118                 my $verlist = $versions{$browser} or next;
 119                 if ($minusage and sum(values %$row) < $minusage) {
 120                         delete $versions{$browser};
 121                         next;
 122                 }
 123                 my %supported = map { $_ => 1 } @$verlist;
 124
 125                 # cascade unknown versions
 126                 $row->{$_} //= undef for @$verlist;  # ensure stable keys during iteration
 127                 while (my ($version, $usage) = each %$row) {
 128                         next if defined $supported{$version};
 129                         my $next = first { paddedver($_) ge paddedver($version) } @$verlist
 130                                 or warn("No fallback found for $browser v$version; $usage% ignored"), next;
 131                         $row->{$next} += $usage;
 132                         $row->{$version} = 0;  # balance browser total
 133                 }
 134
 135                 # build row list for each version
 136                 if ($minusage) {
 137                         my @vershown;  # $verlist replacement
 138                         my ($rowusage, @verrow) = (0);  # replacement row tracking
 139                         for (@$verlist) {
 140                                 push @verrow, $_;  # queue each version
 141                                 if (($rowusage += $row->{$_}) >= $minusage) {
 142                                         push @vershown, [@verrow];   # add row
 143                                         ($rowusage, @verrow) = (0);  # reset row tracking
 144                                 }
 145                         }
 146                         push @vershown, \@verrow if @verrow;  # always add latest
 147                         @$verlist = @vershown;
 148                 }
 149                 else {
 150                         @$verlist = map { [$_] } @$verlist;
 151                 }
 152
 153                 # reusable aggregates (grouped by prefix (engine) and browser)
 154                 $engineuse{ $caniuse->{agents}->{$browser}->{prefix} } +=
 155                 $row->{-total} = sum(values %$row);
 156         }
 157
 158         # order browser columns by usage grouped by engine
 159         @browsers = sort {
 160                 $engineuse{ $caniuse->{agents}->{$b}->{prefix} } <=>
 161                 $engineuse{ $caniuse->{agents}->{$a}->{prefix} }
 162                         ||
 163                 $canihas->{$b}->{-total} <=> $canihas->{$a}->{-total}
 164         } keys %versions;
 165 }
 166 else {
 167         # order browser columns by name grouped by engine
 168         @{$_} = map { [$_] } @{$_} for values %versions;
 169         @browsers = sort {
 170                 $caniuse->{agents}->{$b}->{prefix} cmp
 171                 $caniuse->{agents}->{$a}->{prefix}
 172                         ||
 173                 $a cmp $b
 174         } keys %versions;
 175 }
 176 :>.
 177 </p>
 178
 179 <:
 180 $canihas ||= {
 181         map {
 182                 $_ => +{
 183                         map {
 184                                 my $zero = $#$_ - 2;  # baseline index
 185                                 ($_->[$zero - 2] =>  .5), # past
 186                                 ($_->[$zero - 1] => 10 ), # previous
 187                                 ($_->[$zero + 2] =>  0 ), # future
 188                                 ($_->[$zero + 1] =>  .5), # next
 189                                 ($_->[$zero    ] => 30 ), # current
 190                         } $caniuse->{agents}->{$_}->{versions}
 191                 }
 192         } @browsers
 193 }; # fallback hash based on release semantics
 194
 195 # score multiplier for percentage of all browser versions
 196 my $usagepct = 99.99 / sum(
 197         map { $_->{-total} // values %{$_} }
 198         map { $canihas->{$_} }
 199         grep { !/^-/ }
 200         keys %{$canihas}
 201 );
 202
 203 $_->{usage} = featurescore($_->{stats}) * $usagepct
 204         for values %{ $caniuse->{data} };
 205
 206 print '<table class="mapped">';
 207 print '<col span="3">';  # should match first thead row
 208 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
 209 say '</colgroup><col>';
 210
 211 my $header = join('',
 212         '<tr>',
 213         '<th colspan="3" rowspan="2">feature',
 214         (map {
 215                 my $name = $caniuse->{agents}->{$_}->{browser};
 216                 sprintf('<th colspan="%d" class="%s" title="%s">%s',
 217                         scalar @{ $versions{$_} },
 218                         join(' ', map {"b-a-$_"} grep {$_}
 219                                 $_, @{ $caniuse->{agents}->{$_} }{'prefix', 'type'},
 220                         ),
 221                         join(' ',
 222                                 sprintf('%.1f%%', $canihas->{$_}->{-total} * $usagepct),
 223                                 $name,
 224                         ),
 225                         do {
 226                                 length $name <= (3 * @{ $versions{$_} }) ? $name
 227                                         : $caniuse->{agents}->{$_}->{abbr};
 228                         },
 229                 )
 230         } @browsers),
 231         '<th rowspan="2">%',
 232 );
 233 print '<thead>', $header;
 234 # preceding row without any colspan to work around gecko bug
 235 print "\n<tr>";
 236 for my $browser (@browsers) {
 237         for my $span (@{ $versions{$browser} }) {
 238                 my $lastver = first {
 239                         $caniuse->{agents}->{$browser}->{version_list}->{$_}->{release_date} # stable
 240                 } reverse @{$span};
 241                 printf('<td title="%s"%s>%s',
 242                         join(' ',
 243                                 sprintf('%.1f%%', sum(@{ $canihas->{$browser} }{ @{$span} }) * $usagepct),
 244                                 'version ' . showversions(@{$span}, undef),
 245                                 (map {
 246                                         $_ ? () : '(development)'
 247                                 } $caniuse->{agents}->{$browser}->{version_list}->{$lastver}->{release_date}),
 248                         ),
 249                         !defined $lastver && ' class="ex"',
 250                         showversions($lastver // $span->[0]),
 251                 );
 252         }
 253 }
 254 say '</thead>';
 255 say '<tfoot>', $header;
 256 {
 257         # prefix indicates browser family; count adjacent families
 258         my (@families, %familycount);
 259         for my $browser (@browsers) {
 260                 my $family = $caniuse->{agents}->{$browser}->{prefix};
 261                 push @families, $family unless $familycount{$family};
 262                 $familycount{$family} += @{ $versions{$browser} };
 263         }
 264
 265         print "\n", '<tr class="cat">';
 266         printf '<th colspan="%d">%s', $familycount{$_}, $_ for @families;
 267 }
 268 say '</tfoot>';
 269
 270 sub featurescore {
 271         # relative amount of support for given feature
 272         my $rank = 0;
 273         if (my $row = shift) {
 274                 if ($canihas) {
 275                         while (my ($browser, $versions) = each %$row) {
 276                                 ref $versions eq 'HASH' or next;
 277                                 my $prev;
 278                                 for my $version (@{ $caniuse->{agents}->{$browser}->{versions} }) {
 279                                         my $status = $versions->{$version} // $prev;
 280                                         $status =~ s/\h\#\d+//g;
 281                                         $rank += ($canihas->{$browser}->{$version} || .001) * $PSTATS{$status};
 282                                         $prev = $status;
 283                                 }
 284                         }
 285                         return $rank;
 286                 }
 287
 288                 while (my ($browser, $vercols) = each %versions) {
 289                         my $div = 0;  # multiplier exponent (decreased to lower value)
 290                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 291                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 292                                 my @future;  # find upcoming releases (after current)
 293                                 for (reverse @$vercols) {
 294                                         last if $_ eq $current;
 295                                         push @future, pop @vers;
 296                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 297                                 }
 298                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 299                         }
 300                         $rank += $PSTATS{$_} * 2**($div--) for reverse @vers;
 301                 }
 302         }
 303         return $rank;
 304 }
 305
 306 sub formatnotes {
 307         my @html = @_;
 308         for (@html) {
 309                 s/\r\n?/\n/g;  # windows returns
 310                 s/\h* $//gmx;  # trailing whitespace
 311                 s/(?<= [^.\n]) $/./gmx;  # consistently end each line by a period
 312                 Entity($_);
 313                 s{  ` ([^`]*)  ` }{<code>$1</code>}gx;
 314                 s{ \[ ([^]]*) \] \( ([^)]*) \) }{<a href="$2">$1</a>}gx;
 315         }
 316         return @html;
 317 }
 318
 319 sub notestotitle {
 320         my @notes = @_;
 321         for (@notes) {
 322                 EscapeHTML($_);
 323                 s{ \[ ([^]]*) \] \( [^)]* \) }{$1}gx;  # strip link urls
 324         }
 325         return @notes;
 326 }
 327
 328 sub saytitlecol {
 329         my ($id) = @_;
 330         my $row = $caniuse->{data}->{$id};
 331
 332         for ($row->{categories}) {
 333                 my $cell = $_ ? lc $_->[0] : '-';
 334                 $cell =~ s/ api$//;  # trim unessential fluff in 'js api'
 335                 printf '<th title="%s">%s', join(' + ', @$_), $cell;
 336         }
 337
 338         print '<td>', map {
 339                 sprintf('<a href="%s" onclick="%s">%s</a>',
 340                         "#$id",
 341                         sprintf("try { %s; return false } catch(err) { return true }",
 342                                 "document.getElementById('$id').classList.toggle('target')",
 343                         ),
 344                         Entity($_),
 345                 );
 346         } $row->{title};
 347         print '<div class=aside>';
 348         print "<p>$_</p>"
 349                 for formatnotes($row->{description}, $row->{notes} || ());
 350         if (my %notes = %{ $row->{notes_by_num} }) {
 351                 say '<p>Browser-specific notes:';
 352                 say "<br>#$_: ", formatnotes($notes{$_}) for sort keys %notes;
 353                 say '</p>';
 354         }
 355         printf 'Resources: %s.', join(', ', map {
 356                 showlink($_->{title}, $_->{url})
 357         } @$_) for grep { @$_ } $row->{links} // ();
 358         printf '<br>Parent feature: %s.', join(', ', map {
 359                 showlink($caniuse->{data}->{$_}->{title}, "#$_")
 360         } $_) for $row->{parent} || ();
 361         print '</div>';
 362 }
 363
 364 sub saystatuscol {
 365         my ($id) = @_;
 366         my $row = $caniuse->{data}->{$id};
 367
 368         for ($row->{status}) {
 369                 my $cell = $_ // '-';
 370                 $cell = showlink($cell, $_) for $row->{spec} // ();
 371                 printf '<td title="%s" class="l %s">%s',
 372                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 373         }
 374 }
 375
 376 sub saybrowsercols {
 377         my ($id, $browser) = @_;
 378         my $feature = $caniuse->{data}->{$id};
 379         my $data = $feature->{stats}->{$browser};
 380         if (ref $data eq 'ARRAY') {
 381                 # special case for unsupported
 382                 $data = {
 383                         map { $_ => 'n' }
 384                         keys %{ $caniuse->{agents}->{$browser}->{version_list} }
 385                 };
 386         }
 387
 388         my ($prev, @span);
 389         for my $ver (@{ $versions{$browser} }, undef) {
 390                 my $compare = (
 391                         !defined $ver ? undef :      # last column if nameless
 392                         ref $data ne 'HASH' ? '' :   # unclassified if no support hash
 393                         (first { defined } @{$data}{ reverse @{$ver} })  # last known version
 394                         // $prev                     # inherit from predecessor
 395                         || 'u'                       # unsure
 396                 );
 397                 if (defined $prev and not $prev ~~ $compare) {
 398                         # different columns
 399                         my @vercover = (map { @{$_} } @span);  # accumulated conforming versions
 400                         for ($ver ? @{$ver} : ()) {
 401                                 last if defined $data->{$_};  # until different
 402                                 push @vercover, $_;  # matches from next span start
 403                         }
 404                         my $usage = sum(@{ $canihas->{$browser} }{@vercover});
 405
 406                         # strip #\d note references from support class
 407                         my @notes;
 408                         push @notes, $feature->{notes_by_num}->{$1}
 409                                 while $prev =~ s/\h \# (\d+) \b//x;
 410
 411                         # prepare version hover details
 412                         my $title = sprintf('%.1f%% %s', $usage * $usagepct, join(' ',
 413                                 (map { ref $_ eq 'CODE' ? $_->($browser, $vercover[0]) : $_ }
 414                                  map { $DSTATS{$_} // () }
 415                                  map { split / /, $_ }
 416                                  $prev
 417                                 ),
 418                                 'in', $caniuse->{agents}->{$browser}->{abbr},
 419                                 showversions(@vercover, undef),
 420                         ));
 421                         $title .= "\n$_" for notestotitle(@notes);
 422
 423                         $prev .= ' #' if @notes and $prev =~ /^y/;
 424                         printf('<td class="%s" colspan="%d" title="%s">%s',
 425                                 join(' ',
 426                                         X => $CSTATS{$prev},
 427                                         !$usage ? ('p0') : ('p',
 428                                                 sprintf('p%01d', $usage * ($usagepct - .0001) / 10),
 429                                                 sprintf('p%02d', $usage * ($usagepct - .0001)),
 430                                         ),
 431                                 ),
 432                                 scalar @span,
 433                                 $title,
 434                                 showversions($span[0]->[0], @span > 1 && defined $ver ? $span[-1]->[-1] : ()),
 435                         );
 436                         undef $prev;
 437                         @span = ();
 438                 }
 439                 if ($ver) {
 440                         my $startversion = first { defined $data->{ $ver->[$_] } }
 441                                 reverse 0 .. $#{$ver};  # compare index
 442                         push @span, [ @{$ver}[ $startversion .. $#{$ver} ] ];
 443                 }
 444                 $prev = $compare;
 445         }
 446 }
 447
 448 sub sayusagecol {
 449         my ($id) = @_;
 450         print '<td>', int $caniuse->{data}->{$id}->{usage};
 451 }
 452
 453 say '<tbody>';
 454 for my $id (sort {
 455         $caniuse->{data}->{$b}->{usage} <=> $caniuse->{data}->{$a}->{usage}
 456 } keys %{ $caniuse->{data} }) {
 457         $caniuse->{data}->{$id}->{stats} or next;  # skip metadata [summary]
 458         printf '<tr id="%s">', $id;
 459         saytitlecol($id);
 460         saystatuscol($id);
 461         saybrowsercols($id, $_) for @browsers;
 462         sayusagecol($id);
 463         say '</tr>';
 464 }
 465 say '</tbody>';
 466 say '</table>';
 467
 468 sub paddedver {
 469         # normalised version number comparable as string (cmp)
 470         $_[0] =~ m/(?:.*-|^)(\d*)(.*)/;
 471         # matched (major)(.minor) of last value in range (a-B)
 472         return sprintf('%02d', length $1 ? $1 : 99) . $2;
 473 }
 474
 475 sub showversions {
 476         # title to describe minumum version and optional maximum for multiple cells
 477         my @span = (map { split /-/ } grep { defined } @_);
 478         return $span[0] =~ s/\.0\z//r if @_ <= 1;
 479         splice @span, 1, -1;
 480         return join('‒', @span);
 481 }
 482
 483 :>
 484 <hr>
 485
 486 <div class="legend">
 487         <table class="glyphs"><tr>
 488         <td class="X l5">supported
 489         <td class="X l4">annotated
 490         <td class="X l3">partial
 491         <td class="X l2">optional
 492         <td class="X l1">missing
 493         <td class="X l0">unknown
 494         <td class="X ex">prefixed
 495         </table>
 496
 497         <p><: if ($usage) { :>
 498                 Usage percentage:
 499                 <span class="  p0">0</span> -
 500                 <span class="p p0 p00">.01</span> -
 501                 <span class="p p0 p05">1-9</span> -
 502                 <span class="p p1">10</span> -
 503                 <span class="p p2">20</span> -
 504                 <span class="p p5">majority</span>
 505 <: } else { :>
 506                 <table class="glyphs"><tr>
 507                         <td class="p p1">previous version</td>
 508                         <td class="p p3">current</td>
 509                         <td class="p p0 p00">upcoming (within months)</td>
 510                         <td class="  p0">future (within a year)</td>
 511                 </table>
 512 <: } :> </p>
 513
 514         <div class="right">
 515                 <ul class="legend legend-set">
 516                 <li>default <strong>style</strong> is
 517                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 518                 <li><strong>usage</strong> source is
 519                         <:= !defined $get{usage} && 'default ' :><:= defined $usage ? "<em>$usage</em>" : 'not included (<em>0</em>)' :>
 520                 <li>usage <strong>threshold</strong> is
 521                         <:= defined $get{threshold} && 'changed to ' :><em><:= $minusage :>%</em>
 522                 </ul>
 523         </div>
 524 </div>
 525
 526 <script type="text/javascript" src="/searchlocal.js"></script>
 527 <script type="text/javascript"><!--
 528         prependsearch(document.getElementById('intro'));
 529 //--></script>
 530