barcat

   1 #!/usr/bin/perl -CA
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.04';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s' => sub {
  21                 eval {
  22                         local $_ = $_[1];
  23                         $opt{anchor} = /^[0-9]+$/ ? qr/(?:\S*\h+){$_}\K/ : qr/$_/;
  24                 } or die $@ =~ s/(?: at .+)?$/ for option $_[0]/r;
  25         },
  26         'human-readable|H!',
  27         'interval|t:i',
  28         'trim|length|l=s' => sub {
  29                 my ($optname, $optval) = @_;
  30                 $optval =~ s/%$// and $opt{trimpct}++;
  31                 $optval =~ m/^-?[0-9]+$/ or die(
  32                         "Value \"$optval\" invalid for option $optname",
  33                         " (number or percentage expected)\n"
  34                 );
  35                 $opt{trim} = $optval;
  36         },
  37         'value-length=i',
  38         'hidemin=i',
  39         'hidemax=i',
  40         'limit|L=s' => sub {
  41                 my ($optname, $optval) = @_;
  42                 $optval ||= 0;
  43                 ($opt{hidemin}, $opt{hidemax}) =
  44                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  45                         "Value \"$optval\" invalid for option limit",
  46                         " (range expected)\n"
  47                 );
  48         },
  49         'markers|m=s',
  50         'spark:s' => sub {
  51                 $opt{spark} = [split //, $_[1] || '⎽▁▂▃▄▅▆▇█'];
  52         },
  53         'stat|s!',
  54         'unmodified|u!',
  55         'width|w=i',
  56         'usage|h' => sub { podexit() },
  57         'help'    => sub { podexit(-verbose => 2) },
  58 ) or exit 64;  # EX_USAGE
  59
  60 $opt{width} ||= $ENV{COLUMNS} || 80;
  61 $opt{color} //= -t *STDOUT;  # enable on tty
  62 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  63 $opt{units}   = [split //, ' kMGTPEZYyzafpnμm'] if $opt{'human-readable'};
  64 $opt{anchor} //= qr/\A/;
  65 $opt{'value-length'} = 6 if $opt{units};
  66 $opt{'value-length'} = 1 if $opt{unmodified};
  67
  68 my (@lines, @values, @order);
  69
  70 if (defined $opt{interval}) {
  71         $opt{interval} ||= 1;
  72         $SIG{ALRM} = sub {
  73                 show_lines();
  74                 alarm $opt{interval};
  75         };
  76         alarm $opt{interval};
  77
  78         eval {
  79                 require Tie::Array::Sorted;
  80                 tie @order, 'Tie::Array::Sorted', sub { $_[1] <=> $_[0] };
  81         } or warn $@, "Expect slowdown with large datasets!\n";
  82 }
  83
  84 $SIG{INT} = sub {
  85         $SIG{INT} = 'DEFAULT';  # reset for subsequent attempts
  86         'IGNORE' # continue after assumed eof
  87 };
  88
  89 my $valmatch = qr/$opt{anchor} ( \h* -? [0-9]* \.? [0-9]+ (?: e[+-]?[0-9]+ )? |)/x;
  90 while (readline) {
  91         s/\r?\n\z//;
  92         s/^\h*// unless $opt{unmodified};
  93         push @values, s/$valmatch/\n/ && $1;
  94         push @order, $1 if length $1;
  95         if (defined $opt{trim} and defined $1) {
  96                 my $trimpos = abs $opt{trim};
  97                 $trimpos -= length $1 if $opt{unmodified};
  98                 if ($trimpos <= 1) {
  99                         $_ = substr $_, 0, 1;
 100                 }
 101                 elsif (length > $trimpos) {
 102                         substr($_, $trimpos - 1) = '…';
 103                 }
 104         }
 105         push @lines, $_;
 106 }
 107
 108 $SIG{INT} = 'DEFAULT';
 109
 110 sub color {
 111         $opt{color} and defined $_[0] or return '';
 112         return "\e[$_[0]m" if defined wantarray;
 113         $_ = color(@_) . $_ . color(0) if defined;
 114 }
 115
 116 sub show_lines {
 117
 118 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
 119 @lines and @lines > $nr or return;
 120 @lines or return;
 121 @lines > $nr or return unless $opt{hidemin};
 122
 123 @order = sort { $b <=> $a } @order unless tied @order;
 124 my $maxval = ($opt{hidemax} ? max grep { length } @values[0 .. $opt{hidemax} - 1] : $order[0]) // 0;
 125 my $minval = min $order[-1] // (), 0;
 126 my $lenval = $opt{'value-length'} // max map { length } @order;
 127 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
 128         max map { length $values[$_] && length $lines[$_] }
 129                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 130 my $size   = ($maxval - $minval) &&
 131         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 132
 133 my @barmark;
 134 if ($opt{markers} // 1 and $size > 0) {
 135         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 136         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 137         $barmark[ orderpos($#order * .31731) ] = '>';
 138         $barmark[ orderpos($#order * .68269) ] = '<';
 139         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 140         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 141         color(36) for @barmark;
 142
 143         state $lastmax = $maxval;
 144         if ($maxval > $lastmax) {
 145                 print ' ' x ($lenval + $len);
 146                 printf color(90);
 147                 printf '%-*s',
 148                         ($lastmax - $minval) * $size + .5,
 149                         '-' x (($values[$nr - 1] - $minval) * $size);
 150                 print color(92);
 151                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 152                 print color(0);
 153                 $lastmax = $maxval;
 154         }
 155 }
 156
 157 @lines > $nr or return if $opt{hidemin};
 158
 159 sub sival {
 160         my $unit = int(log(abs $_[0] || 1) / log(10) - 3*($_[0] < 1) + 1e-15);
 161         my $float = $_[0] !~ /^0*[-0-9]{1,3}$/;
 162         sprintf('%3.*f%1s',
 163                 $float && ($unit % 3) == ($unit < 0),  # tenths
 164                 $_[0] / 1000 ** int($unit/3),   # number
 165                 $#{$opt{units}} * 1.5 < abs $unit ? "e$unit" : $opt{units}->[$unit/3]
 166         );
 167 }
 168
 169 while ($nr <= $#lines) {
 170         $nr >= $opt{hidemax} and last if defined $opt{hidemax};
 171         my $val = $values[$nr];
 172
 173         if ($opt{spark}) {
 174                 print $opt{spark}->[ ($val - $minval) / $maxval * $#{$opt{spark}} ];
 175                 next;
 176         }
 177
 178         if (length $val) {
 179                 my $color = !$opt{color} ? undef :
 180                         $val == $order[0] ? 32 : # max
 181                         $val == $order[-1] ? 31 : # min
 182                         90;
 183                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 184                 color($color) for $val;
 185         }
 186         my $line = $lines[$nr] =~ s/\n/$val/r;
 187         printf '%-*s', $len + length($val), $line;
 188         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 189         say '';
 190 }
 191 continue {
 192         $nr++;
 193 }
 194 say '' if $opt{spark};
 195
 196 }
 197 show_lines();
 198
 199 if ($opt{stat}) {
 200         if ($opt{hidemin} or $opt{hidemax}) {
 201                 $opt{hidemin} ||= 1;
 202                 $opt{hidemax} ||= @lines;
 203                 printf '%s of ', sum(@values[$opt{hidemin} - 1 .. $opt{hidemax} - 1]) // 0;
 204         }
 205         if (@order) {
 206                 my $total = sum @order;
 207                 printf '%s total', $total;
 208                 printf ' in %d values', scalar @values;
 209                 printf ' (%s min, %*.*f avg, %s max)',
 210                         $order[-1], 0, 2, $total / @order, $order[0];
 211         }
 212         say '';
 213 }
 214
 215 __END__
 216 =encoding utf8
 217
 218 =head1 NAME
 219
 220 barcat - graph to visualize input values
 221
 222 =head1 SYNOPSIS
 223
 224 B<barcat> [<options>] [<input>]
 225
 226 =head1 DESCRIPTION
 227
 228 Visualizes relative sizes of values read from input (file(s) or STDIN).
 229 Contents are concatenated similar to I<cat>,
 230 but numbers are reformatted and a bar graph is appended to each line.
 231
 232 =head1 OPTIONS
 233
 234 =over
 235
 236 =item -c, --[no-]color
 237
 238 Force colored output of values and bar markers.
 239 Defaults on if output is a tty,
 240 disabled otherwise such as when piped or redirected.
 241
 242 =item -f, --field=(<number>|<regexp>)
 243
 244 Compare values after a given number of whitespace separators,
 245 or matching a regular expression.
 246
 247 Unspecified or I<-f0> means values are at the start of each line.
 248 With I<-f1> the second word is taken instead.
 249 A string can indicate the starting position of a value
 250 (such as I<-f:> if preceded by colons),
 251 or capture the numbers itself,
 252 for example I<-f'(\d+)'> for the first digits anywhere.
 253
 254 =item -H, --human-readable
 255
 256 Format values using SI unit prefixes,
 257 turning long numbers like I<12356789> into I<12.4M>.
 258 Also changes an exponent I<1.602176634e-19> to I<160.2z>.
 259 Short integers are aligned but kept without decimal point.
 260
 261 =item -t, --interval[=<seconds>]
 262
 263 Interval time to output partial progress.
 264
 265 =item -l, --length=[-]<size>[%]
 266
 267 Trim line contents (between number and bars)
 268 to a maximum number of characters.
 269 The exceeding part is replaced by an abbreviation sign,
 270 unless C<--length=0>.
 271
 272 Prepend a dash (i.e. make negative) to enforce padding
 273 regardless of encountered contents.
 274
 275 =item -L, --limit=(<count>|<start>-[<end>])
 276
 277 Stop output after a number of lines.
 278 All input is still counted and analyzed for statistics,
 279 but disregarded for padding and bar size.
 280
 281 =item -m, --markers=
 282
 283 Statistical positions to indicate on bars.
 284 Cannot be customized yet,
 285 only disabled by providing an empty argument.
 286
 287 Any value enables all marker characters:
 288
 289 =over 2
 290
 291 =item B<=>
 292
 293 Average:
 294 the sum of all values divided by the number of counted lines.
 295
 296 =item B<+>
 297
 298 Mean, median:
 299 the middle value or average between middle values.
 300
 301 =item B<<>
 302
 303 Standard deviation left of the mean.
 304 Only 16% of all values are lower.
 305
 306 =item B<< > >>
 307
 308 Standard deviation right of the mean.
 309 The part between B<< <--> >> encompass all I<normal> results,
 310 or 68% of all entries.
 311
 312 =back
 313
 314 =item -s, --stat
 315
 316 Total statistics after all data.
 317
 318 =item -u, --unmodified
 319
 320 Do not reformat values, keeping leading whitespace.
 321 Keep original value alignment, which may be significant in some programs.
 322
 323 =item --value-length=<size>
 324
 325 Reserved space for numbers.
 326
 327 =item -w, --width=<columns>
 328
 329 Override the maximum number of columns to use.
 330 Appended graphics will extend to fill up the entire screen.
 331
 332 =back
 333
 334 =head1 EXAMPLES
 335
 336 Draw a sine wave:
 337
 338     seq 30 | awk '{print sin($1/10)}' | barcat
 339
 340 Compare file sizes (with human-readable numbers):
 341
 342     du -d0 -b * | barcat -H
 343
 344 Memory usage of user processes with long names truncated:
 345
 346     ps xo %mem,pid,cmd | barcat -l40
 347
 348 Monitor network latency from prefixed results:
 349
 350     ping google.com | barcat -f'time=\K' -t
 351
 352 Commonly used after counting, for example users on the current server:
 353
 354     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 355
 356 Letter frequencies in text files:
 357
 358     cat /usr/share/games/fortunes/*.u8 |
 359     perl -CS -nE 'say for grep length, split /\PL*/, uc' |
 360     sort | uniq -c | barcat
 361
 362 Number of HTTP requests per day:
 363
 364     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 365
 366 Any kind of database query with counts, preserving returned alignment:
 367
 368     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 369     psql -t | barcat -u
 370
 371 Earthquakes worldwide magnitude 1+ in the last 24 hours:
 372
 373     https://earthquake.usgs.gov/earthquakes/feed/v1.0/summary/1.0_day.csv |
 374     column -tns, | graph -f4 -u -l80%
 375
 376 External datasets, like movies per year:
 377
 378     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 379     perl -054 -nlE 'say if s/^"year"://' | uniq -c | barcat
 380
 381 But please get I<jq> to process JSON
 382 and replace the manual selection by C<< jq '.[].year' >>.
 383
 384 Pokémon height comparison:
 385
 386     curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 387     jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 388
 389 USD/EUR exchange rate from CSV provided by the ECB:
 390
 391     curl https://sdw.ecb.europa.eu/export.do \
 392          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 393     grep '^[12]' | barcat -f',\K' --value-length=7
 394
 395 Total population history from the World Bank dataset (XML):
 396 External datasets, like total population in XML from the World Bank:
 397
 398     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 399     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 400     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 401
 402 And of course various Git statistics, such commit count by year:
 403
 404     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 405
 406 Or the top 3 most frequent authors with statistics over all:
 407
 408     git shortlog -sn | barcat -L3 -s
 409
 410 Activity of the last days (substitute date C<-v-{}d> on BSD):
 411
 412     ( git log --pretty=%ci --since=30day | cut -b-10
 413       seq 0 30 | xargs -i date +%F -d-{}day ) |
 414     sort | uniq -c | awk '$1--' | graph --spark
 415
 416 =head1 AUTHOR
 417
 418 Mischa POSLAWSKY <perl@shiar.org>
 419
 420 =head1 LICENSE
 421
 422 GPL3+.