barcat

   1 #!/usr/bin/env perl
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.04';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s' => sub {
  21                 eval {
  22                         local $_ = $_[1];
  23                         $opt{anchor} = /^[0-9]+$/ ? qr/(?:\S*\h+){$_}\K/ : qr/$_/;
  24                 } or die $@ =~ s/(?: at .+)?$/ for option $_[0]/r;
  25         },
  26         'human-readable|H!',
  27         'interval|t:i',
  28         'trim|length|l=s' => sub {
  29                 my ($optname, $optval) = @_;
  30                 $optval =~ s/%$// and $opt{trimpct}++;
  31                 $optval =~ m/^-?[0-9]+$/ or die(
  32                         "Value \"$optval\" invalid for option $optname",
  33                         " (number or percentage expected)\n"
  34                 );
  35                 $opt{trim} = $optval;
  36         },
  37         'value-length=i',
  38         'hidemin=i',
  39         'hidemax=i',
  40         'limit|L=s' => sub {
  41                 my ($optname, $optval) = @_;
  42                 $optval ||= 0;
  43                 ($opt{hidemin}, $opt{hidemax}) =
  44                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  45                         "Value \"$optval\" invalid for option limit",
  46                         " (range expected)\n"
  47                 );
  48         },
  49         'markers|m=s',
  50         'stat|s!',
  51         'unmodified|u!',
  52         'width|w=i',
  53         'usage|h' => sub { podexit() },
  54         'help'    => sub { podexit(-verbose => 2) },
  55 ) or exit 64;  # EX_USAGE
  56
  57 $opt{width} ||= $ENV{COLUMNS} || 80;
  58 $opt{color} //= -t *STDOUT;  # enable on tty
  59 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  60 $opt{units}   = [split //, ' kMGTPEZYyzafpnμm'] if $opt{'human-readable'};
  61 $opt{anchor} //= qr/\A/;
  62 $opt{'value-length'} = 6 if $opt{units};
  63
  64 my (@lines, @values, @order);
  65
  66 if (defined $opt{interval}) {
  67         $opt{interval} ||= 1;
  68         $SIG{ALRM} = sub {
  69                 show_lines();
  70                 alarm $opt{interval};
  71         };
  72         alarm $opt{interval};
  73
  74         eval {
  75                 require Tie::Array::Sorted;
  76                 tie @order, 'Tie::Array::Sorted', sub { $_[1] <=> $_[0] };
  77         } or warn $@, "Expect slowdown with large datasets!\n";
  78 }
  79
  80 $SIG{INT} = 'IGNORE';  # continue after assumed eof
  81
  82 my $valmatch = qr/$opt{anchor} ( \h* -? [0-9]* \.? [0-9]+ (?: e[+-]?[0-9]+ )? |)/x;
  83 while (readline) {
  84         s/\r?\n\z//;
  85         s/^\h*// unless $opt{unmodified};
  86         push @values, s/$valmatch/\n/ && $1;
  87         push @order, $1 if length $1;
  88         if (defined $opt{trim} and defined $1) {
  89                 my $trimpos = abs $opt{trim};
  90                 if ($trimpos <= 1) {
  91                         $_ = substr $_, 0, 1;
  92                 }
  93                 elsif (length > $trimpos) {
  94                         substr($_, $trimpos - 1) = '…';
  95                 }
  96         }
  97         push @lines, $_;
  98 }
  99
 100 $SIG{INT} = 'DEFAULT';
 101
 102 sub show_lines {
 103
 104 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
 105 @lines and @lines > $nr or return;
 106 @lines or return;
 107 @lines > $nr or return unless $opt{hidemin};
 108
 109 @order = sort { $b <=> $a } @order unless tied @order;
 110 my $maxval = ($opt{hidemax} ? max grep { length } @values[0 .. $opt{hidemax} - 1] : $order[0]) // 0;
 111 my $minval = min $order[-1] // (), 0;
 112 my $lenval = $opt{'value-length'} // max map { length } @order;
 113 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
 114         max map { length $values[$_] && length $lines[$_] }
 115                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 116 my $size   = ($maxval - $minval) &&
 117         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 118
 119 my @barmark;
 120 if ($opt{markers} // 1 and $size > 0) {
 121         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 122         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 123         $barmark[ orderpos($#order * .31731) ] = '>';
 124         $barmark[ orderpos($#order * .68269) ] = '<';
 125         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 126         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 127         defined and $opt{color} and $_ = "\e[36m$_\e[0m" for @barmark;
 128
 129         state $lastmax = $maxval;
 130         if ($maxval > $lastmax) {
 131                 print ' ' x ($lenval + $len);
 132                 printf "\e[90m" if $opt{color};
 133                 printf '%-*s',
 134                         ($lastmax - $minval) * $size + .5,
 135                         '-' x (($values[$nr - 1] - $minval) * $size);
 136                 print "\e[92m" if $opt{color};
 137                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 138                 print "\e[0m" if $opt{color};
 139                 $lastmax = $maxval;
 140         }
 141 }
 142
 143 @lines > $nr or return if $opt{hidemin};
 144
 145 sub sival {
 146         my $unit = int(log(abs $_[0] || 1) / log(10) - 3*($_[0] < 1) + 1e-15);
 147         my $float = $_[0] !~ /^0*[-0-9]{1,3}$/;
 148         sprintf('%3.*f%1s',
 149                 $float && ($unit % 3) == ($unit < 0),  # tenths
 150                 $_[0] / 1000 ** int($unit/3),   # number
 151                 $#{$opt{units}} * 1.5 < abs $unit ? "e$unit" : $opt{units}->[$unit/3]
 152         );
 153 }
 154
 155 while ($nr <= $#lines) {
 156         $nr >= $opt{hidemax} and last if defined $opt{hidemax};
 157         my $val = $values[$nr];
 158         if (length $val) {
 159                 my $color = !$opt{color} ? 0 :
 160                         $val == $order[0] ? 32 : # max
 161                         $val == $order[-1] ? 31 : # min
 162                         90;
 163                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 164                 $val = "\e[${color}m$val\e[0m" if $color;
 165         }
 166         my $line = $lines[$nr] =~ s/\n/$val/r;
 167         printf '%-*s', $len + length($val), $line;
 168         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 169         say '';
 170
 171         $nr++;
 172 }
 173
 174 }
 175 show_lines();
 176
 177 if ($opt{stat}) {
 178         if ($opt{hidemin} or $opt{hidemax}) {
 179                 $opt{hidemin} ||= 1;
 180                 $opt{hidemax} ||= @lines;
 181                 printf '%s of ', sum(@values[$opt{hidemin} - 1 .. $opt{hidemax} - 1]) // 0;
 182         }
 183         if (@order) {
 184                 my $total = sum @order;
 185                 printf '%s total', $total;
 186                 printf ' in %d values', scalar @values;
 187                 printf ' (%s min, %*.*f avg, %s max)',
 188                         $order[-1], 0, 2, $total / @order, $order[0];
 189         }
 190         say '';
 191 }
 192
 193 __END__
 194 =encoding utf8
 195
 196 =head1 NAME
 197
 198 barcat - graph to visualize input values
 199
 200 =head1 SYNOPSIS
 201
 202 B<barcat> [<options>] [<input>]
 203
 204 =head1 DESCRIPTION
 205
 206 Visualizes relative sizes of values read from input (file(s) or STDIN).
 207 Contents are concatenated similar to I<cat>,
 208 but numbers are reformatted and a bar graph is appended to each line.
 209
 210 =head1 OPTIONS
 211
 212 =over
 213
 214 =item -c, --[no-]color
 215
 216 Force colored output of values and bar markers.
 217 Defaults on if output is a tty,
 218 disabled otherwise such as when piped or redirected.
 219
 220 =item -f, --field=(<number>|<regexp>)
 221
 222 Compare values after a given number of whitespace separators,
 223 or matching a regular expression.
 224
 225 Unspecified or I<-f0> means values are at the start of each line.
 226 With I<-f1> the second word is taken instead.
 227 A string can indicate the starting position of a value
 228 (such as I<-f:> if preceded by colons),
 229 or capture the numbers itself,
 230 for example I<-f'(\d+)'> for the first digits anywhere.
 231
 232 =item -H, --human-readable
 233
 234 Format values using SI unit prefixes,
 235 turning long numbers like I<12356789> into I<12.4M>.
 236 Also changes an exponent I<1.602176634e-19> to I<160.2z>.
 237 Short integers are aligned but kept without decimal point.
 238
 239 =item -t, --interval[=<seconds>]
 240
 241 Interval time to output partial progress.
 242
 243 =item -l, --length=[-]<size>[%]
 244
 245 Trim line contents (between number and bars)
 246 to a maximum number of characters.
 247 The exceeding part is replaced by an abbreviation sign,
 248 unless C<--length=0>.
 249
 250 Prepend a dash (i.e. make negative) to enforce padding
 251 regardless of encountered contents.
 252
 253 =item -L, --limit=(<count>|<start>-[<end>])
 254
 255 Stop output after a number of lines.
 256 All input is still counted and analyzed for statistics,
 257 but disregarded for padding and bar size.
 258
 259 =item -m, --markers=
 260
 261 Statistical positions to indicate on bars.
 262 Cannot be customized yet,
 263 only disabled by providing an empty argument.
 264
 265 Any value enables all marker characters:
 266
 267 =over 2
 268
 269 =item B<=>
 270
 271 Average:
 272 the sum of all values divided by the number of counted lines.
 273
 274 =item B<+>
 275
 276 Mean, median:
 277 the middle value or average between middle values.
 278
 279 =item B<<>
 280
 281 Standard deviation left of the mean.
 282 Only 16% of all values are lower.
 283
 284 =item B<< > >>
 285
 286 Standard deviation right of the mean.
 287 The part between B<< <--> >> encompass all I<normal> results,
 288 or 68% of all entries.
 289
 290 =back
 291
 292 =item -s, --stat
 293
 294 Total statistics after all data.
 295
 296 =item -u, --unmodified
 297
 298 Do not strip leading whitespace.
 299 Keep original value alignment, which may be significant in some programs.
 300
 301 =item --value-length=<size>
 302
 303 Reserved space for numbers.
 304
 305 =item -w, --width=<columns>
 306
 307 Override the maximum number of columns to use.
 308 Appended graphics will extend to fill up the entire screen.
 309
 310 =back
 311
 312 =head1 EXAMPLES
 313
 314 Draw a sine wave:
 315
 316     seq 30 | awk '{print sin($1/10)}' | barcat
 317
 318 Compare file sizes (with human-readable numbers):
 319
 320     du -d0 -b * | barcat -H
 321
 322 Memory usage of user processes with long names truncated:
 323
 324     ps xo %mem,pid,cmd | barcat -l40
 325
 326 Monitor network latency from prefixed results:
 327
 328     ping google.com | barcat -f'time=\K' -t
 329
 330 Commonly used after counting, for example users on the current server:
 331
 332     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 333
 334 Letter frequencies in text files:
 335
 336     cat /usr/share/games/fortunes/*.u8 |
 337     perl -CS -nE 'say for grep length, split /\PL*/, uc' |
 338     sort | uniq -c | barcat
 339
 340 Number of HTTP requests per day:
 341
 342     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 343
 344 Any kind of database query with counts, preserving returned alignment:
 345
 346     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 347     psql -t | barcat -u
 348
 349 External datasets, like movies per year:
 350
 351     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 352     perl -054 -nlE 'say if s/^"year"://' | uniq -c | barcat
 353
 354 But please get I<jq> to process JSON
 355 and replace the manual selection by C<< jq '.[].year' >>.
 356
 357 Pokémon height comparison:
 358
 359     curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 360     jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 361
 362 USD/EUR exchange rate from CSV provided by the ECB:
 363
 364     curl https://sdw.ecb.europa.eu/export.do \
 365          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 366     grep '^[12]' | barcat -f',\K' --value-length=7
 367
 368 Total population history from the World Bank dataset (XML):
 369 External datasets, like total population in XML from the World Bank:
 370
 371     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 372     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 373     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 374
 375 And of course various Git statistics, such commit count by year:
 376
 377     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 378
 379 Or the top 3 most frequent authors with statistics over all:
 380
 381     git shortlog -sn | barcat -L3 -s
 382
 383 =head1 AUTHOR
 384
 385 Mischa POSLAWSKY <perl@shiar.org>
 386
 387 =head1 LICENSE
 388
 389 GPL3+.