barcat

   1 #!/usr/bin/env perl
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.03';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s',
  21         'human-readable|H!',
  22         'interval|t:i',
  23         'trim|length|l=s' => sub {
  24                 my ($optname, $optval) = @_;
  25                 $optval =~ s/%$// and $opt{trimpct}++;
  26                 $optval =~ m/^-?[0-9]+$/ or die(
  27                         "Value \"$optval\" invalid for option $optname",
  28                         " (number or percentage expected)\n"
  29                 );
  30                 $opt{trim} = $optval;
  31         },
  32         'value-length=i',
  33         'hidemin=i',
  34         'hidemax=i',
  35         'limit|L=s' => sub {
  36                 my ($optname, $optval) = @_;
  37                 $optval ||= 0;
  38                 ($opt{hidemin}, $opt{hidemax}) =
  39                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  40                         "Value \"$optval\" invalid for option limit",
  41                         " (range expected)\n"
  42                 );
  43         },
  44         'markers|m=s',
  45         'unmodified|u!',
  46         'width|w=i',
  47         'usage|h' => sub { podexit() },
  48         'help'    => sub { podexit(-verbose => 2) },
  49 ) or exit 64;  # EX_USAGE
  50
  51 $opt{width} ||= $ENV{COLUMNS} || 80;
  52 $opt{color} //= -t *STDOUT;  # enable on tty
  53 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  54 $opt{units}   = $opt{'human-readable'} && ['', qw( k M G T <> n μ m )];
  55
  56 if (defined $opt{interval}) {
  57         $opt{interval} ||= 1;
  58         $SIG{ALRM} = sub {
  59                 show_lines();
  60                 alarm $opt{interval};
  61         };
  62         alarm $opt{interval};
  63 }
  64
  65 $SIG{INT} = 'IGNORE';  # continue after assumed eof
  66
  67 my (@lines, @values);
  68 my $anchor = !defined $opt{field} ? qr/\A/ :
  69         $opt{field} =~ /^[0-9]+$/ ? qr/(?:\S*\h+){$opt{field}}\K/ :
  70         $opt{field};
  71 while (readline) {
  72         s/\r?\n\z//;
  73         s/^\h*// unless $opt{unmodified};
  74         push @values, s/$anchor ( \h* -? [0-9]* \.? [0-9]+ |)/\n/x && $1;
  75         if (defined $opt{trim}) {
  76                 my $trimpos = abs $opt{trim};
  77                 if ($trimpos <= 1) {
  78                         $_ = substr $_, 0, 1;
  79                 }
  80                 elsif (length > $trimpos) {
  81                         substr($_, $trimpos - 1) = '…';
  82                 }
  83         }
  84         push @lines, $_;
  85 }
  86
  87 $SIG{INT} = 'DEFAULT';
  88
  89 sub show_lines {
  90
  91 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
  92 @lines and @lines > $nr or return;
  93
  94 my @order  = sort { $b <=> $a } grep { length } @values;
  95 my $maxval = $opt{hidemax} ? max @values[0 .. $opt{hidemax} - 1] : $order[0];
  96 my $minval = min $order[-1], 0;
  97 my $lenval = $opt{'value-length'} // max map { length } @order;
  98 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
  99         max map { length $values[$_] && length $lines[$_] }
 100                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 101 my $size   = ($maxval - $minval) &&
 102         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 103
 104 my @barmark;
 105 if ($opt{markers} // 1 and $size > 0) {
 106         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 107         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 108         $barmark[ orderpos($#order * .31731) ] = '>';
 109         $barmark[ orderpos($#order * .68269) ] = '<';
 110         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 111         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 112         defined and $opt{color} and $_ = "\e[36m$_\e[0m" for @barmark;
 113
 114         state $lastmax = $maxval;
 115         if ($maxval > $lastmax) {
 116                 print ' ' x ($lenval + $len);
 117                 printf "\e[90m" if $opt{color};
 118                 printf '%-*s',
 119                         ($lastmax - $minval) * $size + .5,
 120                         '-' x (($values[$nr - 1] - $minval) * $size);
 121                 print "\e[92m" if $opt{color};
 122                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 123                 print "\e[0m" if $opt{color};
 124                 $lastmax = $maxval;
 125         }
 126 }
 127
 128 sub sival {
 129         my $unit = int(log($_[0]) / log(1000) - ($_[0] < 1));
 130         sprintf "%3.1f%1s", $_[0] / 1000 ** $unit, $opt{units}->[$unit];
 131 }
 132
 133 while ($nr <= $#lines) {
 134         $nr >= $opt{hidemax} and last if $opt{hidemax};
 135         my $val = $values[$nr];
 136         if (length $val) {
 137                 my $color = !$opt{color} ? 0 :
 138                         $val == $order[0] ? 32 : # max
 139                         $val == $order[-1] ? 31 : # min
 140                         90;
 141                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 142                 $val = "\e[${color}m$val\e[0m" if $color;
 143         }
 144         my $line = $lines[$nr] =~ s/\n/$val/r;
 145         printf '%-*s', $len + length($val), $line;
 146         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 147         say '';
 148
 149         $nr++;
 150 }
 151
 152 }
 153 show_lines();
 154
 155 __END__
 156
 157 =head1 NAME
 158
 159 barcat - graph to visualize input values
 160
 161 =head1 SYNOPSIS
 162
 163 B<barcat> [<options>] [<input>]
 164
 165 =head1 DESCRIPTION
 166
 167 Visualizes relative sizes of values read from input (file(s) or STDIN).
 168 Contents are concatenated similar to I<cat>,
 169 but numbers are reformatted and a bar graph is appended to each line.
 170
 171 =head1 OPTIONS
 172
 173 =over
 174
 175 =item -c, --[no-]color
 176
 177 Force colored output of values and bar markers.
 178 Defaults on if output is a tty,
 179 disabled otherwise such as when piped or redirected.
 180
 181 =item -f, --field=(<number>|<regexp>)
 182
 183 Compare values after a given number of whitespace separators,
 184 or matching a regular expression.
 185
 186 Unspecified or I<-f0> means values are at the start of each line.
 187 With I<-f1> the second word is taken instead.
 188 A string can indicate the starting position of a value
 189 (such as I<-f:> if preceded by colons),
 190 or capture the numbers itself,
 191 for example I<-f'(\d+)'> for the first digits anywhere.
 192
 193 =item -H, --human-readable
 194
 195 Format values using SI unit prefixes,
 196 turning long numbers like I<12356789> into I<12.4M>.
 197
 198 =item -t, --interval[=<seconds>]
 199
 200 Interval time to output partial progress.
 201
 202 =item -l, --length=[-]<size>[%]
 203
 204 Trim line contents (between number and bars)
 205 to a maximum number of characters.
 206 The exceeding part is replaced by an abbreviation sign,
 207 unless C<--length=0>.
 208
 209 Prepend a dash (i.e. make negative) to enforce padding
 210 regardless of encountered contents.
 211
 212 =item -L, --limit=(<count>|<start>-[<end>])
 213
 214 Stop output after a number of lines.
 215 All input is still counted and analyzed for statistics,
 216 but disregarded for padding and bar size.
 217
 218 =item -m, --markers=
 219
 220 Statistical positions to indicate on bars.
 221 Cannot be customized yet,
 222 only disabled by providing an empty argument.
 223
 224 Any value enables all marker characters:
 225
 226 =over 2
 227
 228 =item B<=>
 229
 230 Average:
 231 the sum of all values divided by the number of counted lines.
 232
 233 =item B<+>
 234
 235 Mean, median:
 236 the middle value or average between middle values.
 237
 238 =item B<<>
 239
 240 Standard deviation left of the mean.
 241 Only 16% of all values are lower.
 242
 243 =item B<< > >>
 244
 245 Standard deviation right of the mean.
 246 The part between B<< <--> >> encompass all I<normal> results,
 247 or 68% of all entries.
 248
 249 =back
 250
 251 =item -u, --unmodified
 252
 253 Do not strip leading whitespace.
 254 Keep original value alignment, which may be significant in some programs.
 255
 256 =item --value-length=<size>
 257
 258 Reserved space for numbers.
 259
 260 =item -w, --width=<columns>
 261
 262 Override the maximum number of columns to use.
 263 Appended graphics will extend to fill up the entire screen.
 264
 265 =back
 266
 267 =head1 EXAMPLES
 268
 269 Commonly used after counting, such as users on the current server:
 270
 271     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 272
 273 Letter frequencies in text files:
 274
 275     cat /usr/share/games/fortunes/*.u8 |
 276     perl -CO -nE 'say for grep length, split /\PL*/, uc' |
 277     sort | uniq -c | barcat
 278
 279 Memory usage of user processes:
 280
 281     ps xo %mem,pid,cmd | barcat -l40
 282
 283 Sizes (in megabytes) of all root files and directories:
 284
 285     du -d0 -m * | barcat
 286
 287 Number of HTTP requests per day:
 288
 289     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 290
 291 Any kind of database query with leading counts:
 292
 293     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 294     psql -t | barcat -u
 295
 296 Exchange rate USD/EUR history from CSV download provided by ECB:
 297
 298     curl https://sdw.ecb.europa.eu/export.do \
 299          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 300     grep '^[12]' | barcat -f',\K' --value-length=7
 301
 302 Total population history from the World Bank dataset (XML):
 303
 304     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 305     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 306     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 307
 308 Movies per year from prepared JSON data:
 309
 310     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 311     jq '.[].year' | uniq -c | barcat
 312
 313 Pokémon height comparison:
 314
 315         curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 316         jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 317
 318 Git statistics, such commit count by year:
 319
 320     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 321
 322 Or the most frequent authors:
 323
 324     git shortlog -sn | barcat -L3
 325
 326 Latency history:
 327
 328     ping google.com | barcat -f'time=\K' -t
 329
 330 =head1 AUTHOR
 331
 332 Mischa POSLAWSKY <perl@shiar.org>
 333
 334 =head1 LICENSE
 335
 336 GPL3+.