Shiar_Sheet/FormatChar.pm

   1 package Shiar_Sheet::FormatChar;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6
   7 use Data::Dump 'pp';
   8 use PLP::Functions 'EscapeHTML';
   9
  10 our $VERSION = '1.06';
  11
  12 our $uc = do 'unicode-char.inc.pl';
  13
  14 sub new {
  15         my ($class) = @_;
  16         bless { anno => ['di', 0], style => 'di' }, $class;
  17 }
  18
  19 sub glyph_info {
  20         my ($self, $codepoint) = @_;
  21         return $uc->{chr $codepoint} || eval {
  22                 require Unicode::UCD;
  23                 if (my $fullinfo = Unicode::UCD::charinfo($codepoint)) {
  24                         return [@$fullinfo{qw/category name - string/}];
  25                 }
  26         } || [];
  27 }
  28
  29 sub glyph_html {
  30         my ($self, $char) = @_;
  31         my $codepoint = ord $char;
  32         my $info = $self->glyph_info($codepoint);
  33         my ($class, $name, $mnem, $html, $string) = @$info;
  34
  35         my $cell = EscapeHTML($string || $char);
  36         my $title = sprintf 'U+%04X%s', $codepoint, $name && " ($name)";
  37
  38         $cell = "<span>$cell</span>" if $class =~ /\bZs\b/;
  39         $cell = '&nbsp;' if $cell eq '';
  40
  41         return ($cell, EscapeHTML($title), "X $class", $mnem, $html);
  42 }
  43
  44 sub glyphs_html {
  45         my $self = shift;
  46
  47         return $self->glyph_html(@_) if length $_[0] <= 1;
  48
  49         my @chars = map { [ $self->glyph_html($_) ] } split //, $_[0];
  50         return (
  51                 EscapeHTML($_[0]), # cell
  52                 join(' | ', map { $_->[1] } @chars), # title
  53                 $chars[0][2], # class
  54                 join(' ',  grep { defined } map { $_->[3] } @chars), # digraph
  55         );
  56 }
  57
  58 sub glyph_cell {
  59         my ($self, $char) = @_;
  60         return sprintf('<td class="%3$s" title="%2$s">%s', $self->glyph_html($char));
  61 }
  62
  63 sub cell {
  64         my ($self, $input, $html) = @_;
  65         my (@class, $title, $cell, $mnem, $entity);
  66
  67         if ($input eq '-') {
  68                 $cell = '';
  69         }
  70         elsif ($input eq '=') {
  71                 push @class, 'u-invalid';
  72                 $cell = '';
  73         }
  74         else {{
  75                 push @class, 'X';
  76
  77                 if ($input =~ s/^-//) {
  78                         push @class, 'ex'; # discouraged
  79                 }
  80
  81                 $input =~ s/^\\//;  # escaped char
  82                 ($cell, $title, my $class, $mnem, $entity) = $self->glyphs_html($input);
  83
  84                 if ($self->{style} eq 'univer') {
  85                         state $agemap = do 'unicode-age.inc.pl' or die $!;
  86                         my $version = $agemap->{ord $input};
  87                         if (!$version) {
  88                                 push @class, 'l1';  # no known unicode assignment
  89                         }
  90                         elsif ($version < 20) {
  91                                 push @class, 'l5';  # first release 1993
  92                         }
  93                         elsif ($version < 31) {
  94                                 push @class, 'l4';  # 20th century
  95                         }
  96                         elsif ($version < 50) {
  97                                 push @class, 'l4';  # over 10 years ago
  98                         }
  99                         elsif ($version < 61) {
 100                                 push @class, 'l3';  # before 2012
 101                         }
 102                         else {
 103                                 push @class, 'l2';  # more recent
 104                         }
 105                         next;
 106                 }
 107
 108                 if ($self->{style} eq 'di') {
 109                         if ($class =~ /\bu-di\b/) {
 110                                 push @class, ('l3', 'u-di'); # standard digraph
 111                         }
 112                         elsif ($class =~ /\bu-prop\b/) {
 113                                 push @class, ('l2', 'u-prop'); # unofficial
 114                         }
 115                 }
 116                 elsif ($self->{style} eq 'html') {
 117                         if (defined $entity) {
 118                                 push @class, ('l3', 'u-html');
 119                         }
 120                 }
 121                 else {
 122                         my $codepoint = ord(substr $input, 0, 1);
 123                         if ($codepoint <= 0xFF) {
 124                                 push @class, 'l3', 'u-lat1';  # latin1
 125                         }
 126                         elsif ($codepoint <= 0xD7FF) {
 127                                 push @class, 'l2', 'u-bmp';  # bmp
 128                         }
 129                 }
 130
 131                 if ($input =~ /[ -~]/) {
 132                         push @class, 'l4', 'u-ascii'; # ascii
 133                 }
 134                 else {
 135                         push @class, 'l1'; # basic unicode
 136                 }
 137         }}
 138
 139         my $anno = '';
 140         if ($cell ne '') {
 141                 for (@{ $self->{anno} }) {
 142                         if (/html$/) {
 143                                 if (defined $entity) {
 144                                         $entity = "&$entity;" if /^&/;
 145                                         $anno = sprintf(' <small class="digraph">%s</small>', EscapeHTML($entity));
 146                                         last;
 147                                 }
 148                         }
 149                         elsif ($_ eq 'xml') {
 150                                 $anno = sprintf(' <small class="digraph">%s</small>',
 151                                         sprintf '#%d', ord($cell)
 152                                 );
 153                                 last;
 154                         }
 155                         elsif ($_ eq '&xml') {
 156                                 $anno = sprintf(' <small class="digraph">%s</small>',
 157                                         sprintf '&amp;#%d;', ord($cell)
 158                                 );
 159                                 last;
 160                         }
 161                         elsif ($_ eq 'di') {
 162                                 if (defined $mnem and length $mnem) {
 163                                         $anno = sprintf(' <small class="digraph">%s</small>', EscapeHTML($mnem));
 164                                         last;
 165                                 }
 166                         }
 167                         else {
 168                                 if ($_ eq 'hex' or $cell =~ /^[^a-zA-Z]$/) {
 169                                         $anno = sprintf(' <small class="%s">%04X</small>', 'value', ord $cell);
 170                                         last;
 171                                 }
 172                         }
 173                 }
 174         }
 175
 176         return sprintf('<td%s%s%s>%s%s',
 177                 defined $title  ? qq{ title="$title"}  : '',
 178                 @class ? sprintf(' class="%s"', join ' ', @class) : '',
 179                 $html || '',
 180                 $cell eq '' ? '&nbsp;' : $cell,
 181                 $anno,
 182         );
 183 }
 184
 185 sub table {
 186         my ($self, $digraphs) = @_;
 187
 188         my @rows;
 189
 190         my @colheads;
 191         while ($digraphs->[0] !~ /^\./) {
 192                 my $cell = shift @$digraphs or last;
 193                 push @colheads, sprintf(
 194                         '<%s%s>%s',
 195                         $cell =~ s/^-// ? 'td' : 'th',
 196                         $cell =~ s/:(.*)// ? qq{ title="$1"} : '',
 197                         $cell eq '_' ? '&nbsp;' : $cell
 198                 );
 199         }
 200         push @rows, sprintf '<thead><tr>%s<tbody>', join '', @colheads if @colheads;
 201
 202         my $colspan = 1;
 203         for my $cell (@$digraphs) {
 204                 if ($cell =~ s/^\.//) {
 205                         # dot indicates start of a new row
 206                         push @rows, '<tr>';
 207                         if ($cell =~ s/^>//) {
 208                                 # header cell text follows
 209                                 $cell =~ s/_/ /g;  # underscores may be used instead of whitespace (for qw//ability)
 210                                 my $class = $cell =~ s/^-// && ' class="ex"';
 211                                 $rows[-1] .= "<th$class>".($cell || '&nbsp;');
 212                         }
 213                         next;
 214                 }
 215                 elsif ($cell eq '>') {
 216                         # merge this cell to the next column
 217                         $colspan++;
 218                         next;
 219                 }
 220
 221                 $rows[-1] .= $self->cell($cell,
 222                         $colspan > 1 && qq{ colspan="$colspan"},
 223                 );
 224
 225                 $colspan = 1;
 226         }
 227
 228         return sprintf qq{<table class="glyphs%s">\n%s</table>\n},
 229                 @{ $self->{anno} } ? ' dilabel' : '',
 230                 join '', map {"$_\n"} @rows;
 231 }
 232
 233 sub print {
 234         my $self = shift;
 235         while (@_) {
 236                 print '<div class="section">';
 237                 printf '<h2>%s</h2>', shift unless ref $_[0];
 238                 print "\n\n";
 239                 while (ref $_[0] and $_ = shift) {
 240                         print $self->table($_);
 241                 }
 242                 print "\n</div>";
 243         }
 244 }
 245
 246 1;
 247