browser.plp

   1 <(common.inc.plp)><:
   2 use List::Util qw(sum max first);
   3 no if $] >= 5.018, warnings => 'experimental::smartmatch';
   4
   5 Html({
   6         title => 'browser compatibility cheat sheet',
   7         version => '1.5',
   8         description => [
   9                 "Compatibility table of new web features (HTML5, CSS3, SVG, Javascript)",
  10                 "comparing support and usage share for all popular browser versions.",
  11         ],
  12         keywords => [qw'
  13                 web browser support compatibility usage matrix available feature
  14                 html html5 css css3 svg javascript js dom mobile
  15                 ie internet explorer firefox chrome safari webkit opera
  16         '],
  17         stylesheet => [qw'circus dark mono red light'],
  18         data => ['data/browser/support.inc.pl'],
  19 });
  20
  21 say "<h1>Browser compatibility</h1>\n";
  22
  23 my $caniuse = do 'data/browser/support.inc.pl' or die $@ || $!;
  24 $_->{verrelease} = {
  25         # mark last three (future) versions as unreleased, ensure current isn't
  26         map {
  27                 $_->[-1] => 0, $_->[-2] => 0, $_->[-3] => 0,
  28                 $_->[-4] => undef,
  29         } $_->{versions}
  30 } for values %{ $caniuse->{agents} };
  31
  32 my %CSTATS = (
  33         'n'   => 'l1',
  34         'n d' => 'l2',
  35         'n x d' => 'l2 ex',
  36         'p d' => 'l2',
  37         'a d' => 'l2',
  38         'y'   => 'l5',
  39         'y #' => 'l4',
  40         'y x' => 'l5 ex',
  41         'y x #' => 'l4 ex',
  42         'a'   => 'l3',
  43         'a x' => 'l3 ex',
  44         'p'   => 'l2',
  45         'u'   => 'l0',
  46         'u d' => 'l2',
  47 );
  48 my %DSTATS = (
  49         u => 'unknown',
  50         n => 'unsupported',
  51         p => 'plugin required',
  52         a => 'partial',
  53         y => 'supported',
  54         d => '(disabled by default)',
  55         x => sub {
  56                 join(' ',
  57                         'with prefix',
  58                         map {"-$_-"}
  59                         ($caniuse->{agents}->{$_[0]}->{prefix_exceptions} // {})->{$_[1]}
  60                         // $caniuse->{agents}->{$_[0]}->{prefix} // (),
  61                 );
  62         },
  63 );
  64 my %PSTATS = (  # score percentage
  65         y => 1,  'y x' => .9,
  66         a => .5, 'a x' => .5, 'a d' => .2,
  67         p => .2, 'p d' => .1,
  68         n => 0,  'n d' => .2, 'n x d' => .2,
  69         u => 0,
  70 );
  71 my %CSTATUS = (
  72         unoff => 'l1', # unofficial
  73         wd    => 'l2', # draft
  74         cr    => 'l3', # candidate
  75         pr    => 'l3', # proposed
  76         rec   => 'l5', # recommendation
  77         ls    => 'l4', # whatwg
  78         ietf  => 'l0', # standard
  79         other => 'l0', # non-w3
  80 );
  81 my %versions;
  82 while (my ($browser, $row) = each %{ $caniuse->{agents} }) {
  83         $versions{$browser} = [
  84                 sort { paddedver($a) cmp paddedver($b) } grep { defined }
  85                 @{ $row->{versions} }
  86         ];
  87 }
  88
  89 my $ref = showlink('Can I use', 'https://caniuse.com/');
  90 $ref =~ s/(?=>)/ title="updated $_"/
  91         for map { s/[\sT].*//r } $caniuse->{-date} || ();
  92 $ref = "Fyrd's $ref page";
  93 say '<p id="intro">Alternate rendition of '.$ref;
  94
  95 my ($canihas, $usage);
  96 my $minusage = $get{threshold} // 1;
  97 given ($get{usage} // 'wm') {
  98         when (!$_) {
  99                 # none
 100         }
 101         when (!m{ \A [a-z]\w+ (?:/\d[\d-]*\d)? \z }x) {
 102                 Alert([
 103                         'Invalid browser usage data request',
 104                         'Identifier must be alphanumeric name or <q>0</q>.',
 105                 ]);
 106         }
 107         $canihas = do "data/browser/usage-$_.inc.pl" or do {
 108                 Alert('Browser usage data not found', $@ || $!);
 109                 break;
 110         };
 111         $usage = $_;
 112         my $ref = $canihas->{-title} || 'unknown';
 113         $ref = showlink($ref, $_)
 114                 for $canihas->{-site} || $canihas->{-source} || ();
 115         $ref =~ s/(?=>)/ title="updated $_"/ for $canihas->{-date} || ();
 116         print "\nwith $ref browser usage statistics";
 117 }
 118
 119 my @browsers;
 120 if ($usage) { # first() does not work inside given >:(
 121         # adapt version usage to actual support data
 122         my %engineuse;  # prefix => usage sum
 123         for my $browser (keys %versions) {
 124                 my $row = $canihas->{$browser} // {};
 125                 my $verlist = $versions{$browser} or next;
 126                 if ($minusage and sum(values %$row) < $minusage) {
 127                         delete $versions{$browser};
 128                         next;
 129                 }
 130                 my %supported = map { $_ => 1 } @$verlist;
 131
 132                 # cascade unknown versions
 133                 $row->{$_} //= undef for @$verlist;  # ensure stable keys during iteration
 134                 while (my ($version, $usage) = each %$row) {
 135                         next if defined $supported{$version};
 136                         my $next = first { paddedver($_) ge paddedver($version) } @$verlist
 137                                 or warn("No fallback found for $browser v$version; $usage% ignored"), next;
 138                         $row->{$next} += $usage;
 139                         $row->{$version} = 0;  # balance browser total
 140                 }
 141
 142                 # build row list for each version
 143                 if ($minusage) {
 144                         my @vershown;  # $verlist replacement
 145                         my ($rowusage, @verrow) = (0);  # replacement row tracking
 146                         for (@$verlist) {
 147                                 push @verrow, $_;  # queue each version
 148                                 if (($rowusage += $row->{$_}) >= $minusage) {
 149                                         push @vershown, [@verrow];   # add row
 150                                         ($rowusage, @verrow) = (0);  # reset row tracking
 151                                 }
 152                         }
 153                         push @vershown, \@verrow if @verrow;  # always add latest
 154                         @$verlist = @vershown;
 155                 }
 156                 else {
 157                         @$verlist = map { [$_] } @$verlist;
 158                 }
 159
 160                 # reusable aggregates (grouped by prefix (engine) and browser)
 161                 $engineuse{ $caniuse->{agents}->{$browser}->{prefix} } +=
 162                 $row->{-total} = sum(values %$row);
 163         }
 164
 165         # order browser columns by usage grouped by engine
 166         @browsers = sort {
 167                 $engineuse{ $caniuse->{agents}->{$b}->{prefix} } <=>
 168                 $engineuse{ $caniuse->{agents}->{$a}->{prefix} }
 169                         ||
 170                 $canihas->{$b}->{-total} <=> $canihas->{$a}->{-total}
 171         } keys %versions;
 172 }
 173 else {
 174         # order browser columns by name grouped by engine
 175         @{$_} = map { [$_] } @{$_} for values %versions;
 176         @browsers = sort {
 177                 $caniuse->{agents}->{$b}->{prefix} cmp
 178                 $caniuse->{agents}->{$a}->{prefix}
 179                         ||
 180                 $a cmp $b
 181         } keys %versions;
 182 }
 183 :>.
 184 </p>
 185
 186 <:
 187 $canihas ||= {
 188         map {
 189                 $_ => +{
 190                         map {
 191                                 my $zero = $#$_ - 2;  # baseline index
 192                                 ($_->[$zero - 2] =>  .5), # past
 193                                 ($_->[$zero - 1] => 10 ), # previous
 194                                 ($_->[$zero + 2] =>  0 ), # future
 195                                 ($_->[$zero + 1] =>  .5), # next
 196                                 ($_->[$zero    ] => 30 ), # current
 197                         } $caniuse->{agents}->{$_}->{versions}
 198                 }
 199         } @browsers
 200 }; # fallback hash based on release semantics
 201
 202 # score multiplier for percentage of all browser versions
 203 my $usagepct = 99.99 / sum(
 204         map { $_->{-total} // values %{$_} }
 205         map { $canihas->{$_} }
 206         grep { !/^-/ }
 207         keys %{$canihas}
 208 );
 209
 210 $_->{usage} = featurescore($_->{stats}) * $usagepct
 211         for values %{ $caniuse->{data} };
 212
 213 print '<table class="mapped">';
 214 print '<col span="3">';  # should match first thead row
 215 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
 216 say '</colgroup><col>';
 217
 218 my $header = join('',
 219         '<tr>',
 220         '<th colspan="3" rowspan="2">feature',
 221         (map {
 222                 my $name = $caniuse->{agents}->{$_}->{browser};
 223                 sprintf('<th colspan="%d" class="%s" title="%s">%s',
 224                         scalar @{ $versions{$_} },
 225                         join(' ', map {"b-a-$_"} grep {$_}
 226                                 $_, @{ $caniuse->{agents}->{$_} }{'prefix', 'type'},
 227                         ),
 228                         join(' ',
 229                                 sprintf('%.1f%%', $canihas->{$_}->{-total} * $usagepct),
 230                                 $name,
 231                         ),
 232                         do {
 233                                 length $name <= (3 * @{ $versions{$_} }) ? $name
 234                                         : $caniuse->{agents}->{$_}->{abbr};
 235                         },
 236                 )
 237         } @browsers),
 238         '<th rowspan="2">%',
 239 );
 240 print '<thead>', $header;
 241 # preceding row without any colspan to work around gecko bug
 242 print "\n<tr>";
 243 for my $browser (@browsers) {
 244         for my $span (@{ $versions{$browser} }) {
 245                 my $lastver = first {
 246                         !defined $caniuse->{agents}->{$browser}->{verrelease}->{$_} # stable
 247                 } reverse @{$span};
 248                 printf('<td title="%s"%s>%s',
 249                         join(' ',
 250                                 sprintf('%.1f%%', sum(@{ $canihas->{$browser} }{ @{$span} }) * $usagepct),
 251                                 'version ' . showversions(@{$span}, undef),
 252                                 $span->[-1] eq $lastver ? () : '(development)',
 253                         ),
 254                         !defined $lastver && ' class="ex"',
 255                         showversions($lastver // $span->[0]),
 256                 );
 257         }
 258 }
 259 say '</thead>';
 260 say '<tfoot>', $header;
 261 {
 262         # prefix indicates browser family; count adjacent families
 263         my (@families, %familycount);
 264         for my $browser (@browsers) {
 265                 my $family = $caniuse->{agents}->{$browser}->{prefix};
 266                 push @families, $family unless $familycount{$family};
 267                 $familycount{$family} += @{ $versions{$browser} };
 268         }
 269
 270         print "\n", '<tr class="cat">';
 271         printf '<th colspan="%d">%s', $familycount{$_}, $_ for @families;
 272 }
 273 say '</tfoot>';
 274
 275 sub featurescore {
 276         # relative amount of support for given feature
 277         my $rank = 0;
 278         if (my $row = shift) {
 279                 if ($canihas) {
 280                         while (my ($browser, $versions) = each %$row) {
 281                                 ref $versions eq 'HASH' or next;
 282                                 my $prev;
 283                                 for my $version (@{ $caniuse->{agents}->{$browser}->{versions} }) {
 284                                         my $status = $versions->{$version} // $prev;
 285                                         $status =~ s/\h\#\d+//g;
 286                                         $rank += ($canihas->{$browser}->{$version} || .001) * $PSTATS{$status};
 287                                         $prev = $status;
 288                                 }
 289                         }
 290                         return $rank;
 291                 }
 292
 293                 while (my ($browser, $vercols) = each %versions) {
 294                         my $div = 0;  # multiplier exponent (decreased to lower value)
 295                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 296                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 297                                 my @future;  # find upcoming releases (after current)
 298                                 for (reverse @$vercols) {
 299                                         last if $_ eq $current;
 300                                         push @future, pop @vers;
 301                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 302                                 }
 303                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 304                         }
 305                         $rank += $PSTATS{$_} * 2**($div--) for reverse @vers;
 306                 }
 307         }
 308         return $rank;
 309 }
 310
 311 sub formatnotes {
 312         my @html = @_;
 313         for (@html) {
 314                 s/\r\n?/\n/g;  # windows returns
 315                 s/\h* $//gmx;  # trailing whitespace
 316                 s/(?<= [^.\n]) $/./gmx;  # consistently end each line by a period
 317                 Entity($_);
 318                 s{  ` ([^`]*)  ` }{<code>$1</code>}gx;
 319                 s{ \[ ([^]]*) \] \( ([^)]*) \) }{<a href="$2">$1</a>}gx;
 320         }
 321         return @html;
 322 }
 323
 324 sub notestotitle {
 325         my @notes = @_;
 326         for (@notes) {
 327                 EscapeHTML($_);
 328                 s{ \[ ([^]]*) \] \( [^)]* \) }{$1}gx;  # strip link urls
 329         }
 330         return @notes;
 331 }
 332
 333 sub saytitlecol {
 334         my ($id) = @_;
 335         my $row = $caniuse->{data}->{$id};
 336
 337         for ($row->{categories}) {
 338                 my $cell = $_ ? lc $_->[0] : '-';
 339                 $cell =~ s/ api$//;  # trim unessential fluff in 'js api'
 340                 printf '<th title="%s">%s', join(' + ', @$_), $cell;
 341         }
 342
 343         print '<td>', map {
 344                 sprintf('<a href="%s" onclick="%s">%s</a>',
 345                         "#$id",
 346                         sprintf("try { %s; return false } catch(err) { return true }",
 347                                 "document.getElementById('$id').classList.toggle('target')",
 348                         ),
 349                         Entity($_),
 350                 );
 351         } $row->{title};
 352         print '<div class=aside>';
 353         print "<p>$_</p>"
 354                 for formatnotes($row->{description}, $row->{notes} || ());
 355         if (my %notes = %{ $row->{notes_by_num} }) {
 356                 say '<p>Browser-specific notes:';
 357                 say "<br>#$_: ", formatnotes($notes{$_}) for sort keys %notes;
 358                 say '</p>';
 359         }
 360         printf 'Resources: %s.', join(', ', map {
 361                 showlink($_->{title}, $_->{url})
 362         } @$_) for grep { @$_ } $row->{links} // ();
 363         printf '<br>Parent feature: %s.', join(', ', map {
 364                 showlink($caniuse->{data}->{$_}->{title}, "#$_")
 365         } $_) for $row->{parent} || ();
 366         print '</div>';
 367 }
 368
 369 sub saystatuscol {
 370         my ($id) = @_;
 371         my $row = $caniuse->{data}->{$id};
 372
 373         for ($row->{status}) {
 374                 my $cell = $_ // '-';
 375                 $cell = showlink($cell, $_) for $row->{spec} // ();
 376                 printf '<td title="%s" class="l %s">%s',
 377                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 378         }
 379 }
 380
 381 sub saybrowsercols {
 382         my ($id, $browser) = @_;
 383         my $feature = $caniuse->{data}->{$id};
 384         my $data = $feature->{stats}->{$browser};
 385         if (ref $data eq 'ARRAY') {
 386                 # special case for unsupported
 387                 my $release = $caniuse->{agents}->{$browser}->{verrelease};
 388                 $data = {
 389                         map { $_ => defined $release->{$_} ? 'u' : 'n' } keys %$release
 390                 };
 391         }
 392
 393         my ($prev, @span);
 394         for my $ver (@{ $versions{$browser} }, undef) {
 395                 my $compare = (
 396                         !defined $ver ? undef :      # last column if nameless
 397                         ref $data ne 'HASH' ? '' :   # unclassified if no support hash
 398                         (first { defined } @{$data}{ reverse @{$ver} })  # last known version
 399                         // $prev                     # inherit from predecessor
 400                         || 'u'                       # unsure
 401                 );
 402                 if (defined $prev and not $prev ~~ $compare) {
 403                         # different columns
 404                         my @vercover = (map { @{$_} } @span);  # accumulated conforming versions
 405                         for ($ver ? @{$ver} : ()) {
 406                                 last if defined $data->{$_};  # until different
 407                                 push @vercover, $_;  # matches from next span start
 408                         }
 409                         my $usage = sum(@{ $canihas->{$browser} }{@vercover});
 410
 411                         # strip #\d note references from support class
 412                         my @notes;
 413                         push @notes, $feature->{notes_by_num}->{$1}
 414                                 while $prev =~ s/\h \# (\d+) \b//x;
 415
 416                         # prepare version hover details
 417                         my $title = sprintf('%.1f%% %s', $usage * $usagepct, join(' ',
 418                                 (map { ref $_ eq 'CODE' ? $_->($browser, $vercover[0]) : $_ }
 419                                  map { $DSTATS{$_} // () }
 420                                  map { split / /, $_ }
 421                                  $prev
 422                                 ),
 423                                 'in', $caniuse->{agents}->{$browser}->{abbr},
 424                                 showversions(@vercover, undef),
 425                         ));
 426                         $title .= "\n$_" for notestotitle(@notes);
 427
 428                         $prev .= ' #' if @notes and $prev =~ /^y/;
 429                         printf('<td class="%s" colspan="%d" title="%s">%s',
 430                                 join(' ',
 431                                         X => $CSTATS{$prev},
 432                                         !$usage ? ('p0') : ('p',
 433                                                 sprintf('p%01d', $usage * ($usagepct - .0001) / 10),
 434                                                 sprintf('p%02d', $usage * ($usagepct - .0001)),
 435                                         ),
 436                                 ),
 437                                 scalar @span,
 438                                 $title,
 439                                 showversions($span[0]->[0], @span > 1 && defined $ver ? $span[-1]->[-1] : ()),
 440                         );
 441                         undef $prev;
 442                         @span = ();
 443                 }
 444                 if ($ver) {
 445                         my $startversion = first { defined $data->{ $ver->[$_] } }
 446                                 reverse 0 .. $#{$ver};  # compare index
 447                         push @span, [ @{$ver}[ $startversion .. $#{$ver} ] ];
 448                 }
 449                 $prev = $compare;
 450         }
 451 }
 452
 453 sub sayusagecol {
 454         my ($id) = @_;
 455         print '<td>', int $caniuse->{data}->{$id}->{usage};
 456 }
 457
 458 say '<tbody>';
 459 for my $id (sort {
 460         $caniuse->{data}->{$b}->{usage} <=> $caniuse->{data}->{$a}->{usage}
 461 } keys %{ $caniuse->{data} }) {
 462         $caniuse->{data}->{$id}->{stats} or next;  # skip metadata [summary]
 463         printf '<tr id="%s">', $id;
 464         saytitlecol($id);
 465         saystatuscol($id);
 466         saybrowsercols($id, $_) for @browsers;
 467         sayusagecol($id);
 468         say '</tr>';
 469 }
 470 say '</tbody>';
 471 say '</table>';
 472
 473 sub paddedver {
 474         # normalised version number comparable as string (cmp)
 475         $_[0] =~ m/(?:.*-|^)(\d*)(.*)/;
 476         # matched (major)(.minor) of last value in range (a-B)
 477         return sprintf('%02d', length $1 ? $1 : 99) . $2;
 478 }
 479
 480 sub showversions {
 481         # title to describe minumum version and optional maximum for multiple cells
 482         my @span = (map { split /-/ } grep { defined } @_);
 483         return $span[0] =~ s/\.0\z//r if @_ <= 1;
 484         splice @span, 1, -1;
 485         return join('‒', @span);
 486 }
 487
 488 :>
 489 <hr>
 490
 491 <div class="legend">
 492         <table class="glyphs"><tr>
 493         <td class="X l5">supported
 494         <td class="X l4">annotated
 495         <td class="X l3">partial
 496         <td class="X l2">optional
 497         <td class="X l1">missing
 498         <td class="X l0">unknown
 499         <td class="X ex">prefixed
 500         </table>
 501
 502         <p><: if ($usage) { :>
 503                 Usage percentage:
 504                 <span class="  p0">0</span> -
 505                 <span class="p p0 p00">.01</span> -
 506                 <span class="p p0 p05">1-9</span> -
 507                 <span class="p p1">10</span> -
 508                 <span class="p p2">20</span> -
 509                 <span class="p p5">majority</span>
 510 <: } else { :>
 511                 <table class="glyphs"><tr>
 512                         <td class="p p1">previous version</td>
 513                         <td class="p p3">current</td>
 514                         <td class="p p0 p00">upcoming (within months)</td>
 515                         <td class="  p0">future (within a year)</td>
 516                 </table>
 517 <: } :> </p>
 518
 519         <div class="right">
 520                 <ul class="legend legend-set">
 521                 <li>default <strong>style</strong> is
 522                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 523                 <li><strong>usage</strong> source is
 524                         <:= !defined $get{usage} && 'default ' :><:= defined $usage ? "<em>$usage</em>" : 'not included (<em>0</em>)' :>
 525                 <li>usage <strong>threshold</strong> is
 526                         <:= defined $get{threshold} && 'changed to ' :><em><:= $minusage :>%</em>
 527                 </ul>
 528         </div>
 529 </div>
 530
 531 <script type="text/javascript" src="/searchlocal.js"></script>
 532 <script type="text/javascript"><!--
 533         prependsearch(document.getElementById('intro'));
 534 //--></script>
 535