barcat

   1 #!/usr/bin/env perl
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.03';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s' => sub {
  21                 eval {
  22                         local $_ = $_[1];
  23                         $opt{anchor} = /^[0-9]+$/ ? qr/(?:\S*\h+){$_}\K/ : qr/$_/;
  24                 } or die "$@ for option $_[0]\n";
  25         },
  26         'human-readable|H!',
  27         'interval|t:i',
  28         'trim|length|l=s' => sub {
  29                 my ($optname, $optval) = @_;
  30                 $optval =~ s/%$// and $opt{trimpct}++;
  31                 $optval =~ m/^-?[0-9]+$/ or die(
  32                         "Value \"$optval\" invalid for option $optname",
  33                         " (number or percentage expected)\n"
  34                 );
  35                 $opt{trim} = $optval;
  36         },
  37         'value-length=i',
  38         'hidemin=i',
  39         'hidemax=i',
  40         'limit|L=s' => sub {
  41                 my ($optname, $optval) = @_;
  42                 $optval ||= 0;
  43                 ($opt{hidemin}, $opt{hidemax}) =
  44                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  45                         "Value \"$optval\" invalid for option limit",
  46                         " (range expected)\n"
  47                 );
  48         },
  49         'markers|m=s',
  50         'unmodified|u!',
  51         'width|w=i',
  52         'usage|h' => sub { podexit() },
  53         'help'    => sub { podexit(-verbose => 2) },
  54 ) or exit 64;  # EX_USAGE
  55
  56 $opt{width} ||= $ENV{COLUMNS} || 80;
  57 $opt{color} //= -t *STDOUT;  # enable on tty
  58 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  59 $opt{units}   = $opt{'human-readable'} && ['', qw( k M G T P E Z Y y z a f p n μ m )];
  60 $opt{anchor} //= qr/\A/;
  61
  62 if (defined $opt{interval}) {
  63         $opt{interval} ||= 1;
  64         $SIG{ALRM} = sub {
  65                 show_lines();
  66                 alarm $opt{interval};
  67         };
  68         alarm $opt{interval};
  69 }
  70
  71 $SIG{INT} = 'IGNORE';  # continue after assumed eof
  72
  73 my (@lines, @values);
  74 my $valmatch = qr/$opt{anchor} ( \h* -? [0-9]* \.? [0-9]+ (?: e[+-]?[0-9]+ )? |)/x;
  75 while (readline) {
  76         s/\r?\n\z//;
  77         s/^\h*// unless $opt{unmodified};
  78         push @values, s/$valmatch/\n/ && $1;
  79         if (defined $opt{trim}) {
  80                 my $trimpos = abs $opt{trim};
  81                 if ($trimpos <= 1) {
  82                         $_ = substr $_, 0, 1;
  83                 }
  84                 elsif (length > $trimpos) {
  85                         substr($_, $trimpos - 1) = '…';
  86                 }
  87         }
  88         push @lines, $_;
  89 }
  90
  91 $SIG{INT} = 'DEFAULT';
  92
  93 sub show_lines {
  94
  95 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
  96 @lines and @lines > $nr or return;
  97
  98 my @order  = sort { $b <=> $a } grep { length } @values;
  99 my $maxval = $opt{hidemax} ? max @values[0 .. $opt{hidemax} - 1] : $order[0];
 100 my $minval = min $order[-1], 0;
 101 my $lenval = $opt{'value-length'} // max map { length } @order;
 102 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
 103         max map { length $values[$_] && length $lines[$_] }
 104                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 105 my $size   = ($maxval - $minval) &&
 106         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 107
 108 my @barmark;
 109 if ($opt{markers} // 1 and $size > 0) {
 110         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 111         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 112         $barmark[ orderpos($#order * .31731) ] = '>';
 113         $barmark[ orderpos($#order * .68269) ] = '<';
 114         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 115         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 116         defined and $opt{color} and $_ = "\e[36m$_\e[0m" for @barmark;
 117
 118         state $lastmax = $maxval;
 119         if ($maxval > $lastmax) {
 120                 print ' ' x ($lenval + $len);
 121                 printf "\e[90m" if $opt{color};
 122                 printf '%-*s',
 123                         ($lastmax - $minval) * $size + .5,
 124                         '-' x (($values[$nr - 1] - $minval) * $size);
 125                 print "\e[92m" if $opt{color};
 126                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 127                 print "\e[0m" if $opt{color};
 128                 $lastmax = $maxval;
 129         }
 130 }
 131
 132 sub sival {
 133         my $unit = int(log($_[0]) / log(1000) - ($_[0] < 1));
 134         sprintf "%3.1f%1s", $_[0] / 1000 ** $unit,
 135                 $#{$opt{units}} >> 1 < abs $unit ? "e$unit" : $opt{units}->[$unit];
 136 }
 137
 138 while ($nr <= $#lines) {
 139         $nr >= $opt{hidemax} and last if $opt{hidemax};
 140         my $val = $values[$nr];
 141         if (length $val) {
 142                 my $color = !$opt{color} ? 0 :
 143                         $val == $order[0] ? 32 : # max
 144                         $val == $order[-1] ? 31 : # min
 145                         90;
 146                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 147                 $val = "\e[${color}m$val\e[0m" if $color;
 148         }
 149         my $line = $lines[$nr] =~ s/\n/$val/r;
 150         printf '%-*s', $len + length($val), $line;
 151         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 152         say '';
 153
 154         $nr++;
 155 }
 156
 157 }
 158 show_lines();
 159
 160 __END__
 161
 162 =head1 NAME
 163
 164 barcat - graph to visualize input values
 165
 166 =head1 SYNOPSIS
 167
 168 B<barcat> [<options>] [<input>]
 169
 170 =head1 DESCRIPTION
 171
 172 Visualizes relative sizes of values read from input (file(s) or STDIN).
 173 Contents are concatenated similar to I<cat>,
 174 but numbers are reformatted and a bar graph is appended to each line.
 175
 176 =head1 OPTIONS
 177
 178 =over
 179
 180 =item -c, --[no-]color
 181
 182 Force colored output of values and bar markers.
 183 Defaults on if output is a tty,
 184 disabled otherwise such as when piped or redirected.
 185
 186 =item -f, --field=(<number>|<regexp>)
 187
 188 Compare values after a given number of whitespace separators,
 189 or matching a regular expression.
 190
 191 Unspecified or I<-f0> means values are at the start of each line.
 192 With I<-f1> the second word is taken instead.
 193 A string can indicate the starting position of a value
 194 (such as I<-f:> if preceded by colons),
 195 or capture the numbers itself,
 196 for example I<-f'(\d+)'> for the first digits anywhere.
 197
 198 =item -H, --human-readable
 199
 200 Format values using SI unit prefixes,
 201 turning long numbers like I<12356789> into I<12.4M>.
 202 Also changes an exponent I<1.602176634e-19> to I<160.2z>.
 203
 204 =item -t, --interval[=<seconds>]
 205
 206 Interval time to output partial progress.
 207
 208 =item -l, --length=[-]<size>[%]
 209
 210 Trim line contents (between number and bars)
 211 to a maximum number of characters.
 212 The exceeding part is replaced by an abbreviation sign,
 213 unless C<--length=0>.
 214
 215 Prepend a dash (i.e. make negative) to enforce padding
 216 regardless of encountered contents.
 217
 218 =item -L, --limit=(<count>|<start>-[<end>])
 219
 220 Stop output after a number of lines.
 221 All input is still counted and analyzed for statistics,
 222 but disregarded for padding and bar size.
 223
 224 =item -m, --markers=
 225
 226 Statistical positions to indicate on bars.
 227 Cannot be customized yet,
 228 only disabled by providing an empty argument.
 229
 230 Any value enables all marker characters:
 231
 232 =over 2
 233
 234 =item B<=>
 235
 236 Average:
 237 the sum of all values divided by the number of counted lines.
 238
 239 =item B<+>
 240
 241 Mean, median:
 242 the middle value or average between middle values.
 243
 244 =item B<<>
 245
 246 Standard deviation left of the mean.
 247 Only 16% of all values are lower.
 248
 249 =item B<< > >>
 250
 251 Standard deviation right of the mean.
 252 The part between B<< <--> >> encompass all I<normal> results,
 253 or 68% of all entries.
 254
 255 =back
 256
 257 =item -u, --unmodified
 258
 259 Do not strip leading whitespace.
 260 Keep original value alignment, which may be significant in some programs.
 261
 262 =item --value-length=<size>
 263
 264 Reserved space for numbers.
 265
 266 =item -w, --width=<columns>
 267
 268 Override the maximum number of columns to use.
 269 Appended graphics will extend to fill up the entire screen.
 270
 271 =back
 272
 273 =head1 EXAMPLES
 274
 275 Commonly used after counting, such as users on the current server:
 276
 277     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 278
 279 Letter frequencies in text files:
 280
 281     cat /usr/share/games/fortunes/*.u8 |
 282     perl -CO -nE 'say for grep length, split /\PL*/, uc' |
 283     sort | uniq -c | barcat
 284
 285 Memory usage of user processes:
 286
 287     ps xo %mem,pid,cmd | barcat -l40
 288
 289 Sizes (in megabytes) of all root files and directories:
 290
 291     du -d0 -m * | barcat
 292
 293 Number of HTTP requests per day:
 294
 295     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 296
 297 Any kind of database query with leading counts:
 298
 299     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 300     psql -t | barcat -u
 301
 302 Exchange rate USD/EUR history from CSV download provided by ECB:
 303
 304     curl https://sdw.ecb.europa.eu/export.do \
 305          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 306     grep '^[12]' | barcat -f',\K' --value-length=7
 307
 308 Total population history from the World Bank dataset (XML):
 309
 310     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 311     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 312     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 313
 314 Movies per year from prepared JSON data:
 315
 316     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 317     jq '.[].year' | uniq -c | barcat
 318
 319 Pokémon height comparison:
 320
 321         curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 322         jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 323
 324 Git statistics, such commit count by year:
 325
 326     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 327
 328 Or the most frequent authors:
 329
 330     git shortlog -sn | barcat -L3
 331
 332 Latency history:
 333
 334     ping google.com | barcat -f'time=\K' -t
 335
 336 =head1 AUTHOR
 337
 338 Mischa POSLAWSKY <perl@shiar.org>
 339
 340 =head1 LICENSE
 341
 342 GPL3+.