barcat

   1 #!/usr/bin/env perl
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.03';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s',
  21         'human-readable|H!',
  22         'interval|t:i',
  23         'trim|length|l=s' => sub {
  24                 my ($optname, $optval) = @_;
  25                 $optval =~ s/%$// and $opt{trimpct}++;
  26                 $optval =~ m/^-?[0-9]+$/ or die(
  27                         "Value \"$optval\" invalid for option $optname",
  28                         " (number or percentage expected)\n"
  29                 );
  30                 $opt{trim} = $optval;
  31         },
  32         'value-length=i',
  33         'hidemin=i',
  34         'hidemax=i',
  35         'limit|L=s' => sub {
  36                 my ($optname, $optval) = @_;
  37                 $optval ||= 0;
  38                 ($opt{hidemin}, $opt{hidemax}) =
  39                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  40                         "Value \"$optval\" invalid for option limit",
  41                         " (range expected)\n"
  42                 );
  43         },
  44         'markers|m=s',
  45         'unmodified|u!',
  46         'width|w=i',
  47         'usage|h' => sub { podexit() },
  48         'help'    => sub { podexit(-verbose => 2) },
  49 ) or exit 64;  # EX_USAGE
  50
  51 $opt{width} ||= $ENV{COLUMNS} || 80;
  52 $opt{color} //= -t *STDOUT;  # enable on tty
  53 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  54 $opt{units}   = $opt{'human-readable'} && ['', qw( k M G T P E Z Y y z a f p n μ m )];
  55
  56 if (defined $opt{interval}) {
  57         $opt{interval} ||= 1;
  58         $SIG{ALRM} = sub {
  59                 show_lines();
  60                 alarm $opt{interval};
  61         };
  62         alarm $opt{interval};
  63 }
  64
  65 $SIG{INT} = 'IGNORE';  # continue after assumed eof
  66
  67 my (@lines, @values);
  68 my $anchor = !defined $opt{field} ? qr/\A/ :
  69         $opt{field} =~ /^[0-9]+$/ ? qr/(?:\S*\h+){$opt{field}}\K/ :
  70         $opt{field};
  71 while (readline) {
  72         s/\r?\n\z//;
  73         s/^\h*// unless $opt{unmodified};
  74         push @values, s/$anchor ( \h* -? [0-9]* \.? [0-9]+ |)/\n/x && $1;
  75         if (defined $opt{trim}) {
  76                 my $trimpos = abs $opt{trim};
  77                 if ($trimpos <= 1) {
  78                         $_ = substr $_, 0, 1;
  79                 }
  80                 elsif (length > $trimpos) {
  81                         substr($_, $trimpos - 1) = '…';
  82                 }
  83         }
  84         push @lines, $_;
  85 }
  86
  87 $SIG{INT} = 'DEFAULT';
  88
  89 sub show_lines {
  90
  91 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
  92 @lines and @lines > $nr or return;
  93
  94 my @order  = sort { $b <=> $a } grep { length } @values;
  95 my $maxval = $opt{hidemax} ? max @values[0 .. $opt{hidemax} - 1] : $order[0];
  96 my $minval = min $order[-1], 0;
  97 my $lenval = $opt{'value-length'} // max map { length } @order;
  98 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
  99         max map { length $values[$_] && length $lines[$_] }
 100                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 101 my $size   = ($maxval - $minval) &&
 102         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 103
 104 my @barmark;
 105 if ($opt{markers} // 1 and $size > 0) {
 106         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 107         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 108         $barmark[ orderpos($#order * .31731) ] = '>';
 109         $barmark[ orderpos($#order * .68269) ] = '<';
 110         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 111         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 112         defined and $opt{color} and $_ = "\e[36m$_\e[0m" for @barmark;
 113
 114         state $lastmax = $maxval;
 115         if ($maxval > $lastmax) {
 116                 print ' ' x ($lenval + $len);
 117                 printf "\e[90m" if $opt{color};
 118                 printf '%-*s',
 119                         ($lastmax - $minval) * $size + .5,
 120                         '-' x (($values[$nr - 1] - $minval) * $size);
 121                 print "\e[92m" if $opt{color};
 122                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 123                 print "\e[0m" if $opt{color};
 124                 $lastmax = $maxval;
 125         }
 126 }
 127
 128 sub sival {
 129         my $unit = int(log($_[0]) / log(1000) - ($_[0] < 1));
 130         sprintf "%3.1f%1s", $_[0] / 1000 ** $unit,
 131                 $#{$opt{units}} >> 1 < abs $unit ? "e$unit" : $opt{units}->[$unit];
 132 }
 133
 134 while ($nr <= $#lines) {
 135         $nr >= $opt{hidemax} and last if $opt{hidemax};
 136         my $val = $values[$nr];
 137         if (length $val) {
 138                 my $color = !$opt{color} ? 0 :
 139                         $val == $order[0] ? 32 : # max
 140                         $val == $order[-1] ? 31 : # min
 141                         90;
 142                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 143                 $val = "\e[${color}m$val\e[0m" if $color;
 144         }
 145         my $line = $lines[$nr] =~ s/\n/$val/r;
 146         printf '%-*s', $len + length($val), $line;
 147         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 148         say '';
 149
 150         $nr++;
 151 }
 152
 153 }
 154 show_lines();
 155
 156 __END__
 157
 158 =head1 NAME
 159
 160 barcat - graph to visualize input values
 161
 162 =head1 SYNOPSIS
 163
 164 B<barcat> [<options>] [<input>]
 165
 166 =head1 DESCRIPTION
 167
 168 Visualizes relative sizes of values read from input (file(s) or STDIN).
 169 Contents are concatenated similar to I<cat>,
 170 but numbers are reformatted and a bar graph is appended to each line.
 171
 172 =head1 OPTIONS
 173
 174 =over
 175
 176 =item -c, --[no-]color
 177
 178 Force colored output of values and bar markers.
 179 Defaults on if output is a tty,
 180 disabled otherwise such as when piped or redirected.
 181
 182 =item -f, --field=(<number>|<regexp>)
 183
 184 Compare values after a given number of whitespace separators,
 185 or matching a regular expression.
 186
 187 Unspecified or I<-f0> means values are at the start of each line.
 188 With I<-f1> the second word is taken instead.
 189 A string can indicate the starting position of a value
 190 (such as I<-f:> if preceded by colons),
 191 or capture the numbers itself,
 192 for example I<-f'(\d+)'> for the first digits anywhere.
 193
 194 =item -H, --human-readable
 195
 196 Format values using SI unit prefixes,
 197 turning long numbers like I<12356789> into I<12.4M>.
 198
 199 =item -t, --interval[=<seconds>]
 200
 201 Interval time to output partial progress.
 202
 203 =item -l, --length=[-]<size>[%]
 204
 205 Trim line contents (between number and bars)
 206 to a maximum number of characters.
 207 The exceeding part is replaced by an abbreviation sign,
 208 unless C<--length=0>.
 209
 210 Prepend a dash (i.e. make negative) to enforce padding
 211 regardless of encountered contents.
 212
 213 =item -L, --limit=(<count>|<start>-[<end>])
 214
 215 Stop output after a number of lines.
 216 All input is still counted and analyzed for statistics,
 217 but disregarded for padding and bar size.
 218
 219 =item -m, --markers=
 220
 221 Statistical positions to indicate on bars.
 222 Cannot be customized yet,
 223 only disabled by providing an empty argument.
 224
 225 Any value enables all marker characters:
 226
 227 =over 2
 228
 229 =item B<=>
 230
 231 Average:
 232 the sum of all values divided by the number of counted lines.
 233
 234 =item B<+>
 235
 236 Mean, median:
 237 the middle value or average between middle values.
 238
 239 =item B<<>
 240
 241 Standard deviation left of the mean.
 242 Only 16% of all values are lower.
 243
 244 =item B<< > >>
 245
 246 Standard deviation right of the mean.
 247 The part between B<< <--> >> encompass all I<normal> results,
 248 or 68% of all entries.
 249
 250 =back
 251
 252 =item -u, --unmodified
 253
 254 Do not strip leading whitespace.
 255 Keep original value alignment, which may be significant in some programs.
 256
 257 =item --value-length=<size>
 258
 259 Reserved space for numbers.
 260
 261 =item -w, --width=<columns>
 262
 263 Override the maximum number of columns to use.
 264 Appended graphics will extend to fill up the entire screen.
 265
 266 =back
 267
 268 =head1 EXAMPLES
 269
 270 Commonly used after counting, such as users on the current server:
 271
 272     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 273
 274 Letter frequencies in text files:
 275
 276     cat /usr/share/games/fortunes/*.u8 |
 277     perl -CO -nE 'say for grep length, split /\PL*/, uc' |
 278     sort | uniq -c | barcat
 279
 280 Memory usage of user processes:
 281
 282     ps xo %mem,pid,cmd | barcat -l40
 283
 284 Sizes (in megabytes) of all root files and directories:
 285
 286     du -d0 -m * | barcat
 287
 288 Number of HTTP requests per day:
 289
 290     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 291
 292 Any kind of database query with leading counts:
 293
 294     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 295     psql -t | barcat -u
 296
 297 Exchange rate USD/EUR history from CSV download provided by ECB:
 298
 299     curl https://sdw.ecb.europa.eu/export.do \
 300          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 301     grep '^[12]' | barcat -f',\K' --value-length=7
 302
 303 Total population history from the World Bank dataset (XML):
 304
 305     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 306     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 307     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 308
 309 Movies per year from prepared JSON data:
 310
 311     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 312     jq '.[].year' | uniq -c | barcat
 313
 314 Pokémon height comparison:
 315
 316         curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 317         jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 318
 319 Git statistics, such commit count by year:
 320
 321     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 322
 323 Or the most frequent authors:
 324
 325     git shortlog -sn | barcat -L3
 326
 327 Latency history:
 328
 329     ping google.com | barcat -f'time=\K' -t
 330
 331 =head1 AUTHOR
 332
 333 Mischa POSLAWSKY <perl@shiar.org>
 334
 335 =head1 LICENSE
 336
 337 GPL3+.