Shiar_Sheet/ImagePrep.pm

   1 package Shiar_Sheet::ImagePrep;
   2
   3 use 5.014;
   4 use warnings;
   5
   6 our $VERSION = '1.00';
   7
   8 sub new {
   9         my ($class, $target) = @_;
  10         bless \$target, $class;
  11 }
  12
  13 sub download {
  14         # copy changed remote url to local file
  15         my $target = shift;
  16         unlink $$target if -e $$target;
  17         my $download = shift or return 1;
  18         require LWP::UserAgent;
  19         my $ua = LWP::UserAgent->new;
  20         $ua->agent('/');
  21         my $status = $ua->mirror($download, $$target);
  22         $status->is_success
  23                 or die "Download from <q>$download</q> failed: ".$status->status_line."\n";
  24 }
  25
  26 sub convert {
  27         my ($imgpath, $thumbpath, $cmds) = @_;
  28         if (not -e $$imgpath) {
  29                 return !-e $thumbpath || unlink $thumbpath;
  30         }
  31
  32         my $xyres = 0 ? '600x400' : '300x200'; # cover
  33         my @cmds = @{ $cmds // [] };
  34         if (my ($cmdarg) = grep { $cmds[$_] eq '-area' } 0 .. $#cmds) {
  35                 # replace option by permillage crop
  36                 my @dim = map { $_ / 1000 } split /\D/, $cmds[$cmdarg + 1];
  37                 splice @cmds, $cmdarg, 2, (
  38                         -set => 'option:distort:viewport' => sprintf(
  39                                 '%%[fx:w*%s]x%%[fx:h*%s]+%%[fx:w*%s]+%%[fx:h*%s]',
  40                                 ($dim[2] || 1) - $dim[0], # width  = x2 - x1
  41                                 ($dim[3] || 1) - $dim[1], # height = y2 - y1
  42                                 @dim[0, 1]                # offset = x1,y1
  43                         ),
  44                         -distort => SRT => 0, # noop transform to apply viewport
  45                 );
  46         }
  47         @cmds = (
  48                 'convert',
  49                 $$imgpath,
  50                 -delete => '1--1', -background => 'white',
  51                 -gravity => defined $cmds ? 'northwest' : 'center',
  52                 @cmds,
  53                 -resize => "$xyres^", -extent => $xyres,
  54                 '-strip', -quality => '60%', -interlace => 'plane',
  55                 $thumbpath
  56         );
  57
  58         require IPC::Run;
  59         my $output;
  60         IPC::Run::run(\@cmds, '<' => \undef, '>&' => \$output) or die [
  61                 "Failed to convert source image.",
  62                 "@cmds\n" .
  63                 ($output || ($? & 127 ? "signal $?" : "error code ".($? >> 8))),
  64         ];
  65 }
  66
  67 1;