barcat

   1 #!/usr/bin/perl -CA
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.05';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s' => sub {
  21                 eval {
  22                         local $_ = $_[1];
  23                         $opt{anchor} = /^[0-9]+$/ ? qr/(?:\S*\h+){$_}\K/ : qr/$_/;
  24                 } or die $@ =~ s/(?: at .+)?$/ for option $_[0]/r;
  25         },
  26         'human-readable|H!',
  27         'interval|t:i',
  28         'trim|length|l=s' => sub {
  29                 my ($optname, $optval) = @_;
  30                 $optval =~ s/%$// and $opt{trimpct}++;
  31                 $optval =~ m/^-?[0-9]+$/ or die(
  32                         "Value \"$optval\" invalid for option $optname",
  33                         " (number or percentage expected)\n"
  34                 );
  35                 $opt{trim} = $optval;
  36         },
  37         'value-length=i',
  38         'hidemin=i',
  39         'hidemax=i',
  40         'limit|L=s' => sub {
  41                 my ($optname, $optval) = @_;
  42                 $optval ||= 0;
  43                 ($opt{hidemin}, $opt{hidemax}) =
  44                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  45                         "Value \"$optval\" invalid for option limit",
  46                         " (range expected)\n"
  47                 );
  48         },
  49         'markers|m=s',
  50         'spark:s' => sub {
  51                 $opt{spark} = [split //, $_[1] || '⎽▁▂▃▄▅▆▇█'];
  52         },
  53         'stat|s!',
  54         'unmodified|u!',
  55         'width|w=i',
  56         'usage|h' => sub {
  57                 local $/;
  58                 my $pod = readline *DATA;
  59                 $pod =~ s/^=over\K/ 22/m;  # indent options list
  60                 $pod =~ s/^=item \N*\n\n\N*\n\K(?:(?:^=over.*?^=back\n)?(?!=)\N*\n)*/\n/msg;
  61
  62                 require Pod::Usage;
  63                 my $parser = Pod::Usage->new;
  64                 $parser->select('SYNOPSIS', 'OPTIONS');
  65                 $parser->output_string(\my $contents);
  66                 $parser->parse_string_document($pod);
  67
  68                 $contents =~ s/\n(?=\n\h)//msg;  # strip space between items
  69                 print $contents;
  70                 exit;
  71         },
  72         'help'    => sub { podexit(-verbose => 2) },
  73 ) or exit 64;  # EX_USAGE
  74
  75 $opt{width} ||= $ENV{COLUMNS} || 80;
  76 $opt{color} //= -t *STDOUT;  # enable on tty
  77 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  78 $opt{units}   = [split //, ' kMGTPEZYyzafpnμm'] if $opt{'human-readable'};
  79 $opt{anchor} //= qr/\A/;
  80 $opt{'value-length'} = 6 if $opt{units};
  81 $opt{'value-length'} = 1 if $opt{unmodified};
  82
  83 my (@lines, @values, @order);
  84
  85 if (defined $opt{interval}) {
  86         $opt{interval} ||= 1;
  87         $SIG{ALRM} = sub {
  88                 show_lines();
  89                 alarm $opt{interval};
  90         };
  91         alarm $opt{interval};
  92
  93         eval {
  94                 require Tie::Array::Sorted;
  95                 tie @order, 'Tie::Array::Sorted', sub { $_[1] <=> $_[0] };
  96         } or warn $@, "Expect slowdown with large datasets!\n";
  97 }
  98
  99 $SIG{INT} = sub {
 100         $SIG{INT} = 'DEFAULT';  # reset for subsequent attempts
 101         'IGNORE' # continue after assumed eof
 102 };
 103
 104 my $valmatch = qr/$opt{anchor} ( \h* -? [0-9]* \.? [0-9]+ (?: e[+-]?[0-9]+ )? |)/x;
 105 while (readline) {
 106         s/\r?\n\z//;
 107         s/^\h*// unless $opt{unmodified};
 108         push @values, s/$valmatch/\n/ && $1;
 109         push @order, $1 if length $1;
 110         if (defined $opt{trim} and defined $1) {
 111                 my $trimpos = abs $opt{trim};
 112                 $trimpos -= length $1 if $opt{unmodified};
 113                 if ($trimpos <= 1) {
 114                         $_ = substr $_, 0, 1;
 115                 }
 116                 elsif (length > $trimpos) {
 117                         substr($_, $trimpos - 1) = '…';
 118                 }
 119         }
 120         push @lines, $_;
 121 }
 122
 123 $SIG{INT} = 'DEFAULT';
 124
 125 sub color {
 126         $opt{color} and defined $_[0] or return '';
 127         return "\e[$_[0]m" if defined wantarray;
 128         $_ = color(@_) . $_ . color(0) if defined;
 129 }
 130
 131 sub show_lines {
 132
 133 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
 134 @lines and @lines > $nr or return;
 135 @lines or return;
 136 @lines > $nr or return unless $opt{hidemin};
 137
 138 @order = sort { $b <=> $a } @order unless tied @order;
 139 my $maxval = ($opt{hidemax} ? max grep { length } @values[0 .. $opt{hidemax} - 1] : $order[0]) // 0;
 140 my $minval = min $order[-1] // (), 0;
 141 my $lenval = $opt{'value-length'} // max map { length } @order;
 142 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
 143         max map { length $values[$_] && length $lines[$_] }
 144                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 145 my $size   = ($maxval - $minval) &&
 146         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 147
 148 my @barmark;
 149 if ($opt{markers} // 1 and $size > 0) {
 150         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 151         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 152         $barmark[ orderpos($#order * .31731) ] = '>';
 153         $barmark[ orderpos($#order * .68269) ] = '<';
 154         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 155         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 156         color(36) for @barmark;
 157
 158         state $lastmax = $maxval;
 159         if ($maxval > $lastmax) {
 160                 print ' ' x ($lenval + $len);
 161                 printf color(90);
 162                 printf '%-*s',
 163                         ($lastmax - $minval) * $size + .5,
 164                         '-' x (($values[$nr - 1] - $minval) * $size);
 165                 print color(92);
 166                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 167                 print color(0);
 168                 $lastmax = $maxval;
 169         }
 170 }
 171
 172 @lines > $nr or return if $opt{hidemin};
 173
 174 sub sival {
 175         my $unit = int(log(abs $_[0] || 1) / log(10) - 3*($_[0] < 1) + 1e-15);
 176         my $float = $_[0] !~ /^0*[-0-9]{1,3}$/;
 177         sprintf('%3.*f%1s',
 178                 $float && ($unit % 3) == ($unit < 0),  # tenths
 179                 $_[0] / 1000 ** int($unit/3),   # number
 180                 $#{$opt{units}} * 1.5 < abs $unit ? "e$unit" : $opt{units}->[$unit/3]
 181         );
 182 }
 183
 184 while ($nr <= $#lines) {
 185         $nr >= $opt{hidemax} and last if defined $opt{hidemax};
 186         my $val = $values[$nr];
 187
 188         if ($opt{spark}) {
 189                 print $opt{spark}->[ ($val - $minval) / $maxval * $#{$opt{spark}} ];
 190                 next;
 191         }
 192
 193         if (length $val) {
 194                 my $color = !$opt{color} ? undef :
 195                         $val == $order[0] ? 32 : # max
 196                         $val == $order[-1] ? 31 : # min
 197                         90;
 198                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 199                 color($color) for $val;
 200         }
 201         my $line = $lines[$nr] =~ s/\n/$val/r;
 202         printf '%-*s', $len + length($val), $line;
 203         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 204         say '';
 205 }
 206 continue {
 207         $nr++;
 208 }
 209 say '' if $opt{spark};
 210
 211 }
 212 show_lines();
 213
 214 if ($opt{stat}) {
 215         if ($opt{hidemin} or $opt{hidemax}) {
 216                 $opt{hidemin} ||= 1;
 217                 $opt{hidemax} ||= @lines;
 218                 printf '%s of ', sum(@values[$opt{hidemin} - 1 .. $opt{hidemax} - 1]) // 0;
 219         }
 220         if (@order) {
 221                 my $total = sum @order;
 222                 printf '%s total', $total;
 223                 printf ' in %d values', scalar @values;
 224                 printf ' (%s min, %*.*f avg, %s max)',
 225                         $order[-1], 0, 2, $total / @order, $order[0];
 226         }
 227         say '';
 228 }
 229
 230 __END__
 231 =encoding utf8
 232
 233 =head1 NAME
 234
 235 barcat - graph to visualize input values
 236
 237 =head1 SYNOPSIS
 238
 239 B<barcat> [<options>] [<input>]
 240
 241 =head1 DESCRIPTION
 242
 243 Visualizes relative sizes of values read from input (file(s) or STDIN).
 244 Contents are concatenated similar to I<cat>,
 245 but numbers are reformatted and a bar graph is appended to each line.
 246
 247 =head1 OPTIONS
 248
 249 =over
 250
 251 =item -c, --[no-]color
 252
 253 Force colored output of values and bar markers.
 254 Defaults on if output is a tty,
 255 disabled otherwise such as when piped or redirected.
 256
 257 =item -f, --field=(<number>|<regexp>)
 258
 259 Compare values after a given number of whitespace separators,
 260 or matching a regular expression.
 261
 262 Unspecified or I<-f0> means values are at the start of each line.
 263 With I<-f1> the second word is taken instead.
 264 A string can indicate the starting position of a value
 265 (such as I<-f:> if preceded by colons),
 266 or capture the numbers itself,
 267 for example I<-f'(\d+)'> for the first digits anywhere.
 268
 269 =item -H, --human-readable
 270
 271 Format values using SI unit prefixes,
 272 turning long numbers like I<12356789> into I<12.4M>.
 273 Also changes an exponent I<1.602176634e-19> to I<160.2z>.
 274 Short integers are aligned but kept without decimal point.
 275
 276 =item -t, --interval[=<seconds>]
 277
 278 Interval time to output partial progress.
 279
 280 =item -l, --length=[-]<size>[%]
 281
 282 Trim line contents (between number and bars)
 283 to a maximum number of characters.
 284 The exceeding part is replaced by an abbreviation sign,
 285 unless C<--length=0>.
 286
 287 Prepend a dash (i.e. make negative) to enforce padding
 288 regardless of encountered contents.
 289
 290 =item -L, --limit=(<count>|<start>-[<end>])
 291
 292 Stop output after a number of lines.
 293 All input is still counted and analyzed for statistics,
 294 but disregarded for padding and bar size.
 295
 296 =item -m, --markers=
 297
 298 Statistical positions to indicate on bars.
 299 Cannot be customized yet,
 300 only disabled by providing an empty argument.
 301
 302 Any value enables all marker characters:
 303
 304 =over 2
 305
 306 =item B<=>
 307
 308 Average:
 309 the sum of all values divided by the number of counted lines.
 310
 311 =item B<+>
 312
 313 Mean, median:
 314 the middle value or average between middle values.
 315
 316 =item B<<>
 317
 318 Standard deviation left of the mean.
 319 Only 16% of all values are lower.
 320
 321 =item B<< > >>
 322
 323 Standard deviation right of the mean.
 324 The part between B<< <--> >> encompass all I<normal> results,
 325 or 68% of all entries.
 326
 327 =back
 328
 329 =item -s, --stat
 330
 331 Total statistics after all data.
 332
 333 =item -u, --unmodified
 334
 335 Do not reformat values, keeping leading whitespace.
 336 Keep original value alignment, which may be significant in some programs.
 337
 338 =item --value-length=<size>
 339
 340 Reserved space for numbers.
 341
 342 =item -w, --width=<columns>
 343
 344 Override the maximum number of columns to use.
 345 Appended graphics will extend to fill up the entire screen.
 346
 347 =back
 348
 349 =head1 EXAMPLES
 350
 351 Draw a sine wave:
 352
 353     seq 30 | awk '{print sin($1/10)}' | barcat
 354
 355 Compare file sizes (with human-readable numbers):
 356
 357     du -d0 -b * | barcat -H
 358
 359 Memory usage of user processes with long names truncated:
 360
 361     ps xo %mem,pid,cmd | barcat -l40
 362
 363 Monitor network latency from prefixed results:
 364
 365     ping google.com | barcat -f'time=\K' -t
 366
 367 Commonly used after counting, for example users on the current server:
 368
 369     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 370
 371 Letter frequencies in text files:
 372
 373     cat /usr/share/games/fortunes/*.u8 |
 374     perl -CS -nE 'say for grep length, split /\PL*/, uc' |
 375     sort | uniq -c | barcat
 376
 377 Number of HTTP requests per day:
 378
 379     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 380
 381 Any kind of database query with counts, preserving returned alignment:
 382
 383     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 384     psql -t | barcat -u
 385
 386 Earthquakes worldwide magnitude 1+ in the last 24 hours:
 387
 388     https://earthquake.usgs.gov/earthquakes/feed/v1.0/summary/1.0_day.csv |
 389     column -tns, | graph -f4 -u -l80%
 390
 391 External datasets, like movies per year:
 392
 393     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 394     perl -054 -nlE 'say if s/^"year"://' | uniq -c | barcat
 395
 396 But please get I<jq> to process JSON
 397 and replace the manual selection by C<< jq '.[].year' >>.
 398
 399 Pokémon height comparison:
 400
 401     curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 402     jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 403
 404 USD/EUR exchange rate from CSV provided by the ECB:
 405
 406     curl https://sdw.ecb.europa.eu/export.do \
 407          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 408     grep '^[12]' | barcat -f',\K' --value-length=7
 409
 410 Total population history from the World Bank dataset (XML):
 411 External datasets, like total population in XML from the World Bank:
 412
 413     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 414     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 415     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 416
 417 And of course various Git statistics, such commit count by year:
 418
 419     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 420
 421 Or the top 3 most frequent authors with statistics over all:
 422
 423     git shortlog -sn | barcat -L3 -s
 424
 425 Activity of the last days (substitute date C<-v-{}d> on BSD):
 426
 427     ( git log --pretty=%ci --since=30day | cut -b-10
 428       seq 0 30 | xargs -i date +%F -d-{}day ) |
 429     sort | uniq -c | awk '$1--' | graph --spark
 430
 431 =head1 AUTHOR
 432
 433 Mischa POSLAWSKY <perl@shiar.org>
 434
 435 =head1 LICENSE
 436
 437 GPL3+.