barcat

   1 #!/usr/bin/env perl
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.03';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s' => sub {
  21                 eval {
  22                         local $_ = $_[1];
  23                         $opt{anchor} = /^[0-9]+$/ ? qr/(?:\S*\h+){$_}\K/ : qr/$_/;
  24                 } or die $@ =~ s/(?: at .+)?$/ for option $_[0]/r;
  25         },
  26         'human-readable|H!',
  27         'interval|t:i',
  28         'trim|length|l=s' => sub {
  29                 my ($optname, $optval) = @_;
  30                 $optval =~ s/%$// and $opt{trimpct}++;
  31                 $optval =~ m/^-?[0-9]+$/ or die(
  32                         "Value \"$optval\" invalid for option $optname",
  33                         " (number or percentage expected)\n"
  34                 );
  35                 $opt{trim} = $optval;
  36         },
  37         'value-length=i',
  38         'hidemin=i',
  39         'hidemax=i',
  40         'limit|L=s' => sub {
  41                 my ($optname, $optval) = @_;
  42                 $optval ||= 0;
  43                 ($opt{hidemin}, $opt{hidemax}) =
  44                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  45                         "Value \"$optval\" invalid for option limit",
  46                         " (range expected)\n"
  47                 );
  48         },
  49         'markers|m=s',
  50         'stat|s!',
  51         'unmodified|u!',
  52         'width|w=i',
  53         'usage|h' => sub { podexit() },
  54         'help'    => sub { podexit(-verbose => 2) },
  55 ) or exit 64;  # EX_USAGE
  56
  57 $opt{width} ||= $ENV{COLUMNS} || 80;
  58 $opt{color} //= -t *STDOUT;  # enable on tty
  59 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  60 $opt{units}   = [split //, ' kMGTPEZYyzafpnμm'] if $opt{'human-readable'};
  61 $opt{anchor} //= qr/\A/;
  62 $opt{'value-length'} = 6 if $opt{units};
  63
  64 if (defined $opt{interval}) {
  65         $opt{interval} ||= 1;
  66         $SIG{ALRM} = sub {
  67                 show_lines();
  68                 alarm $opt{interval};
  69         };
  70         alarm $opt{interval};
  71 }
  72
  73 $SIG{INT} = 'IGNORE';  # continue after assumed eof
  74
  75 my (@lines, @values);
  76 my $valmatch = qr/$opt{anchor} ( \h* -? [0-9]* \.? [0-9]+ (?: e[+-]?[0-9]+ )? |)/x;
  77 while (readline) {
  78         s/\r?\n\z//;
  79         s/^\h*// unless $opt{unmodified};
  80         push @values, s/$valmatch/\n/ && $1;
  81         if (defined $opt{trim}) {
  82                 my $trimpos = abs $opt{trim};
  83                 if ($trimpos <= 1) {
  84                         $_ = substr $_, 0, 1;
  85                 }
  86                 elsif (length > $trimpos) {
  87                         substr($_, $trimpos - 1) = '…';
  88                 }
  89         }
  90         push @lines, $_;
  91 }
  92
  93 $SIG{INT} = 'DEFAULT';
  94
  95 sub show_lines {
  96
  97 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
  98 @lines and @lines > $nr or return;
  99 @lines or return;
 100 @lines > $nr or return unless $opt{hidemin};
 101
 102 my @order  = sort { $b <=> $a } grep { length } @values;
 103 my $maxval = $opt{hidemax} ? max @values[0 .. $opt{hidemax} - 1] : $order[0];
 104 my $minval = min $order[-1], 0;
 105 my $lenval = $opt{'value-length'} // max map { length } @order;
 106 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
 107         max map { length $values[$_] && length $lines[$_] }
 108                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 109 my $size   = ($maxval - $minval) &&
 110         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 111
 112 my @barmark;
 113 if ($opt{markers} // 1 and $size > 0) {
 114         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 115         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 116         $barmark[ orderpos($#order * .31731) ] = '>';
 117         $barmark[ orderpos($#order * .68269) ] = '<';
 118         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 119         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 120         defined and $opt{color} and $_ = "\e[36m$_\e[0m" for @barmark;
 121
 122         state $lastmax = $maxval;
 123         if ($maxval > $lastmax) {
 124                 print ' ' x ($lenval + $len);
 125                 printf "\e[90m" if $opt{color};
 126                 printf '%-*s',
 127                         ($lastmax - $minval) * $size + .5,
 128                         '-' x (($values[$nr - 1] - $minval) * $size);
 129                 print "\e[92m" if $opt{color};
 130                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 131                 print "\e[0m" if $opt{color};
 132                 $lastmax = $maxval;
 133         }
 134 }
 135
 136 @lines > $nr or return if $opt{hidemin};
 137
 138 sub sival {
 139         my $unit = int(log($_[0]) / log(1000) - ($_[0] < 1));
 140         my $float = $_[0] !~ /^ (?: 0*\.)? [0-9]{1,3} $/x;
 141         sprintf('%*.*f%*s',
 142                 $float ? 5 : 3, $float,  # length and tenths
 143                 $_[0] / 1000 ** $unit,   # number
 144                 $float ? 0 : 3,          # unit size
 145                 $#{$opt{units}} >> 1 < abs $unit ? "e$unit" : $opt{units}->[$unit]
 146         );
 147 }
 148
 149 while ($nr <= $#lines) {
 150         $nr >= $opt{hidemax} and last if defined $opt{hidemax};
 151         my $val = $values[$nr];
 152         if (length $val) {
 153                 my $color = !$opt{color} ? 0 :
 154                         $val == $order[0] ? 32 : # max
 155                         $val == $order[-1] ? 31 : # min
 156                         90;
 157                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 158                 $val = "\e[${color}m$val\e[0m" if $color;
 159         }
 160         my $line = $lines[$nr] =~ s/\n/$val/r;
 161         printf '%-*s', $len + length($val), $line;
 162         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 163         say '';
 164
 165         $nr++;
 166 }
 167
 168 }
 169 show_lines();
 170
 171 if ($opt{stat}) {
 172         printf '%d values', scalar @values;
 173         say '';
 174 }
 175
 176 __END__
 177
 178 =head1 NAME
 179
 180 barcat - graph to visualize input values
 181
 182 =head1 SYNOPSIS
 183
 184 B<barcat> [<options>] [<input>]
 185
 186 =head1 DESCRIPTION
 187
 188 Visualizes relative sizes of values read from input (file(s) or STDIN).
 189 Contents are concatenated similar to I<cat>,
 190 but numbers are reformatted and a bar graph is appended to each line.
 191
 192 =head1 OPTIONS
 193
 194 =over
 195
 196 =item -c, --[no-]color
 197
 198 Force colored output of values and bar markers.
 199 Defaults on if output is a tty,
 200 disabled otherwise such as when piped or redirected.
 201
 202 =item -f, --field=(<number>|<regexp>)
 203
 204 Compare values after a given number of whitespace separators,
 205 or matching a regular expression.
 206
 207 Unspecified or I<-f0> means values are at the start of each line.
 208 With I<-f1> the second word is taken instead.
 209 A string can indicate the starting position of a value
 210 (such as I<-f:> if preceded by colons),
 211 or capture the numbers itself,
 212 for example I<-f'(\d+)'> for the first digits anywhere.
 213
 214 =item -H, --human-readable
 215
 216 Format values using SI unit prefixes,
 217 turning long numbers like I<12356789> into I<12.4M>.
 218 Also changes an exponent I<1.602176634e-19> to I<160.2z>.
 219 Short integers are aligned but kept without decimal point.
 220
 221 =item -t, --interval[=<seconds>]
 222
 223 Interval time to output partial progress.
 224
 225 =item -l, --length=[-]<size>[%]
 226
 227 Trim line contents (between number and bars)
 228 to a maximum number of characters.
 229 The exceeding part is replaced by an abbreviation sign,
 230 unless C<--length=0>.
 231
 232 Prepend a dash (i.e. make negative) to enforce padding
 233 regardless of encountered contents.
 234
 235 =item -L, --limit=(<count>|<start>-[<end>])
 236
 237 Stop output after a number of lines.
 238 All input is still counted and analyzed for statistics,
 239 but disregarded for padding and bar size.
 240
 241 =item -m, --markers=
 242
 243 Statistical positions to indicate on bars.
 244 Cannot be customized yet,
 245 only disabled by providing an empty argument.
 246
 247 Any value enables all marker characters:
 248
 249 =over 2
 250
 251 =item B<=>
 252
 253 Average:
 254 the sum of all values divided by the number of counted lines.
 255
 256 =item B<+>
 257
 258 Mean, median:
 259 the middle value or average between middle values.
 260
 261 =item B<<>
 262
 263 Standard deviation left of the mean.
 264 Only 16% of all values are lower.
 265
 266 =item B<< > >>
 267
 268 Standard deviation right of the mean.
 269 The part between B<< <--> >> encompass all I<normal> results,
 270 or 68% of all entries.
 271
 272 =back
 273
 274 =item -s, --stat
 275
 276 Total statistics after all data.
 277
 278 =item -u, --unmodified
 279
 280 Do not strip leading whitespace.
 281 Keep original value alignment, which may be significant in some programs.
 282
 283 =item --value-length=<size>
 284
 285 Reserved space for numbers.
 286
 287 =item -w, --width=<columns>
 288
 289 Override the maximum number of columns to use.
 290 Appended graphics will extend to fill up the entire screen.
 291
 292 =back
 293
 294 =head1 EXAMPLES
 295
 296 Commonly used after counting, such as users on the current server:
 297
 298     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 299
 300 Letter frequencies in text files:
 301
 302     cat /usr/share/games/fortunes/*.u8 |
 303     perl -CO -nE 'say for grep length, split /\PL*/, uc' |
 304     sort | uniq -c | barcat
 305
 306 Memory usage of user processes:
 307
 308     ps xo %mem,pid,cmd | barcat -l40
 309
 310 Sizes (in megabytes) of all root files and directories:
 311
 312     du -d0 -m * | barcat
 313
 314 Number of HTTP requests per day:
 315
 316     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 317
 318 Any kind of database query with leading counts:
 319
 320     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 321     psql -t | barcat -u
 322
 323 Exchange rate USD/EUR history from CSV download provided by ECB:
 324
 325     curl https://sdw.ecb.europa.eu/export.do \
 326          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 327     grep '^[12]' | barcat -f',\K' --value-length=7
 328
 329 Total population history from the World Bank dataset (XML):
 330
 331     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 332     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 333     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 334
 335 Movies per year from prepared JSON data:
 336
 337     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 338     jq '.[].year' | uniq -c | barcat
 339
 340 Pokémon height comparison:
 341
 342         curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 343         jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 344
 345 Git statistics, such commit count by year:
 346
 347     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 348
 349 Or the most frequent authors:
 350
 351     git shortlog -sn | barcat -L3
 352
 353 Latency history:
 354
 355     ping google.com | barcat -f'time=\K' -t
 356
 357 =head1 AUTHOR
 358
 359 Mischa POSLAWSKY <perl@shiar.org>
 360
 361 =head1 LICENSE
 362
 363 GPL3+.