word/edit.plp

   1 <(../common.inc.plp)><:
   2
   3 my $editorurl = '/word/edit';
   4 s{\Aedit(/|\z)}{} for $Request // ();
   5
   6 Html({
   7         title => 'words cheat sheet admin',
   8         version => '1.0',
   9         nocache => 1,
  10         raw => <<'EOT',
  11 <link rel="stylesheet" type="text/css" media="all" href="/word/editor.css" />
  12 <script src="/word/editor.js"></script>
  13 EOT
  14 });
  15
  16 use List::Util qw( pairs pairkeys );
  17 use Shiar_Sheet::FormRow;
  18 use JSON;
  19
  20 my $db = eval {
  21         require Shiar_Sheet::DB;
  22         Shiar_Sheet::DB->connect;
  23 } or Abort('Database error', 501, $@);
  24
  25 my $user = eval {
  26         if (defined $post{username}) {
  27                 $cookie{login} = EncodeURI(join ':', @post{qw( username pass )});
  28         }
  29         elsif (exists $fields{logout}) {
  30                 require CGI::Cookie;
  31                 if (AddCookie(CGI::Cookie->new(
  32                         -name    => 'login',
  33                         -value   => '',
  34                         -path    => $editorurl,
  35                         -expires => 'now',
  36                 )->as_string)) {
  37                         delete $cookie{login};
  38                         die "Logged out as requested\n";
  39                 }
  40                 Alert("Failed to log out", "Login cookie could not be removed.");
  41         }
  42
  43         my $cookiedata = $cookie{login} or return;
  44         my ($name, $key) = split /[:\v]/, DecodeURI($cookiedata);
  45         my %rowmatch = (username => $name, pass => $key);
  46         my $found = $db->select(login => '*', \%rowmatch)->hash
  47                 or die "Invalid user or password\n";
  48
  49         eval {
  50                 require CGI::Cookie;
  51                 my $httpcookie = CGI::Cookie->new(
  52                         -name    => 'login',
  53                         -value   => join(':', @{$found}{qw( username pass )}),
  54                         -path    => $editorurl,
  55                 ) or die "prepared object is empty\n";
  56                 AddCookie($httpcookie->as_string);
  57         } or Abort(["Unable to create login cookie", $@], 403);
  58
  59         return $found;
  60 } or do {
  61         say '<h1>Login to edit words</h1>';
  62         Alert('Access denied', $@) if $@;
  63         say '<form action="?" method="post" class="inline"><ul>';
  64         my $loginform = bless {%post}, 'Shiar_Sheet::FormRow';
  65         say '<li>', $loginform->input(@{$_}), '</li>' for pairs (
  66                 username => {-label => 'User name'},
  67                 pass     => {-label => 'Password', type => 'password'},
  68         );
  69         say '<li><input type="submit" value="Login" /></li>';
  70         say '</ul></form>';
  71         exit;
  72 };
  73
  74 my %lang = (
  75         '' => ['(reference)'],
  76         nl => ["\N{REGIONAL INDICATOR SYMBOL LETTER N}\N{REGIONAL INDICATOR SYMBOL LETTER L}", 'nederlands'],
  77         en => ["\N{REGIONAL INDICATOR SYMBOL LETTER G}\N{REGIONAL INDICATOR SYMBOL LETTER B}", 'english'],
  78         eo => [qq'<span style="color:green">\N{BLACK STAR}</span>', 'esperanto'],
  79         ru => ["\N{REGIONAL INDICATOR SYMBOL LETTER R}\N{REGIONAL INDICATOR SYMBOL LETTER U}", 'русский'],
  80         zh => ["\N{REGIONAL INDICATOR SYMBOL LETTER C}\N{REGIONAL INDICATOR SYMBOL LETTER N}", '中文'],
  81         la => ["\N{PUSHPIN}", 'latin'],
  82 );
  83 my @wordcols = pairkeys
  84 my %wordcol = (
  85         lang    => {-label => 'Language', -select => {
  86                 map { $_ => "@{$lang{$_}}" } keys %lang
  87         }},
  88         cat     => [{-label => 'Category'}, 'ref'],
  89         ref     => {-label => 'Reference'},
  90         prio    => [
  91                 {-label => 'Level', -select => sub {
  92                         my ($row) = @_;
  93                         my @enum = qw[
  94                                 essential ubiquitous basic common distinctive specialised rare invisible
  95                         ];
  96                         return {
  97                                 ('' => 'parent') x (defined $row->{ref}),
  98                                 map { $_ => $enum[$_] } 0 .. $#enum
  99                         };
 100                 }},
 101                 'cover', 'grade',
 102         ],
 103         cover   => {-label => 'Highlighted', type => 'checkbox'},
 104         grade   => {-label => 'Order', type => 'number'},
 105         form    => {-label => 'Title'},
 106         alt     => {-label => 'Synonyms', -multiple => 1},
 107         wptitle => {-label => 'Wikipedia'},
 108         source  => {-label => 'Image', -json => 'image', -src => sub {
 109                 return "data/word/org/$_[0]->{id}.jpg";
 110         }},
 111         convert => {-label => 'Convert options', -json => 'image', -multiple => 1, -src => sub {
 112                 return "data/word/32/$_[0]->{id}.jpg";
 113         }},
 114         crop32  => {-json => 'image', type => 'hidden'}, # set by javascript interface
 115         story   => {-label => 'Story', type => 'textarea', hidden => 'hidden'},
 116 );
 117
 118 if (my $search = $fields{q}) {
 119         my %filter = $search eq '^' ? (cat => undef, ref => undef) :
 120                 (form => {ilike => '%'.parseinput($search).'%'});
 121         my $results = $db->select(word => '*', \%filter);
 122         say '<h1>Search</h1><ul>';
 123         printf("<li><small>%s</small> %s %s</li>\n",
 124                 $_->{id}, showlink($_->{form}, "$editorurl/$_->{id}"),
 125                 sprintf('<img src="/%s" style="height:3ex; width:auto" />', $wordcol{convert}->{-src}->($_)) x defined $_->{image}
 126         ) for $results->hashes;
 127         say "</ul>\n";
 128         exit;
 129 }
 130
 131 my ($find) = map {{id => $_}} $fields{id} || $Request || ();
 132 my $row;
 133 if ($find) {
 134         $row = $db->select(word => '*', $find)->hash
 135                 or Abort("Word not found", 404);
 136 }
 137
 138 if (exists $get{copy}) {
 139         $row = {%{$row}{ qw(prio lang cat) }};
 140 }
 141 elsif (defined $post{form}) {{
 142         sub parseinput {
 143                 return if not length $_[0];
 144                 require Encode;
 145                 return Encode::decode_utf8($_[0]);
 146         }
 147
 148         my $replace = $row;  # currently stored
 149         $row = {};  # proposed update
 150         while (my ($col, $colinfo) = each %wordcol) {
 151                 ref $colinfo eq 'HASH' or $colinfo = {};
 152                 my @val = map { parseinput($_) } $post{'@'.$col}->@*;
 153                 my $val = $colinfo->{-multiple} && @val ? \@val : $val[-1];
 154                 if (my $jsoncol = $colinfo->{-json}) {
 155                         $row->{$jsoncol}->{$col} = $val;  # hash will be encoded
 156                 }
 157                 else {
 158                         $row->{$col} = $val;
 159                 }
 160         }
 161         my $imagecol = $row->{image};  # backup image subcolumns
 162         while (my ($col, $val) = each %{$row}) {
 163                 # convert json subcolumns to database string
 164                 ref $val eq 'HASH' or next;
 165                 $val = { %{decode_json($_)}, %{$val} } for $replace->{$col} // ();  # preserve unknown
 166                 defined $val->{$_} or delete $val->{$_} for keys %{$val};  # delete emptied
 167                 $row->{$col} = encode_json($val);
 168         }
 169
 170         if (!$row->{form} and $row->{lang}) {
 171                 if ($row->{ref} ne 'delete') {
 172                         Alert("Empty title",
 173                                 "Confirm removal by setting <em>Reference</em> to <q>delete</q>."
 174                         );
 175                 }
 176                 else {
 177                         $db->delete(word => $find);
 178                         Alert("Entry removed");
 179                 }
 180                 next;
 181         }
 182
 183         eval {
 184                 my %res = (returning => '*');
 185                 $row->{creator} = $user->{id} unless $find;
 186                 $row->{updated} = ['now()'];
 187                 my $query = $find ? $db->update(word => $row, $find, \%res) :
 188                         $db->insert(word => $row, \%res);
 189                 $row = $query->hash;
 190         } or do {
 191                 Alert("Entry could not be saved", $@);
 192                 next;
 193         };
 194
 195         eval {
 196                 while (my ($lang, $val) = each %post) {
 197                         my $field = $lang;
 198                         $lang =~ s/^trans-// or next;
 199                         $val = parseinput($val) or next;
 200                         my %subrow = (
 201                                 ref   => $row->{id},
 202                                 lang  => $lang,
 203                                 form  => $val,
 204                                 prio  => undef,
 205                         );
 206                         $subrow{wptitle} = $1 if $subrow{form} =~ s/\h*\[(.*)\]$//; # [Link] shorthand
 207                         $subrow{alt} = [split m{/}, $1] if $subrow{form} =~ s{/(\S.*)}{}; # /alternates shorthand
 208                         $db->insert(word => \%subrow);
 209                         delete $fields{$field};
 210                 }
 211                 return 1;
 212         } or Alert('Error creating translation entries', $@);
 213
 214         require Shiar_Sheet::ImagePrep;
 215         my $image = Shiar_Sheet::ImagePrep->new($wordcol{source}->{-src}->($row));
 216         my $reimage = eval {
 217                 ($imagecol->{source} // '') ne ($replace->{source} // '') or return;
 218                 $image->download($imagecol->{source});
 219         };
 220         !$@ or Alert(["Source image not found", $@]);
 221
 222         $reimage ||= $row->{image} ~~ $replace->{image};  # different source
 223         $reimage ||= $row->{cover} ~~ $replace->{cover};  # resize
 224         $reimage++ if $fields{rethumb};  # force refresh
 225         if ($reimage) {
 226                 eval {
 227                         $image->generate($wordcol{convert}->{-src}->($row), $imagecol);
 228                 } or do {
 229                         my ($warn, @details) = ref $@ ? @{$@} : $@;
 230                         Alert([ "Thumbnail image not generated", $warn ], @details);
 231                 };
 232         }
 233 }}
 234 else {
 235         $row->{lang} //= $user->{editlang}->[0] unless exists $row->{lang};
 236         $row->{$_} = $get{$_} for keys %get;
 237         $row->{prio} = defined $row->{ref} ? undef : 4 unless exists $row->{prio};
 238 }
 239
 240 eval {
 241         my $imagerow = $row->{image} && JSON->new->decode(delete $row->{image}) || {};
 242         while (my ($col, $val) = each %{$imagerow}) {
 243                 $row->{$col} = $val;
 244         }
 245         1;
 246 } or Alert("Error decoding image metadata", $@);
 247
 248 my $title = $row->{id} ? "entry <small>#$row->{id}</small>" : 'new entry';
 249 bless $row, 'Shiar_Sheet::FormRow';
 250 :>
 251 <h1>Words <:= $title :></h1>
 252
 253 <div class="inline">
 254
 255 <form action="?" method="post">
 256 <input id="id" name="id" value="<:= $row->{id} // '' :>" type="hidden" />
 257 <ul>
 258 <:
 259 for my $col (@wordcols) {
 260         my $info = $wordcol{$col} or next;
 261         my ($attr, @span) = ref $info eq 'ARRAY' ? @{$info} : $info;
 262         next if delete $attr->{hidden} and not $row->{$col};
 263         my $title = ref $attr ? delete $attr->{-label} : $attr;
 264         printf '<li><label for="%s">%s</label><p>', $col, $title;
 265                 printf '<span class=inline>';
 266                 print $row->input($col => $attr);
 267                 if (my $imgsrc = $attr->{-src}) {
 268                         my $hide = $col eq 'source';
 269                         printf '<span id="%spreview">', $col unless $hide;
 270                         printf('<img src="/%s" alt="%s"%s />',
 271                                 $_, $row->{form}, $hide && qq( id="${col}preview" hidden)
 272                         ) for grep { -e } $imgsrc->($row);
 273                         printf '</span>' unless $hide;
 274                 }
 275                 print $row->input($_ => delete $wordcol{$_}) for @span;
 276                 print '</span>';
 277         say '</p></li>';
 278 }
 279
 280 if (not $row->{ref}) {
 281         printf '<li><label for="%s">%s</label><div><ul class="inline multiinput" id="%1$s">',
 282                 'trans', 'Translations';
 283         my @children = !$row->{id} ? () :
 284                 $db->select(word => '*', {ref => $row->{id}}, 'lang, id')->hashes;
 285         while (my ($lang, $val) = each %fields) {
 286                 $lang =~ s/^trans-// or next;
 287                 push @children, { lang => $lang, form => $val };
 288         }
 289         my %existing = map { $_->{lang} => 1 } $row, @children;
 290         $existing{$_} or push @children, { lang => $_ } for @{$user->{editlang}};
 291
 292         for my $ref (@children) {
 293                 printf(
 294                         '<li><label for="%s" title="%3$s">%s </label>',
 295                         "trans-$ref->{lang}", @{$lang{ $ref->{lang} }}, # flag, name
 296                 );
 297                 printf(
 298                         $ref->{id} ? '<a id="%s" href="%s">%s</a></li>' :
 299                         '<input id="%s" name="%1$s" value="%3$s" />',
 300                         "trans-$ref->{lang}", "$editorurl/$ref->{id}", Entity($ref->{form} // ''),
 301                 );
 302         }
 303         say '</ul></div></li>';
 304 }
 305 :>
 306 </ul>
 307 <p>
 308         <input type="submit" value="Save" />
 309         <input type="submit" value="New" formaction="<:= $editorurl :>?copy=cat" />
 310 </p>
 311 </form>
 312
 313 <:
 314 if ($row->{id}) {
 315 :>
 316 <section id="nav">
 317 <h2>Hierarchy</h2>
 318
 319 <:
 320 say '<ul>';
 321 my $parents = $db->select(word => '*', [{id => $row->{cat}}, {id => $row->{ref}}]);
 322 while (my $ref = $parents->hash) {
 323         printf '<li><a href="%s/%d">%s</a></li>', $editorurl, $ref->{id}, Entity($ref->{form});
 324 }
 325 say "<li><strong>$_</strong></li>" for Entity($row->{form});
 326 my $children = $db->select(word => '*', {cat => $row->{id}, ref => undef}, 'grade, id');
 327 while (my $ref = $children->hash) {
 328         printf '<li><a href="%s/%d">%s</a></li>', $editorurl, $ref->{id}, Entity($ref->{form});
 329 }
 330 :>
 331 <li><form action="<:= $editorurl :>">
 332         <input type="hidden" name="cat" value="<:= $row->{id} :>" />
 333         <input type="hidden" name="lang" value="<:= $row->{lang} :>" />
 334         <input type="submit" value="Add" />
 335 </form></li>
 336 </ul>
 337
 338 <form id="search">
 339         <input type="search" name="q" value="" placeholder="search" /><button type="submit">🔍</button>
 340 </form>
 341 </section>
 342 <:
 343 }
 344 :>
 345 </div>