barcat

   1 #!/usr/bin/perl -CA
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.04';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s' => sub {
  21                 eval {
  22                         local $_ = $_[1];
  23                         $opt{anchor} = /^[0-9]+$/ ? qr/(?:\S*\h+){$_}\K/ : qr/$_/;
  24                 } or die $@ =~ s/(?: at .+)?$/ for option $_[0]/r;
  25         },
  26         'human-readable|H!',
  27         'interval|t:i',
  28         'trim|length|l=s' => sub {
  29                 my ($optname, $optval) = @_;
  30                 $optval =~ s/%$// and $opt{trimpct}++;
  31                 $optval =~ m/^-?[0-9]+$/ or die(
  32                         "Value \"$optval\" invalid for option $optname",
  33                         " (number or percentage expected)\n"
  34                 );
  35                 $opt{trim} = $optval;
  36         },
  37         'value-length=i',
  38         'hidemin=i',
  39         'hidemax=i',
  40         'limit|L=s' => sub {
  41                 my ($optname, $optval) = @_;
  42                 $optval ||= 0;
  43                 ($opt{hidemin}, $opt{hidemax}) =
  44                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  45                         "Value \"$optval\" invalid for option limit",
  46                         " (range expected)\n"
  47                 );
  48         },
  49         'markers|m=s',
  50         'spark:s' => sub {
  51                 $opt{spark} = [split //, $_[1] || '⎽▁▂▃▄▅▆▇█'];
  52         },
  53         'stat|s!',
  54         'unmodified|u!',
  55         'width|w=i',
  56         'usage|h' => sub { podexit() },
  57         'help'    => sub { podexit(-verbose => 2) },
  58 ) or exit 64;  # EX_USAGE
  59
  60 $opt{width} ||= $ENV{COLUMNS} || 80;
  61 $opt{color} //= -t *STDOUT;  # enable on tty
  62 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  63 $opt{units}   = [split //, ' kMGTPEZYyzafpnμm'] if $opt{'human-readable'};
  64 $opt{anchor} //= qr/\A/;
  65 $opt{'value-length'} = 6 if $opt{units};
  66
  67 my (@lines, @values, @order);
  68
  69 if (defined $opt{interval}) {
  70         $opt{interval} ||= 1;
  71         $SIG{ALRM} = sub {
  72                 show_lines();
  73                 alarm $opt{interval};
  74         };
  75         alarm $opt{interval};
  76
  77         eval {
  78                 require Tie::Array::Sorted;
  79                 tie @order, 'Tie::Array::Sorted', sub { $_[1] <=> $_[0] };
  80         } or warn $@, "Expect slowdown with large datasets!\n";
  81 }
  82
  83 $SIG{INT} = sub {
  84         $SIG{INT} = 'DEFAULT';  # reset for subsequent attempts
  85         'IGNORE' # continue after assumed eof
  86 };
  87
  88 my $valmatch = qr/$opt{anchor} ( \h* -? [0-9]* \.? [0-9]+ (?: e[+-]?[0-9]+ )? |)/x;
  89 while (readline) {
  90         s/\r?\n\z//;
  91         s/^\h*// unless $opt{unmodified};
  92         push @values, s/$valmatch/\n/ && $1;
  93         push @order, $1 if length $1;
  94         if (defined $opt{trim} and defined $1) {
  95                 my $trimpos = abs $opt{trim};
  96                 if ($trimpos <= 1) {
  97                         $_ = substr $_, 0, 1;
  98                 }
  99                 elsif (length > $trimpos) {
 100                         substr($_, $trimpos - 1) = '…';
 101                 }
 102         }
 103         push @lines, $_;
 104 }
 105
 106 $SIG{INT} = 'DEFAULT';
 107
 108 sub color {
 109         $opt{color} and defined $_[0] or return '';
 110         return "\e[$_[0]m" if defined wantarray;
 111         $_ = color(@_) . $_ . color(0) if defined;
 112 }
 113
 114 sub show_lines {
 115
 116 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
 117 @lines and @lines > $nr or return;
 118 @lines or return;
 119 @lines > $nr or return unless $opt{hidemin};
 120
 121 @order = sort { $b <=> $a } @order unless tied @order;
 122 my $maxval = ($opt{hidemax} ? max grep { length } @values[0 .. $opt{hidemax} - 1] : $order[0]) // 0;
 123 my $minval = min $order[-1] // (), 0;
 124 my $lenval = $opt{'value-length'} // max map { length } @order;
 125 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
 126         max map { length $values[$_] && length $lines[$_] }
 127                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 128 my $size   = ($maxval - $minval) &&
 129         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 130
 131 my @barmark;
 132 if ($opt{markers} // 1 and $size > 0) {
 133         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 134         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 135         $barmark[ orderpos($#order * .31731) ] = '>';
 136         $barmark[ orderpos($#order * .68269) ] = '<';
 137         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 138         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 139         color(36) for @barmark;
 140
 141         state $lastmax = $maxval;
 142         if ($maxval > $lastmax) {
 143                 print ' ' x ($lenval + $len);
 144                 printf color(90);
 145                 printf '%-*s',
 146                         ($lastmax - $minval) * $size + .5,
 147                         '-' x (($values[$nr - 1] - $minval) * $size);
 148                 print color(92);
 149                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 150                 print color(0);
 151                 $lastmax = $maxval;
 152         }
 153 }
 154
 155 @lines > $nr or return if $opt{hidemin};
 156
 157 sub sival {
 158         my $unit = int(log(abs $_[0] || 1) / log(10) - 3*($_[0] < 1) + 1e-15);
 159         my $float = $_[0] !~ /^0*[-0-9]{1,3}$/;
 160         sprintf('%3.*f%1s',
 161                 $float && ($unit % 3) == ($unit < 0),  # tenths
 162                 $_[0] / 1000 ** int($unit/3),   # number
 163                 $#{$opt{units}} * 1.5 < abs $unit ? "e$unit" : $opt{units}->[$unit/3]
 164         );
 165 }
 166
 167 while ($nr <= $#lines) {
 168         $nr >= $opt{hidemax} and last if defined $opt{hidemax};
 169         my $val = $values[$nr];
 170
 171         if ($opt{spark}) {
 172                 print $opt{spark}->[ ($val - $minval) / $maxval * $#{$opt{spark}} ];
 173                 next;
 174         }
 175
 176         if (length $val) {
 177                 my $color = !$opt{color} ? undef :
 178                         $val == $order[0] ? 32 : # max
 179                         $val == $order[-1] ? 31 : # min
 180                         90;
 181                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 182                 color($color) for $val;
 183         }
 184         my $line = $lines[$nr] =~ s/\n/$val/r;
 185         printf '%-*s', $len + length($val), $line;
 186         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 187         say '';
 188 }
 189 continue {
 190         $nr++;
 191 }
 192 say '' if $opt{spark};
 193
 194 }
 195 show_lines();
 196
 197 if ($opt{stat}) {
 198         if ($opt{hidemin} or $opt{hidemax}) {
 199                 $opt{hidemin} ||= 1;
 200                 $opt{hidemax} ||= @lines;
 201                 printf '%s of ', sum(@values[$opt{hidemin} - 1 .. $opt{hidemax} - 1]) // 0;
 202         }
 203         if (@order) {
 204                 my $total = sum @order;
 205                 printf '%s total', $total;
 206                 printf ' in %d values', scalar @values;
 207                 printf ' (%s min, %*.*f avg, %s max)',
 208                         $order[-1], 0, 2, $total / @order, $order[0];
 209         }
 210         say '';
 211 }
 212
 213 __END__
 214 =encoding utf8
 215
 216 =head1 NAME
 217
 218 barcat - graph to visualize input values
 219
 220 =head1 SYNOPSIS
 221
 222 B<barcat> [<options>] [<input>]
 223
 224 =head1 DESCRIPTION
 225
 226 Visualizes relative sizes of values read from input (file(s) or STDIN).
 227 Contents are concatenated similar to I<cat>,
 228 but numbers are reformatted and a bar graph is appended to each line.
 229
 230 =head1 OPTIONS
 231
 232 =over
 233
 234 =item -c, --[no-]color
 235
 236 Force colored output of values and bar markers.
 237 Defaults on if output is a tty,
 238 disabled otherwise such as when piped or redirected.
 239
 240 =item -f, --field=(<number>|<regexp>)
 241
 242 Compare values after a given number of whitespace separators,
 243 or matching a regular expression.
 244
 245 Unspecified or I<-f0> means values are at the start of each line.
 246 With I<-f1> the second word is taken instead.
 247 A string can indicate the starting position of a value
 248 (such as I<-f:> if preceded by colons),
 249 or capture the numbers itself,
 250 for example I<-f'(\d+)'> for the first digits anywhere.
 251
 252 =item -H, --human-readable
 253
 254 Format values using SI unit prefixes,
 255 turning long numbers like I<12356789> into I<12.4M>.
 256 Also changes an exponent I<1.602176634e-19> to I<160.2z>.
 257 Short integers are aligned but kept without decimal point.
 258
 259 =item -t, --interval[=<seconds>]
 260
 261 Interval time to output partial progress.
 262
 263 =item -l, --length=[-]<size>[%]
 264
 265 Trim line contents (between number and bars)
 266 to a maximum number of characters.
 267 The exceeding part is replaced by an abbreviation sign,
 268 unless C<--length=0>.
 269
 270 Prepend a dash (i.e. make negative) to enforce padding
 271 regardless of encountered contents.
 272
 273 =item -L, --limit=(<count>|<start>-[<end>])
 274
 275 Stop output after a number of lines.
 276 All input is still counted and analyzed for statistics,
 277 but disregarded for padding and bar size.
 278
 279 =item -m, --markers=
 280
 281 Statistical positions to indicate on bars.
 282 Cannot be customized yet,
 283 only disabled by providing an empty argument.
 284
 285 Any value enables all marker characters:
 286
 287 =over 2
 288
 289 =item B<=>
 290
 291 Average:
 292 the sum of all values divided by the number of counted lines.
 293
 294 =item B<+>
 295
 296 Mean, median:
 297 the middle value or average between middle values.
 298
 299 =item B<<>
 300
 301 Standard deviation left of the mean.
 302 Only 16% of all values are lower.
 303
 304 =item B<< > >>
 305
 306 Standard deviation right of the mean.
 307 The part between B<< <--> >> encompass all I<normal> results,
 308 or 68% of all entries.
 309
 310 =back
 311
 312 =item -s, --stat
 313
 314 Total statistics after all data.
 315
 316 =item -u, --unmodified
 317
 318 Do not strip leading whitespace.
 319 Keep original value alignment, which may be significant in some programs.
 320
 321 =item --value-length=<size>
 322
 323 Reserved space for numbers.
 324
 325 =item -w, --width=<columns>
 326
 327 Override the maximum number of columns to use.
 328 Appended graphics will extend to fill up the entire screen.
 329
 330 =back
 331
 332 =head1 EXAMPLES
 333
 334 Draw a sine wave:
 335
 336     seq 30 | awk '{print sin($1/10)}' | barcat
 337
 338 Compare file sizes (with human-readable numbers):
 339
 340     du -d0 -b * | barcat -H
 341
 342 Memory usage of user processes with long names truncated:
 343
 344     ps xo %mem,pid,cmd | barcat -l40
 345
 346 Monitor network latency from prefixed results:
 347
 348     ping google.com | barcat -f'time=\K' -t
 349
 350 Commonly used after counting, for example users on the current server:
 351
 352     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 353
 354 Letter frequencies in text files:
 355
 356     cat /usr/share/games/fortunes/*.u8 |
 357     perl -CS -nE 'say for grep length, split /\PL*/, uc' |
 358     sort | uniq -c | barcat
 359
 360 Number of HTTP requests per day:
 361
 362     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 363
 364 Any kind of database query with counts, preserving returned alignment:
 365
 366     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 367     psql -t | barcat -u
 368
 369 Earthquakes worldwide magnitude 1+ in the last 24 hours:
 370
 371     https://earthquake.usgs.gov/earthquakes/feed/v1.0/summary/1.0_day.csv |
 372     column -tns, | graph -f4 -u -l80%
 373
 374 External datasets, like movies per year:
 375
 376     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 377     perl -054 -nlE 'say if s/^"year"://' | uniq -c | barcat
 378
 379 But please get I<jq> to process JSON
 380 and replace the manual selection by C<< jq '.[].year' >>.
 381
 382 Pokémon height comparison:
 383
 384     curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 385     jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 386
 387 USD/EUR exchange rate from CSV provided by the ECB:
 388
 389     curl https://sdw.ecb.europa.eu/export.do \
 390          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 391     grep '^[12]' | barcat -f',\K' --value-length=7
 392
 393 Total population history from the World Bank dataset (XML):
 394 External datasets, like total population in XML from the World Bank:
 395
 396     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 397     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 398     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 399
 400 And of course various Git statistics, such commit count by year:
 401
 402     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 403
 404 Or the top 3 most frequent authors with statistics over all:
 405
 406     git shortlog -sn | barcat -L3 -s
 407
 408 Activity of the last days (substitute date C<-v-{}d> on BSD):
 409
 410     ( git log --pretty=%ci --since=30day | cut -b-10
 411       seq 0 30 | xargs -i date +%F -d-{}day ) |
 412     sort | uniq -c | awk '$1--' | graph --spark
 413
 414 =head1 AUTHOR
 415
 416 Mischa POSLAWSKY <perl@shiar.org>
 417
 418 =head1 LICENSE
 419
 420 GPL3+.