barcat

   1 #!/usr/bin/env perl
   2 use 5.018;
   3 use warnings;
   4 use utf8;
   5 use List::Util qw( min max sum );
   6 use open qw( :std :utf8 );
   7 use experimental qw( lexical_subs );
   8
   9 our $VERSION = '1.03';
  10
  11 use Getopt::Long '2.33', qw( :config gnu_getopt );
  12 sub podexit {
  13         require Pod::Usage;
  14         Pod::Usage::pod2usage(-exitval => 0, -perldocopt => '-oman', @_);
  15 }
  16 my %opt;
  17 GetOptions(\%opt,
  18         'color|c!',
  19         'C' => sub { $opt{color} = 0 },
  20         'field|f=s' => sub {
  21                 eval {
  22                         local $_ = $_[1];
  23                         $opt{anchor} = /^[0-9]+$/ ? qr/(?:\S*\h+){$_}\K/ : qr/$_/;
  24                 } or die $@ =~ s/(?: at .+)?$/ for option $_[0]/r;
  25         },
  26         'human-readable|H!',
  27         'interval|t:i',
  28         'trim|length|l=s' => sub {
  29                 my ($optname, $optval) = @_;
  30                 $optval =~ s/%$// and $opt{trimpct}++;
  31                 $optval =~ m/^-?[0-9]+$/ or die(
  32                         "Value \"$optval\" invalid for option $optname",
  33                         " (number or percentage expected)\n"
  34                 );
  35                 $opt{trim} = $optval;
  36         },
  37         'value-length=i',
  38         'hidemin=i',
  39         'hidemax=i',
  40         'limit|L=s' => sub {
  41                 my ($optname, $optval) = @_;
  42                 $optval ||= 0;
  43                 ($opt{hidemin}, $opt{hidemax}) =
  44                 $optval =~ m/\A (?: ([0-9]+)? - )? ([0-9]+)? \z/x or die(
  45                         "Value \"$optval\" invalid for option limit",
  46                         " (range expected)\n"
  47                 );
  48         },
  49         'markers|m=s',
  50         'stat|s!',
  51         'unmodified|u!',
  52         'width|w=i',
  53         'usage|h' => sub { podexit() },
  54         'help'    => sub { podexit(-verbose => 2) },
  55 ) or exit 64;  # EX_USAGE
  56
  57 $opt{width} ||= $ENV{COLUMNS} || 80;
  58 $opt{color} //= -t *STDOUT;  # enable on tty
  59 $opt{trim}   *= $opt{width} / 100 if $opt{trimpct};
  60 $opt{units}   = [split //, ' kMGTPEZYyzafpnμm'] if $opt{'human-readable'};
  61 $opt{anchor} //= qr/\A/;
  62 $opt{'value-length'} = 6 if $opt{units};
  63
  64 if (defined $opt{interval}) {
  65         $opt{interval} ||= 1;
  66         $SIG{ALRM} = sub {
  67                 show_lines();
  68                 alarm $opt{interval};
  69         };
  70         alarm $opt{interval};
  71 }
  72
  73 $SIG{INT} = 'IGNORE';  # continue after assumed eof
  74
  75 my (@lines, @values);
  76 my $valmatch = qr/$opt{anchor} ( \h* -? [0-9]* \.? [0-9]+ (?: e[+-]?[0-9]+ )? |)/x;
  77 while (readline) {
  78         s/\r?\n\z//;
  79         s/^\h*// unless $opt{unmodified};
  80         push @values, s/$valmatch/\n/ && $1;
  81         if (defined $opt{trim}) {
  82                 my $trimpos = abs $opt{trim};
  83                 if ($trimpos <= 1) {
  84                         $_ = substr $_, 0, 1;
  85                 }
  86                 elsif (length > $trimpos) {
  87                         substr($_, $trimpos - 1) = '…';
  88                 }
  89         }
  90         push @lines, $_;
  91 }
  92
  93 $SIG{INT} = 'DEFAULT';
  94
  95 my @order;
  96
  97 sub show_lines {
  98
  99 state $nr = $opt{hidemin} ? $opt{hidemin} - 1 : 0;
 100 @lines and @lines > $nr or return;
 101 @lines or return;
 102 @lines > $nr or return unless $opt{hidemin};
 103
 104 @order  = sort { $b <=> $a } grep { length } @values;
 105 my $maxval = ($opt{hidemax} ? max grep { length } @values[0 .. $opt{hidemax} - 1] : $order[0]) // 0;
 106 my $minval = min $order[-1] // (), 0;
 107 my $lenval = $opt{'value-length'} // max map { length } @order;
 108 my $len    = defined $opt{trim} && $opt{trim} <= 0 ? -$opt{trim} + 1 :
 109         max map { length $values[$_] && length $lines[$_] }
 110                 0 .. min $#lines, $opt{hidemax} || ();  # left padding
 111 my $size   = ($maxval - $minval) &&
 112         ($opt{width} - $lenval - $len) / ($maxval - $minval);  # bar multiplication
 113
 114 my @barmark;
 115 if ($opt{markers} // 1 and $size > 0) {
 116         my sub orderpos { (($order[$_[0]] + $order[$_[0] + .5]) / 2 - $minval) * $size }
 117         $barmark[ (sum(@order) / @order - $minval) * $size ] = '=';  # average
 118         $barmark[ orderpos($#order * .31731) ] = '>';
 119         $barmark[ orderpos($#order * .68269) ] = '<';
 120         $barmark[ orderpos($#order / 2) ] = '+';  # mean
 121         $barmark[ -$minval * $size ] = '|' if $minval < 0;  # zero
 122         defined and $opt{color} and $_ = "\e[36m$_\e[0m" for @barmark;
 123
 124         state $lastmax = $maxval;
 125         if ($maxval > $lastmax) {
 126                 print ' ' x ($lenval + $len);
 127                 printf "\e[90m" if $opt{color};
 128                 printf '%-*s',
 129                         ($lastmax - $minval) * $size + .5,
 130                         '-' x (($values[$nr - 1] - $minval) * $size);
 131                 print "\e[92m" if $opt{color};
 132                 say '+' x (($maxval - $lastmax - $minval) * $size + .5);
 133                 print "\e[0m" if $opt{color};
 134                 $lastmax = $maxval;
 135         }
 136 }
 137
 138 @lines > $nr or return if $opt{hidemin};
 139
 140 sub sival {
 141         my $unit = int(log($_[0]) / log(1000) - ($_[0] < 1));
 142         my $float = $_[0] !~ /^ (?: 0*\.)? [0-9]{1,3} $/x;
 143         sprintf('%*.*f%*s',
 144                 $float ? 5 : 3, $float,  # length and tenths
 145                 $_[0] / 1000 ** $unit,   # number
 146                 $float ? 0 : 3,          # unit size
 147                 $#{$opt{units}} >> 1 < abs $unit ? "e$unit" : $opt{units}->[$unit]
 148         );
 149 }
 150
 151 while ($nr <= $#lines) {
 152         $nr >= $opt{hidemax} and last if defined $opt{hidemax};
 153         my $val = $values[$nr];
 154         if (length $val) {
 155                 my $color = !$opt{color} ? 0 :
 156                         $val == $order[0] ? 32 : # max
 157                         $val == $order[-1] ? 31 : # min
 158                         90;
 159                 $val = $opt{units} ? sival($val) : sprintf "%*s", $lenval, $val;
 160                 $val = "\e[${color}m$val\e[0m" if $color;
 161         }
 162         my $line = $lines[$nr] =~ s/\n/$val/r;
 163         printf '%-*s', $len + length($val), $line;
 164         print $barmark[$_] // '-' for 1 .. $size && (($values[$nr] || 0) - $minval) * $size + .5;
 165         say '';
 166
 167         $nr++;
 168 }
 169
 170 }
 171 show_lines();
 172
 173 if ($opt{stat}) {
 174         my $total = sum @order;
 175         printf '%s total', $total;
 176         printf ' in %d values', scalar @values;
 177         printf ' (%s min, %*.*f avg, %s max)',
 178                 $order[-1], 0, 2, $total / @order, $order[0];
 179         say '';
 180 }
 181
 182 __END__
 183
 184 =head1 NAME
 185
 186 barcat - graph to visualize input values
 187
 188 =head1 SYNOPSIS
 189
 190 B<barcat> [<options>] [<input>]
 191
 192 =head1 DESCRIPTION
 193
 194 Visualizes relative sizes of values read from input (file(s) or STDIN).
 195 Contents are concatenated similar to I<cat>,
 196 but numbers are reformatted and a bar graph is appended to each line.
 197
 198 =head1 OPTIONS
 199
 200 =over
 201
 202 =item -c, --[no-]color
 203
 204 Force colored output of values and bar markers.
 205 Defaults on if output is a tty,
 206 disabled otherwise such as when piped or redirected.
 207
 208 =item -f, --field=(<number>|<regexp>)
 209
 210 Compare values after a given number of whitespace separators,
 211 or matching a regular expression.
 212
 213 Unspecified or I<-f0> means values are at the start of each line.
 214 With I<-f1> the second word is taken instead.
 215 A string can indicate the starting position of a value
 216 (such as I<-f:> if preceded by colons),
 217 or capture the numbers itself,
 218 for example I<-f'(\d+)'> for the first digits anywhere.
 219
 220 =item -H, --human-readable
 221
 222 Format values using SI unit prefixes,
 223 turning long numbers like I<12356789> into I<12.4M>.
 224 Also changes an exponent I<1.602176634e-19> to I<160.2z>.
 225 Short integers are aligned but kept without decimal point.
 226
 227 =item -t, --interval[=<seconds>]
 228
 229 Interval time to output partial progress.
 230
 231 =item -l, --length=[-]<size>[%]
 232
 233 Trim line contents (between number and bars)
 234 to a maximum number of characters.
 235 The exceeding part is replaced by an abbreviation sign,
 236 unless C<--length=0>.
 237
 238 Prepend a dash (i.e. make negative) to enforce padding
 239 regardless of encountered contents.
 240
 241 =item -L, --limit=(<count>|<start>-[<end>])
 242
 243 Stop output after a number of lines.
 244 All input is still counted and analyzed for statistics,
 245 but disregarded for padding and bar size.
 246
 247 =item -m, --markers=
 248
 249 Statistical positions to indicate on bars.
 250 Cannot be customized yet,
 251 only disabled by providing an empty argument.
 252
 253 Any value enables all marker characters:
 254
 255 =over 2
 256
 257 =item B<=>
 258
 259 Average:
 260 the sum of all values divided by the number of counted lines.
 261
 262 =item B<+>
 263
 264 Mean, median:
 265 the middle value or average between middle values.
 266
 267 =item B<<>
 268
 269 Standard deviation left of the mean.
 270 Only 16% of all values are lower.
 271
 272 =item B<< > >>
 273
 274 Standard deviation right of the mean.
 275 The part between B<< <--> >> encompass all I<normal> results,
 276 or 68% of all entries.
 277
 278 =back
 279
 280 =item -s, --stat
 281
 282 Total statistics after all data.
 283
 284 =item -u, --unmodified
 285
 286 Do not strip leading whitespace.
 287 Keep original value alignment, which may be significant in some programs.
 288
 289 =item --value-length=<size>
 290
 291 Reserved space for numbers.
 292
 293 =item -w, --width=<columns>
 294
 295 Override the maximum number of columns to use.
 296 Appended graphics will extend to fill up the entire screen.
 297
 298 =back
 299
 300 =head1 EXAMPLES
 301
 302 Commonly used after counting, such as users on the current server:
 303
 304     users | sed 's/ /\n/g' | sort | uniq -c | barcat
 305
 306 Letter frequencies in text files:
 307
 308     cat /usr/share/games/fortunes/*.u8 |
 309     perl -CO -nE 'say for grep length, split /\PL*/, uc' |
 310     sort | uniq -c | barcat
 311
 312 Memory usage of user processes:
 313
 314     ps xo %mem,pid,cmd | barcat -l40
 315
 316 Sizes (in megabytes) of all root files and directories:
 317
 318     du -d0 -m * | barcat
 319
 320 Number of HTTP requests per day:
 321
 322     cat log/access.log | cut -d\  -f4 | cut -d: -f1 | uniq -c | barcat
 323
 324 Any kind of database query with leading counts:
 325
 326     echo 'SELECT count(*),schemaname FROM pg_tables GROUP BY 2' |
 327     psql -t | barcat -u
 328
 329 Exchange rate USD/EUR history from CSV download provided by ECB:
 330
 331     curl https://sdw.ecb.europa.eu/export.do \
 332          -Gd 'node=SEARCHRESULTS&q=EXR.D.USD.EUR.SP00.A&exportType=csv' |
 333     grep '^[12]' | barcat -f',\K' --value-length=7
 334
 335 Total population history from the World Bank dataset (XML):
 336
 337     curl http://api.worldbank.org/v2/country/1W/indicator/SP.POP.TOTL |
 338     xmllint --xpath '//*[local-name()="date" or local-name()="value"]' - |
 339     sed -r 's,</wb:value>,\n,g; s,(<[^>]+>)+, ,g' | barcat -f1 -H
 340
 341 Movies per year from prepared JSON data:
 342
 343     curl https://github.com/prust/wikipedia-movie-data/raw/master/movies.json |
 344     jq '.[].year' | uniq -c | barcat
 345
 346 Pokémon height comparison:
 347
 348         curl https://github.com/Biuni/PokemonGO-Pokedex/raw/master/pokedex.json |
 349         jq -r '.pokemon[] | [.height,.num,.name] | join(" ")' | barcat
 350
 351 Git statistics, such commit count by year:
 352
 353     git log --pretty=%ci | cut -b-4 | uniq -c | barcat
 354
 355 Or the top 3 most frequent authors with statistics over all:
 356
 357     git shortlog -sn | barcat -L3 -s
 358
 359 Latency history:
 360
 361     ping google.com | barcat -f'time=\K' -t
 362
 363 =head1 AUTHOR
 364
 365 Mischa POSLAWSKY <perl@shiar.org>
 366
 367 =head1 LICENSE
 368
 369 GPL3+.