graph

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7
   8 our $VERSION = '1.00';
   9
  10 use Getopt::Long '2.33', qw( :config gnu_getopt );
  11 sub podexit { require Pod::Usage; Pod::Usage::pod2usage(-exitval => 0, @_) }
  12 GetOptions(\my %opt,
  13         'color|c!',
  14         'trim|length|l=i',
  15         'markers|m=s',
  16         'width|w=i',
  17         'usage|h' => sub { podexit() },
  18         'help'    => sub { podexit(-verbose => 2) },
  19 ) or exit 64;  # EX_USAGE
  20 $opt{width} ||= $ENV{COLUMNS} || 80;
  21 $opt{color} //= 1;
  22
  23 my @lines = readline or exit;
  24 chomp for @lines;
  25 my @values = map { s/^\h* ( -? [0-9]* (?:\.[0-9]+)? )//x and $1 } @lines;
  26 my @order  = sort { $b <=> $a } grep { length } @values;
  27 if (defined $opt{trim}) {
  28         my $trimpos = abs $opt{trim};
  29         $trimpos <= 1 ? ($_ = substr($_, 0, 1)) :
  30         (length > $trimpos and substr($_, $trimpos - 1) = '…') for @lines;
  31 }
  32
  33 my $maxval = $order[0];
  34 my $minval = min $order[-1], 0;
  35 my $lenval = max map { length } @order;
  36 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
  37         1 + max map { length } @lines;  # left padding
  38 my $size   = ($maxval - $minval) &&
  39         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
  40
  41 my @barmark;
  42 if ($opt{markers} // 1 and $size > 0) {
  43         sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
  44         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
  45         $barmark[ orderpos($#order / 2) ] = '+';  # mean
  46         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
  47         defined and $opt{color} and $_ = "\e[36m$_\e[0m" for @barmark;
  48 }
  49
  50 for my $nr (0 .. $#lines) {
  51         my $val = $values[$nr];
  52         if (length $val) {
  53                 my $color = !$opt{color} ? 0 :
  54                         $val == $order[0] ? 32 : # max
  55                         $val == $order[-1] ? 31 : # min
  56                         90;
  57                 printf "\e[%sm", $color if $color;
  58                 printf "%*s", $lenval, $val;
  59                 print "\e[0m" if $color;
  60         }
  61         printf '%-*s', $len, $lines[$nr];
  62         print $barmark[$_] // '-' for 1 .. (($val || 0) - $minval) * $size;
  63         say '';
  64 }
  65
  66 __END__
  67
  68 =head1 NAME
  69
  70 graph - append bar chart to input numbers
  71
  72 =head1 SYNOPSIS
  73
  74 B<graph> [<options>] [<input>]
  75
  76 =head1 DESCRIPTION
  77
  78 Each line starting with a number is given a bar to visualise relative sizes.
  79
  80 =head1 OPTIONS
  81
  82 =over
  83
  84 =item --no-color
  85
  86 Disable colored output of values and bar markers.
  87
  88 =item -l, --length=[-]<size>
  89
  90 Trim line contents (between number and bars)
  91 to a maximum number of characters.
  92 The exceeding part is replaced by an abbreviation sign,
  93 unless C<--length=0>.
  94
  95 Prepend a dash (i.e. make negative) to enforce padding
  96 regardless of encountered contents.
  97
  98 =item -m, --markers=
  99
 100 Statistical positions to indicate on bars.
 101 Cannot be customized yet,
 102 only disabled by providing an empty argument.
 103
 104 Any value enables all marker characters:
 105
 106 =over 2
 107
 108 =item B<=>
 109
 110 Average:
 111 the sum of all values divided by the number of counted lines.
 112
 113 =item B<+>
 114
 115 Median:
 116 the middle value or average between middle values.
 117
 118 =back
 119
 120 =item -w, --width=<columns>
 121
 122 Override the maximum number of columns to use.
 123 Appended graphics will extend to fill up the entire screen.
 124
 125 =back
 126
 127 =head1 EXAMPLES
 128
 129 Commonly used after counting, such as users on the current server:
 130
 131     users | sed 's/ /\n/g' | sort | uniq -c | graph
 132
 133 Letter frequencies in text files:
 134
 135     cat /usr/share/games/fortunes/*.u8 |
 136     perl -CO -nE 'say for grep length, split /\PL*/, uc' |
 137     sort | uniq -c | graph
 138
 139 Memory usage of user processes:
 140
 141     ps xo %mem,pid,cmd | graph -l40
 142
 143 Sizes (in megabytes) of all root files and directories:
 144
 145     du -d0 -m * | graph
 146
 147 Number of HTTP requests per day:
 148
 149     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | graph
 150
 151 Any kind of database query with leading counts:
 152
 153     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 154     psql -t | graph
 155
 156 Git statistics, such commit count by year:
 157
 158     git log --pretty=%ci | cut -b-4 | uniq -c | graph
 159
 160 Or the most frequent authors:
 161
 162     git shortlog -sn | graph | head -3
 163
 164 =head1 AUTHOR
 165
 166 Mischa POSLAWSKY <perl@shiar.org>
 167
 168 =head1 LICENSE
 169
 170 GPL3+.