termcol.plp

   1 <(common.inc.plp)><:
   2
   3 Html({
   4         title => 'terminal colour cheat sheet',
   5         version => '1.0',
   6         description => [
   7                 "Index of all terminal/console colour codes,",
   8                 "with an example result of various environments.",
   9         ],
  10         keywords => [qw'
  11                 color code terminal console escape table xterm rxvt
  12         '],
  13         stylesheet => [qw'light dark'],
  14 });
  15
  16 :>
  17 <h1>Terminal colours</h1>
  18
  19 <p>
  20 <span title="ECMA-48">ANSI</span> (VT100, ISO-6429) 16-colour text palette
  21 as implemented by various systems and programs.
  22 <:
  23 print
  24         !exists $get{v} ? 'Also see <a href="?v">8-bit legacy hardware</a> palettes.' :
  25         'Also included are 8-bit legacy hardware palettes.';
  26 :>
  27 </p>
  28
  29 <div class="section">
  30 <:
  31 use Shiar_Sheet::Colour '1.01';
  32
  33 sub colcell {
  34         my $name = shift;
  35         my $col = Shiar_Sheet::Colour->new(@_);
  36         my $minhex = $col->rgb24;
  37         my $css     = '#' . $col->rgb48;
  38         my $inverse = '#' . sprintf('%X', $col->luminance/255 < .3 ? 12 : 0) x 3;
  39
  40         my $sample = [ qw(#000 #FFF) ];
  41         ($name, $sample) = @$name if ref $name eq 'ARRAY';
  42
  43         my $out = sprintf('<td title="%s" style="%s">%s',
  44                 join(',', map { int } @$col),
  45                 "background:$css; color:$inverse; padding:0 1ex",
  46                 $name,
  47         );
  48         $out .= sprintf '<td style="%s"><code>%s</code>', "background:$_; color:$css", $minhex
  49                 for @$sample;
  50         return "$out\n";
  51 }
  52
  53 my %col = (
  54         html => [
  55                 sprintf('<a title="%s" href="%s">html</a>',
  56                         'HTML keywords (inherited by CSS≥2.1 and SVG), mostly identical to X11',
  57                         'http://www.w3.org/TR/css3-color/#html4',
  58                 ),
  59                 qw/000000:black 800000:maroon  008000:green 808000:olive
  60                    000080:navy  800080:purple  008080:cyan  C0C0C0:silver
  61                    808080:gray  FF0000:red     00FF00:lime  FFFF00:yellow
  62                    0000FF:blue  FF00FF:fuchsia 00FFFF:aqua  FFFFFF:white /,
  63         ],
  64         cga => [
  65                 undef,  # linux console, kde?
  66                 qw/000000 AA0000 00AA00 AA5500 0000AA AA00AA 00AAAA AAAAAA
  67                    555555 FF5555 55FF55 FFFF55 5555FF FF55FF 55FFFF FFFFFF/,
  68 #               qw/reset bold dim italic underline blink fastblink reverse hidden/,
  69         ],
  70         xterm => [
  71                 undef,  # rxvt except for blues
  72                 qw/000000 CC0000 00CC00 CCCC00 4682B4 CC00CC 00CCCC E5E5E5
  73                    4C4C4C FF0000 00FF00 FFFF00 1E90FF FF00FF 00FFFF FFFFFF/,
  74         ],
  75         tango => [
  76                 undef,  # default Gnome theme
  77                 qw/2E3436 CC0000 4E9A06 C4A000 3465A4 75507B 06989A D3D7CF
  78                    555753 EF2929 8AE234 FCE94F 729FCF AD7FA8 34E2E2 EEEEEC/,
  79         ],
  80         xkcd => [
  81                 sprintf('<a title="%s" href="%s">xkcd</a>',
  82                         'human averages in xkcd survey results',
  83                         'http://blog.xkcd.com/2010/05/03/color-survey-results/',
  84                 ),
  85                 qw/000000:black 650021:maroon  15b01a:green 6e750e:olive
  86                    01153e:navy  7e1e9c:purple  029386:teal  c5c9c7:silver
  87                    929591:grey  e50000:red     aaff32:lime  ffff14:yellow
  88                    0343df:blue  ed0dd9:fuchsia 00ffff:cyan  ffffff:white /,
  89         ],
  90         android => [
  91                 sprintf('<a href="%s" title="%s">android</a>',
  92                         'http://developer.android.com/guide/practices/ui_guidelines/icon_design.html',
  93                         'recommended colour palette for Android icons',
  94                 ),
  95                 qw/FFFFFF:white   BFBFBF:light   808080:medium  404040:dark
  96                    000000:black   6699FF:blue1   3366CC:blue2   003399:blue3
  97                    99CC33:green1  00CC00:green2  669933:green3  FFCC00:orange1
  98                    FF9900:orange2 FF6600:orange3 CC0000:red /,
  99         ],
 100         app => [
 101                 'Term.app',
 102                 qw/000000 C23621 25BC24 ADAD27 492EE1 D338D3 33BBC8 CBCCCD
 103                    818383 FC391F 31E722 EAEC23 5833FF F935F8 14F0F0 E9EBEB /,
 104         ],
 105         putty => [
 106                 'PuTTY',
 107                 qw/000000 BB0000 00BB00 BBBB00 0000BB BB00BB 00BBBB BBBBBB
 108                    555555 FF5555 55FF55 FFFF55 5555FF FF55FF 55FFFF FFFFFF /,
 109         ],
 110         slutty => [
 111                 sprintf('<a href="%s" title="%s">SluTTY</a>',
 112                         'http://www.npjh.com/slutty.html',
 113                         'PuTTY fork with light colour scheme',
 114                 ),
 115                 qw/000000 9C1D1D 6C9446 AC9A47 335786 8F6496 486768 E0DCDC
 116                    2F2F2F CD5757 8FC35B D1C45E 5C81A9 BC95B7 76CBCB EEEEEC /,
 117         ],
 118         mac2 => [
 119                 'MacII',
 120                 qw/FFFFFF FBF305 FF6403 DD0907 F20884 4700A5 0000D3 02ABEA
 121                    1FB714 006412 562C05 90713A C0C0C0 808080 404040 000000 /,
 122         ],
 123         risc => [
 124                 'RISC',  # v2/3
 125                 qw/FFFFFF DDDDDD BBBBBB 999999 777777 555555 333333 000000
 126                    004499 EEEE00 00CC00 DD0000 EEEEBB 558800 FFBB00 00BBFF /,
 127         ],
 128         c64 => [
 129                 'C=64',  # commodore 64/128
 130                 map {
 131                         # 5-bit luma ± 2-bit colour angle
 132                         my ($y, $neg, $hue) = split /(-)|\+/;
 133
 134                         # convert to yuv
 135                         my ($u, $v) = (0, 0);
 136                         if (defined $hue) {
 137                                 my $RAD = 3.14159;
 138                                 $hue *= $RAD / 8;
 139                                 $hue += $RAD if $neg;
 140                                 $u = cos $hue;
 141                                 $v = sin $hue;
 142                         }
 143
 144                         # convert to rgb
 145                         $y *= 255 / 32;
 146                         $_ = $_ * 127.5 + 128 for $u, $v;
 147                         Shiar_Sheet::Colour->newyuv($y, $u, $v)->rgb48;
 148                 }
 149                 qw/ 0    32  10+5 20-5 12+2 16-2 8+0  24-0
 150                     12+6 8+7 16+5 10   15   24-2 15+0 20 /,
 151         ],
 152         msx1 => [
 153                 'MSX',
 154                 map {
 155                         my ($y, @c) = split /;/;
 156                         $y *= 255;
 157                         $_ = ($_ - .47) / .53 * 127.5 + 128 for @c;
 158                         Shiar_Sheet::Colour->newyuv($y, @c)->rgb48;
 159                 }
 160                 qw/ 0.00;0.47;0.47 0.00;0.47;0.47 0.53;0.20;0.07 0.67;0.27;0.17
 161                     0.40;1.00;0.40 0.53;0.93;0.43 0.47;0.30;0.83 0.73;0.70;0.00
 162                     0.53;0.27;0.93 0.67;0.27;0.93 0.73;0.07;0.57 0.80;0.17;0.57
 163                     0.47;0.23;0.13 0.53;0.67;0.73 0.80;0.47;0.47 1.00;0.47;0.47 /,
 164         ],
 165         msx2 => [
 166                 'MSX2',
 167                 map { s{([0-7])}{sprintf '%02X', $1 / 7 * 255}egr }
 168                 qw/ 000 000 161 373 117 237 511 267
 169                     711 733 661 663 141 625 555 777 /,
 170         ],
 171         arnejmp => [
 172                 sprintf('<a href="%s" title="%s">%s</a>',
 173                         'http://androidarts.com/palette/16pal.htm',
 174                         "Arne's Japanese Machine Palette v3 (MSX)",
 175                         'A:JMP',
 176                 ),
 177                 qw/ 000000 191028 46AF45 A1D685 453E78 7664FE 833129 9EC2E8
 178                     DC534B E18D79 D6B97B E9D8A1 216C4B D365C8 AFAAB9 F5F4EB /,
 179         ],
 180         arnegame => [
 181                 sprintf('<a href="%s" title="%s">%s</a>',
 182                         'http://androidarts.com/palette/16pal.htm',
 183                         'Generic 16 color game palette v20 by Arne Niklas Jansson',
 184                         'Arne',
 185                 ),
 186                 qw/ 000000::void     9D9D9D::ash     FFFFFF::blind   BE2633::bloodred
 187                     E06F8B::pigmeat  493C2B::oldpoop A46422::newpoop EB8931::blaze
 188                     F7E26B::zornskin 2F484E::shade   44891A::leaf    A3CE27::slime
 189                     1B2632::night    005784::sea     31A2F2::sky     B2DCEF::cloud /,
 190         ],
 191 );
 192
 193 if ($get{v}) {
 194         my %reorder = (
 195                 arnegame => [ 0,5,9,12 , 3,6,10,13,1 , 4,7,8,11,14,15,2 ],
 196         );
 197         $reorder{$_} = $reorder{msx2} for qw( msx1 arnejmp );
 198         while (my ($name, $order) = each %reorder) {
 199                 for my $pal ( $col{$name}) {
 200                         $pal = [ map { $pal->[$_ + 1] =~ s/:|$/:$_/r } -1, @{$order} ];
 201                 }
 202         }
 203 }
 204
 205 my @termlist = qw( cga xterm tango app html xkcd );
 206 push @termlist, qw( c64 msx2 mac2 risc arnegame ) if exists $get{v};
 207 for my $term (@termlist) {
 208         print '<table>', "\n";
 209         printf "<caption>%s</caption>\n", $col{$term}[0] || $term;
 210         for my $num (1 .. $#{ $col{$term} }) {
 211                 my ($rgb, $name) = split /:/, $col{$term}[$num], 3;
 212                 $name ||= $num - 1;
 213                 $name = [ $name, ['#333'] ] if $term eq 'xkcd';
 214                 print '<tr>', colcell($name, $rgb);
 215         }
 216         print "</table>\n\n";
 217 }
 218 :></div>
 219
 220 <hr>
 221
 222 <div class="section">
 223 <h2>88-colour space</h2>
 224 <:
 225 for my $r (0 .. 3) {
 226         print '<table>';
 227         for my $g (0 .. 3) {
 228                 print '<tr>';
 229                 for my $b (0 .. 3) {
 230                         my $index = $r*4*4 + $g*4 + $b + 16;
 231                         print colcell($index, map {(0, 139, 205, 255)[$_]} $r, $g, $b);
 232                 }
 233         }
 234         print "</table>\n";
 235 }
 236 print "\n";
 237
 238 print '<table><tr>';
 239 print colcell(80+$_, (($_ + 2 + ($_>0)) * 255/11) x 3) for 0 .. 7;
 240 print "</table>\n\n";
 241
 242 :></div>
 243 <: if ($ENV{PATH_INFO} =~ /256/) { :>
 244 <hr>
 245
 246 <div class="section">
 247 <h2>256-colour space</h2>
 248 <:
 249 for my $r (0 .. 5) {
 250         print '<table>';
 251         for my $g (0 .. 5) {
 252                 print '<tr>';
 253                 for my $b (0 .. 5) {
 254                         my $index = $r*6*6 + $g*6 + $b + 16;
 255                         print colcell($index, map { $_ && $_*40 + 55 } $r, $g, $b);
 256                 }
 257         }
 258         print "</table>\n";
 259 }
 260 print "\n";
 261
 262         print '<table>';
 263 for my $row (0, 12) {
 264         print '<tr>';
 265         print colcell(232+$_, ($_*10 + 8) x 3) for $row .. $row+11;
 266 }
 267         print "</table>\n";
 268 print "\n";
 269
 270 :></div>
 271 <: } :>
 272 <hr>
 273