Shiar_Sheet/ImagePrep.pm

   1 package Shiar_Sheet::ImagePrep;
   2
   3 use 5.014;
   4 use warnings;
   5
   6 our $VERSION = '1.01';
   7
   8 sub new {
   9         my ($class, $target) = @_;
  10         bless \$target, $class;
  11 }
  12
  13 sub download {
  14         # copy changed remote url to local file
  15         my $target = shift;
  16         unlink $$target if -e $$target;
  17         my $download = shift or return 1;
  18         require LWP::UserAgent;
  19         my $ua = LWP::UserAgent->new;
  20         $ua->agent('/');
  21         my $status = $ua->mirror($download, $$target);
  22         $status->is_success
  23                 or die "Download from <q>$download</q> failed: ".$status->status_line."\n";
  24 }
  25
  26 sub dimensions {
  27         my ($imgpath) = @_;
  28         require IPC::Run;
  29         IPC::Run::run(
  30                 [identify => -format => '%w %h', $$imgpath],
  31                 '<' => \undef, '>&' => \my $xy
  32         ) or die ["Image dimensions could not be determined.", $$imgpath];
  33         return split /\s/, $xy, 3;
  34 }
  35
  36 sub convert {
  37         my ($imgpath, $thumbpath, $cmds, $xyres) = @_;
  38         if (not -e $$imgpath) {
  39                 return !-e $thumbpath || unlink $thumbpath;
  40         }
  41
  42         #my ($w, $h) = $imgpath->dimensions;
  43         $xyres //= '300x200'; # cover
  44         my $aspect = 3/2;
  45         my @cmds = @{ $cmds // [] };
  46         if (my ($cmdarg) = grep { $cmds[$_] eq '-area' } 0 .. $#cmds) {
  47                 # replace option by permillage crop
  48                 my @dim = map { $_ / 1000 } split /\D/, $cmds[$cmdarg + 1];
  49                 $dim[$_] ||= 1 for 2, 3; # optional end
  50                 push @dim, $dim[2 + $_] - $dim[$_] for 0, 1; # add width, height
  51                 splice @cmds, $cmdarg, 2, (
  52                         #crop="%[fx:floor(w*$ratio)]x%[fx:floor(h*$ratio)]"
  53                         #crop="$crop+%[fx:ceil((w-w*$ratio)/2)]+%[fx:ceil((h-h*$ratio)/2)]"
  54                         -set => 'option:distort:viewport' => sprintf(
  55                                 '%%[fx:%s]x%%[fx:%s]+%%[fx:%s]+%%[fx:%s]',
  56                                 "w*$dim[4]", "h*$dim[5]", # width x height
  57                                 #"max(w*$dim[4], h*$dim[5]*$aspect)", # width
  58                                 #"max(h*$dim[5], w*$dim[4]/$aspect)", # height
  59                                 "w*$dim[0]", "h*$dim[1]", # x+y offset
  60                         ),
  61                         -distort => SRT => 0, # noop transform to apply viewport
  62                 );
  63         }
  64         @cmds = (
  65                 'convert',
  66                 $$imgpath,
  67                 -delete => '1--1', -background => 'white',
  68                 -gravity => defined $cmds ? 'northwest' : 'center',
  69                 @cmds,
  70                 -resize => "$xyres^", -extent => $xyres,
  71                 '-strip', -quality => '60%', -interlace => 'plane',
  72                 $thumbpath
  73         );
  74
  75         require IPC::Run;
  76         my $output;
  77         IPC::Run::run(\@cmds, '<' => \undef, '>&' => \$output) or die [
  78                 "Failed to convert source image.",
  79                 "@cmds\n" .
  80                 ($output || ($? & 127 ? "signal $?" : "error code ".($? >> 8))),
  81         ];
  82 }
  83
  84 1;