browser.plp

   1 <(common.inc.plp)><:
   2 use List::Util qw(sum max first);
   3 no if $] >= 5.018, warnings => 'experimental::smartmatch';
   4
   5 Html({
   6         title => 'browser compatibility cheat sheet',
   7         version => '1.5',
   8         description => [
   9                 "Compatibility table of new web features (HTML5, CSS3, SVG, Javascript)",
  10                 "comparing support and usage share for all popular browser versions.",
  11         ],
  12         keywords => [qw'
  13                 web browser support compatibility usage matrix available feature
  14                 html html5 css css3 svg javascript js dom mobile
  15                 ie internet explorer firefox chrome safari webkit opera
  16         '],
  17         stylesheet => [qw'circus dark mono red light'],
  18         data => ['data/browser/support.inc.pl'],
  19 });
  20
  21 say "<h1>Browser compatibility</h1>\n";
  22
  23 my $caniuse = do 'data/browser/support.inc.pl' or die $@ || $!;
  24 $_->{verrelease} = {
  25         # mark last three (future) versions as unreleased, ensure current isn't
  26         map {
  27                 $_->[-1] => 0, $_->[-2] => 0, $_->[-3] => 0,
  28                 $_->[-4] => undef,
  29         } $_->{versions}
  30 } for values %{ $caniuse->{agents} };
  31
  32 my %CSTATS = (
  33         'n'   => 'l1',
  34         'n d' => 'l2',
  35         'n x d' => 'l2 ex',
  36         'p d' => 'l2',
  37         'a d' => 'l2',
  38         'y'   => 'l5',
  39         'y #' => 'l4',
  40         'y x' => 'l5 ex',
  41         'y x #' => 'l4 ex',
  42         'a'   => 'l3',
  43         'a x' => 'l3 ex',
  44         'p'   => 'l2',
  45         'u'   => 'l0',
  46         'u d' => 'l2',
  47 );
  48 my %DSTATS = (
  49         u => 'unknown',
  50         n => 'unsupported',
  51         p => 'plugin required',
  52         a => 'partial',
  53         y => 'supported',
  54         d => '(disabled by default)',
  55         x => sub {
  56                 join(' ',
  57                         'with prefix',
  58                         map {"-$_-"}
  59                         ($caniuse->{agents}->{$_[0]}->{prefix_exceptions} // {})->{$_[1]}
  60                         // $caniuse->{agents}->{$_[0]}->{prefix} // (),
  61                 );
  62         },
  63 );
  64 my %PSTATS = (  # score percentage
  65         y => 1,  'y x' => .9,
  66         a => .5, 'a x' => .5, 'a d' => .2,
  67         p => .2, 'p d' => .1,
  68         n => 0,  'n d' => .2, 'n x d' => .2,
  69         u => 0,
  70 );
  71 my %CSTATUS = (
  72         unoff => 'l1', # unofficial
  73         wd    => 'l2', # draft
  74         cr    => 'l3', # candidate
  75         pr    => 'l3', # proposed
  76         rec   => 'l5', # recommendation
  77         ls    => 'l4', # whatwg
  78         ietf  => 'l0', # standard
  79         other => 'l0', # non-w3
  80 );
  81 my %versions;
  82 while (my ($browser, $row) = each %{ $caniuse->{agents} }) {
  83         $versions{$browser} = [
  84                 sort { paddedver($a) cmp paddedver($b) } grep { defined }
  85                 @{ $row->{versions} }
  86         ];
  87 }
  88
  89 my $ref = showlink('Can I use', 'https://caniuse.com/');
  90 $ref =~ s/(?=>)/ title="updated $_"/
  91         for map { s/[\sT].*//r } $caniuse->{-date} || ();
  92 $ref = "Fyrd's $ref page";
  93 say '<p id="intro">Alternate rendition of '.$ref;
  94
  95 my ($canihas, $usage);
  96 my $minusage = $get{threshold} // 1;
  97 given ($get{usage} // 'wm') {
  98         when (!$_) {
  99                 # none
 100         }
 101         when (!m{ \A [a-z]\w+ (?:/\d[\d-]*\d)? \z }x) {
 102                 Alert([
 103                         'Invalid browser usage data request',
 104                         'Identifier must be alphanumeric name or <q>0</q>.',
 105                 ]);
 106         }
 107         $canihas = do "data/browser/usage-$_.inc.pl" or do {
 108                 Alert('Browser usage data not found', $@ || $!);
 109                 break;
 110         };
 111         $usage = $_;
 112         my $ref = $canihas->{-title} || 'unknown';
 113         $ref = showlink($ref, $_)
 114                 for $canihas->{-site} || $canihas->{-source} || ();
 115         $ref =~ s/(?=>)/ title="updated $_"/ for $canihas->{-date} || ();
 116         print "\nwith $ref browser usage statistics";
 117 }
 118
 119 my @browsers;
 120 if ($usage) { # first() does not work inside given >:(
 121         # adapt version usage to actual support data
 122         my %engineuse;  # prefix => usage sum
 123         for my $browser (keys %versions) {
 124                 my $row = $canihas->{$browser} // {};
 125                 my $verlist = $versions{$browser} or next;
 126                 if ($minusage and sum(values %$row) < $minusage) {
 127                         delete $versions{$browser};
 128                         next;
 129                 }
 130                 my %supported = map { $_ => 1 } @$verlist;
 131
 132                 # cascade unknown versions
 133                 $row->{$_} //= undef for @$verlist;  # ensure stable keys during iteration
 134                 while (my ($version, $usage) = each %$row) {
 135                         next if defined $supported{$version};
 136                         my $next = first { paddedver($_) ge paddedver($version) } @$verlist
 137                                 or warn("No fallback found for $browser v$version; $usage% ignored"), next;
 138                         $row->{$next} += $usage;
 139                         $row->{$version} = 0;  # balance browser total
 140                 }
 141
 142                 # build row list for each version
 143                 if ($minusage) {
 144                         my @vershown;  # $verlist replacement
 145                         my ($rowusage, @verrow) = (0);  # replacement row tracking
 146                         for (@$verlist) {
 147                                 push @verrow, $_;  # queue each version
 148                                 if (($rowusage += $row->{$_}) >= $minusage) {
 149                                         push @vershown, [@verrow];   # add row
 150                                         ($rowusage, @verrow) = (0);  # reset row tracking
 151                                 }
 152                         }
 153                         push @vershown, \@verrow if @verrow;  # always add latest
 154                         @$verlist = @vershown;
 155                 }
 156                 else {
 157                         @$verlist = map { [$_] } @$verlist;
 158                 }
 159
 160                 # reusable aggregates (grouped by prefix (engine) and browser)
 161                 $engineuse{ $caniuse->{agents}->{$browser}->{prefix} } +=
 162                 $row->{-total} = sum(values %$row);
 163         }
 164
 165         # order browser columns by usage grouped by engine
 166         @browsers = sort {
 167                 $engineuse{ $caniuse->{agents}->{$b}->{prefix} } <=>
 168                 $engineuse{ $caniuse->{agents}->{$a}->{prefix} }
 169                         ||
 170                 $canihas->{$b}->{-total} <=> $canihas->{$a}->{-total}
 171         } keys %versions;
 172 }
 173 else {
 174         # order browser columns by name grouped by engine
 175         @{$_} = map { [$_] } @{$_} for values %versions;
 176         @browsers = sort {
 177                 $caniuse->{agents}->{$b}->{prefix} cmp
 178                 $caniuse->{agents}->{$a}->{prefix}
 179                         ||
 180                 $a cmp $b
 181         } keys %versions;
 182 }
 183 :>.
 184 </p>
 185
 186 <:
 187 $canihas ||= {
 188         map {
 189                 $_ => +{
 190                         map {
 191                                 my $zero = $#$_ - 2;  # baseline index
 192                                 ($_->[$zero - 2] =>  .5), # past
 193                                 ($_->[$zero - 1] => 10 ), # previous
 194                                 ($_->[$zero + 2] =>  0 ), # future
 195                                 ($_->[$zero + 1] =>  .5), # next
 196                                 ($_->[$zero    ] => 30 ), # current
 197                         } $caniuse->{agents}->{$_}->{versions}
 198                 }
 199         } @browsers
 200 }; # fallback hash based on release semantics
 201
 202 # score multiplier for percentage of all browser versions
 203 my $usagepct = 99.99 / sum(
 204         map { $_->{-total} // values %{$_} }
 205         map { $canihas->{$_} }
 206         grep { !/^-/ }
 207         keys %{$canihas}
 208 );
 209
 210 $_->{usage} = featurescore($_->{stats}) * $usagepct
 211         for values %{ $caniuse->{data} };
 212
 213 print '<table class="mapped">';
 214 print '<col span="3">';  # should match first thead row
 215 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
 216 say '</colgroup><col>';
 217
 218 my $header = join('',
 219         '<tr>',
 220         '<th colspan="3" rowspan="2">feature',
 221         (map {
 222                 my $name = $caniuse->{agents}->{$_}->{browser};
 223                 sprintf('<th colspan="%d" class="%s" title="%s">%s',
 224                         scalar @{ $versions{$_} },
 225                         join(' ', map {"b-a-$_"} grep {$_}
 226                                 $_, @{ $caniuse->{agents}->{$_} }{'prefix', 'type'},
 227                         ),
 228                         join(' ',
 229                                 sprintf('%.1f%%', $canihas->{$_}->{-total} * $usagepct),
 230                                 $name,
 231                         ),
 232                         do {
 233                                 length $name <= (3 * @{ $versions{$_} }) ? $name
 234                                         : $caniuse->{agents}->{$_}->{abbr};
 235                         },
 236                 )
 237         } @browsers),
 238         '<th rowspan="2">%',
 239 );
 240 print '<thead>', $header;
 241 # preceding row without any colspan to work around gecko bug
 242 print "\n<tr>";
 243 for my $browser (@browsers) {
 244         for my $span (@{ $versions{$browser} }) {
 245                 my $lastver = first {
 246                         !defined $caniuse->{agents}->{$browser}->{verrelease}->{$_} # stable
 247                 } reverse @{$span};
 248                 printf('<td title="%s"%s>%s',
 249                         join(' ',
 250                                 sprintf('%.1f%%', sum(@{ $canihas->{$browser} }{ @{$span} }) * $usagepct),
 251                                 'version ' . showversions(@{$span}, undef),
 252                                 $span->[-1] eq $lastver ? () : '(development)',
 253                         ),
 254                         !defined $lastver && ' class="ex"',
 255                         showversions($lastver // $span->[0]),
 256                 );
 257         }
 258 }
 259 say '</thead>';
 260 say '<tfoot>', $header;
 261 {
 262         # prefix indicates browser family; count adjacent families
 263         my (@families, %familycount);
 264         for my $browser (@browsers) {
 265                 my $family = $caniuse->{agents}->{$browser}->{prefix};
 266                 push @families, $family unless $familycount{$family};
 267                 $familycount{$family} += @{ $versions{$browser} };
 268         }
 269
 270         print "\n", '<tr class="cat">';
 271         printf '<th colspan="%d">%s', $familycount{$_}, $_ for @families;
 272 }
 273 say '</tfoot>';
 274
 275 sub featurescore {
 276         # relative amount of support for given feature
 277         my $rank = 0;
 278         if (my $row = shift) {
 279                 if ($canihas) {
 280                         while (my ($browser, $versions) = each %$row) {
 281                                 ref $versions eq 'HASH' or next;
 282                                 while (my ($version, $status) = each %$versions) {
 283                                         $status =~ s/\h\#\d+//g;
 284                                         $rank += ($canihas->{$browser}->{$version} || .001) * $PSTATS{$status};
 285                                 }
 286                         }
 287                         return $rank;
 288                 }
 289
 290                 while (my ($browser, $vercols) = each %versions) {
 291                         my $div = 0;  # multiplier exponent (decreased to lower value)
 292                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 293                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 294                                 my @future;  # find upcoming releases (after current)
 295                                 for (reverse @$vercols) {
 296                                         last if $_ eq $current;
 297                                         push @future, pop @vers;
 298                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 299                                 }
 300                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 301                         }
 302                         $rank += $PSTATS{$_} * 2**($div--) for reverse @vers;
 303                 }
 304         }
 305         return $rank;
 306 }
 307
 308 sub formatnotes {
 309         my @html = @_;
 310         for (@html) {
 311                 s/\r\n?/\n/g;  # windows returns
 312                 s/\h* $//gmx;  # trailing whitespace
 313                 s/(?<= [^.\n]) $/./gmx;  # consistently end each line by a period
 314                 Entity($_);
 315                 s{  ` ([^`]*)  ` }{<code>$1</code>}gx;
 316                 s{ \[ ([^]]*) \] \( ([^)]*) \) }{<a href="$2">$1</a>}gx;
 317         }
 318         return @html;
 319 }
 320
 321 sub notestotitle {
 322         my @notes = @_;
 323         for (@notes) {
 324                 EscapeHTML($_);
 325                 s{ \[ ([^]]*) \] \( [^)]* \) }{$1}gx;  # strip link urls
 326         }
 327         return @notes;
 328 }
 329
 330 sub saytitlecol {
 331         my ($id) = @_;
 332         my $row = $caniuse->{data}->{$id};
 333
 334         for ($row->{categories}) {
 335                 my $cell = $_ ? lc $_->[0] : '-';
 336                 $cell =~ s/ api$//;  # trim unessential fluff in 'js api'
 337                 printf '<th title="%s">%s', join(' + ', @$_), $cell;
 338         }
 339
 340         print '<td>', map {
 341                 sprintf('<a href="%s" onclick="%s">%s</a>',
 342                         "#$id",
 343                         sprintf("try { %s; return false } catch(err) { return true }",
 344                                 "document.getElementById('$id').classList.toggle('target')",
 345                         ),
 346                         Entity($_),
 347                 );
 348         } $row->{title};
 349         print '<div class=aside>';
 350         print "<p>$_</p>"
 351                 for formatnotes($row->{description}, $row->{notes} || ());
 352         if (my %notes = %{ $row->{notes_by_num} }) {
 353                 say '<p>Browser-specific notes:';
 354                 say "<br>#$_: ", formatnotes($notes{$_}) for sort keys %notes;
 355                 say '</p>';
 356         }
 357         printf 'Resources: %s.', join(', ', map {
 358                 showlink($_->{title}, $_->{url})
 359         } @$_) for grep { @$_ } $row->{links} // ();
 360         printf '<br>Parent feature: %s.', join(', ', map {
 361                 showlink($caniuse->{data}->{$_}->{title}, "#$_")
 362         } $_) for $row->{parent} || ();
 363         print '</div>';
 364 }
 365
 366 sub saystatuscol {
 367         my ($id) = @_;
 368         my $row = $caniuse->{data}->{$id};
 369
 370         for ($row->{status}) {
 371                 my $cell = $_ // '-';
 372                 $cell = showlink($cell, $_) for $row->{spec} // ();
 373                 printf '<td title="%s" class="l %s">%s',
 374                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 375         }
 376 }
 377
 378 sub saybrowsercols {
 379         my ($id, $browser) = @_;
 380         my $feature = $caniuse->{data}->{$id};
 381         my $data = $feature->{stats}->{$browser};
 382         if (ref $data eq 'ARRAY') {
 383                 # special case for unsupported
 384                 my $release = $caniuse->{agents}->{$browser}->{verrelease};
 385                 $data = {
 386                         map { $_ => defined $release->{$_} ? 'u' : 'n' } keys %$release
 387                 };
 388         }
 389
 390         my ($prev, @span);
 391         for my $ver (@{ $versions{$browser} }, undef) {
 392                 my $compare = (
 393                         !defined $ver ? undef :      # last column if nameless
 394                         ref $data ne 'HASH' ? '' :   # unclassified if no support hash
 395                         $data->{ $ver->[-1] } // $prev  # known or inherit from predecessor
 396                         // (grep { defined } @{$data}{ map { $_->[0] } @{ $versions{$browser} } })[0]
 397                            ~~ 'n' && 'n'             # first known version is unsupported
 398                         || 'u'                       # unsure
 399                 );
 400                 unless (!defined $prev or $prev ~~ $compare) {
 401                         my @vercover = (map { @{$_} } @span);
 402                         for ($ver ? @{$ver} : ()) {
 403                                 $data->{$_} eq $data->{$vercover[-1]} or last;
 404                                 push @vercover, $_;  # matches from next span start
 405                         }
 406                         my $usage = sum(@{ $canihas->{$browser} }{@vercover});
 407
 408                         # strip #\d note references from support class
 409                         my @notes;
 410                         push @notes, $feature->{notes_by_num}->{$1}
 411                                 while $prev =~ s/\h \# (\d+) \b//x;
 412
 413                         # prepare version hover details
 414                         my $title = sprintf('%.1f%% %s', $usage * $usagepct, join(' ',
 415                                 (map { ref $_ eq 'CODE' ? $_->($browser, $vercover[0]) : $_ }
 416                                  map { $DSTATS{$_} // () }
 417                                  map { split / /, $_ }
 418                                  $prev
 419                                 ),
 420                                 'in', $caniuse->{agents}->{$browser}->{abbr},
 421                                 showversions(@vercover, undef),
 422                         ));
 423                         $title .= "\n$_" for notestotitle(@notes);
 424
 425                         $prev .= ' #' if @notes and $prev =~ /^y/;
 426                         printf('<td class="%s" colspan="%d" title="%s">%s',
 427                                 join(' ',
 428                                         X => $CSTATS{$prev},
 429                                         !$usage ? ('p0') : ('p',
 430                                                 sprintf('p%01d', $usage * ($usagepct - .0001) / 10),
 431                                                 sprintf('p%02d', $usage * ($usagepct - .0001)),
 432                                         ),
 433                                 ),
 434                                 scalar @span,
 435                                 $title,
 436                                 showversions($span[0]->[0], @span > 1 && defined $ver ? $span[-1]->[-1] : ()),
 437                         );
 438                         undef $prev;
 439                         @span = ();
 440                 }
 441                 push @span, $ver && [ grep { $data->{ $_ } eq $data->{ $ver->[-1] } } @{$ver} ];
 442                 $prev = $compare;
 443         }
 444 }
 445
 446 sub sayusagecol {
 447         my ($id) = @_;
 448         print '<td>', int $caniuse->{data}->{$id}->{usage};
 449 }
 450
 451 say '<tbody>';
 452 for my $id (sort {
 453         $caniuse->{data}->{$b}->{usage} <=> $caniuse->{data}->{$a}->{usage}
 454 } keys %{ $caniuse->{data} }) {
 455         $caniuse->{data}->{$id}->{stats} or next;  # skip metadata [summary]
 456         printf '<tr id="%s">', $id;
 457         saytitlecol($id);
 458         saystatuscol($id);
 459         saybrowsercols($id, $_) for @browsers;
 460         sayusagecol($id);
 461         say '</tr>';
 462 }
 463 say '</tbody>';
 464 say '</table>';
 465
 466 sub paddedver {
 467         # normalised version number comparable as string (cmp)
 468         $_[0] =~ m/(?:.*-|^)(\d*)(.*)/;
 469         # matched (major)(.minor) of last value in range (a-B)
 470         return sprintf('%02d', length $1 ? $1 : 99) . $2;
 471 }
 472
 473 sub showversions {
 474         # title to describe minumum version and optional maximum for multiple cells
 475         my @span = (map { split /-/ } grep { defined } @_);
 476         return $span[0] =~ s/\.0\z//r if @_ <= 1;
 477         splice @span, 1, -1;
 478         return join('‒', @span);
 479 }
 480
 481 :>
 482 <hr>
 483
 484 <div class="legend">
 485         <table class="glyphs"><tr>
 486         <td class="X l5">supported
 487         <td class="X l4">annotated
 488         <td class="X l3">partial
 489         <td class="X l2">optional
 490         <td class="X l1">missing
 491         <td class="X l0">unknown
 492         <td class="X ex">prefixed
 493         </table>
 494
 495         <p><: if ($usage) { :>
 496                 Usage percentage:
 497                 <span class="  p0">0</span> -
 498                 <span class="p p0 p00">.01</span> -
 499                 <span class="p p0 p05">1-9</span> -
 500                 <span class="p p1">10</span> -
 501                 <span class="p p2">20</span> -
 502                 <span class="p p5">majority</span>
 503 <: } else { :>
 504                 <table class="glyphs"><tr>
 505                         <td class="p p1">previous version</td>
 506                         <td class="p p3">current</td>
 507                         <td class="p p0 p00">upcoming (within months)</td>
 508                         <td class="  p0">future (within a year)</td>
 509                 </table>
 510 <: } :> </p>
 511
 512         <div class="right">
 513                 <ul class="legend legend-set">
 514                 <li>default <strong>style</strong> is
 515                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 516                 <li><strong>usage</strong> source is
 517                         <:= !defined $get{usage} && 'default ' :><:= defined $usage ? "<em>$usage</em>" : 'not included (<em>0</em>)' :>
 518                 <li>usage <strong>threshold</strong> is
 519                         <:= defined $get{threshold} && 'changed to ' :><em><:= $minusage :>%</em>
 520                 </ul>
 521         </div>
 522 </div>
 523
 524 <script type="text/javascript" src="/searchlocal.js"></script>
 525 <script type="text/javascript"><!--
 526         prependsearch(document.getElementById('intro'));
 527 //--></script>
 528