parse-wormedit

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use 5.010;
   5
   6 use Data::Dumper;
   7 use Getopt::Long 2.33 qw(HelpMessage :config bundling);
   8
   9 our $VERSION = '1.03';
  10
  11 GetOptions(\my %opt,
  12         'raw|r',  # full output
  13         'version=i',  # force version
  14 ) or HelpMessage(-exitval => 2);
  15
  16
  17 package Shiar_Parse::WormEdit;
  18
  19 use strict;
  20 use warnings;
  21
  22 our %MAGICID = (
  23         "WormEdit053\000LVL" => 53,
  24         "WormEdit\34195\000LVL" => 95,
  25         "WormEdit\34194\000LVL" => 94,
  26         "WormEdit\34193\000LVL" => 93,
  27 );
  28
  29 my @FORMAT = (
  30         magic       => 'a15',
  31         version     => 'C',
  32         name        => 'Ca32',
  33         description => 'Ca64x256',
  34         levelcount  => [1,
  35                 single => 'C',
  36                 multi  => 'C',
  37                 race   => 'C',
  38                 ctf    => 'C',
  39                 total  => 'C',
  40         ],
  41         moderef     => [1,
  42                 map { (start => $_, end => $_) } [1,
  43                         single     => 'C',
  44                         peaworm    => 'C',
  45                         tron       => 'C',
  46                         deathmatch => 'C',
  47                         foodmatch  => 'C',
  48                         multifood  => 'C',
  49                         timematch  => 'C',
  50                         race       => 'C',
  51                         ctf        => 'Cx',
  52                 ],
  53         ],
  54         sprite     => ['8C',
  55                 line => 'B8',
  56         ],
  57         finish      => [1,
  58                 type    => 's',
  59                 message => 'Ca255',
  60                 code    => 'Ca255x256',
  61         ],
  62         hiname      => 'a3',
  63         levels      => ['*', # levelcount->total actually
  64                 id         => 'Ca22',
  65                 name       => 'Ca22',
  66                 size       => 'C',
  67                 peas       => 'C',
  68                 delay      => 'C',
  69                 growth     => 'C',
  70                 bsize      => 'C',
  71                 sprite     => ['8C',
  72                         line => 'B8',
  73                 ],
  74                 balls      => ['32C',
  75                         y   => 'C',
  76                         x   => 'C',
  77                         dir => 'C',
  78                 ],
  79                 worms      => [4,
  80                         d => 'C',
  81                         y => 'C',
  82                         x => 'C',
  83                 ],
  84                 width      => 'C',
  85                 height     => 'C',
  86                 flags      => [2,
  87                         y => 'C',
  88                         x => 'C',
  89                 ],
  90                 objects    => ['128C',
  91                         type => 'C',
  92                         x1   => 'C',
  93                         y1   => 'C',
  94                         x2   => 'C',
  95                         y2   => 'C',
  96                 ],
  97         ],
  98 );
  99
 100 sub read {
 101         my ($self, $input) = @_;
 102         my ($id, $version) = (substr($input, 0, 15), ord substr($input, 15, 1));
 103         my $fileversion = $MAGICID{$id}
 104                 or die "File does not match any known WormEdit level header\n";
 105
 106         if ($opt{version}) {
 107                 warn "Override version $version to $opt{version}\n";
 108                 $version = $opt{version};
 109         }
 110         elsif ($version != $fileversion) {
 111                 warn "Unexpected version $version (expecting $fileversion)\n";
 112         }
 113         elsif ($version == 95) {
 114                 # auto-detect exact variant
 115                 if (ord substr($input, 70, 1) ~~ [1 .. 8]) {
 116                         # valid sprite length instead of description byte
 117                         # (which is usually a letter or nul)
 118                         $version = 94;
 119                 }
 120                 elsif (ord substr($input, 147, 1) == 0) {
 121                         # nul of finish type is 2 bytes later (unlike first char of message)
 122                         $version = 96;
 123                 }
 124                 warn "Ambiguous file version 95; guessing subversion $version\n";
 125         };
 126
 127         $fileversion += 100 if $fileversion < 90;  # 93..95 came before 50..53
 128         given ($fileversion) {
 129                 when (153) { } # current @FORMAT
 130                         $FORMAT[7] = 'Ca64'; # no reserved space after description
 131                         $FORMAT[15]->[-1] = 'Ca255'; # enddata
 132                         $FORMAT[-1]->[-1]->[0] = '32C'; # less objects
 133                 when ($version == 96) {
 134                         ref $_ and $_->[-1] = 'C' for @{ $FORMAT[11] }; # 9 moderefs
 135                 }
 136                         ref $_ and pop @$_ for @{ $FORMAT[11] }; # only 8 moderefs
 137                         splice @FORMAT, 6, 2 if $version <= 94;  # earlier version without description
 138                 when (95) { }
 139                         splice @{ $FORMAT[7] }, 4, 2;  # no race
 140                         splice @{ $FORMAT[13] }, 4, 2; # no enddata
 141                         splice @{ $FORMAT[-1] }, 1, 2; # no name
 142                 when (94) { }
 143                         splice @FORMAT, 14, 2; # no hiname
 144                         $FORMAT[-1]->[0] = 64; # constant amount of levels
 145                 when (93) { }
 146                 default {
 147                         die "Cannot parse data for Wormedit $fileversion/$version\n";
 148                 }
 149         }
 150
 151         # convert to an easily accessible hash
 152         my @values = unpack Shiar_Parse::Nested->template(\@FORMAT).'a*', $input;
 153         my $data = Shiar_Parse::Nested->convert(\@FORMAT, \@values);
 154         warn "Trailing data left unparsed\n" if grep {length} @values;
 155         $data->{format} = 'WormEdit';
 156         return $data;
 157 }
 158
 159
 160 package Shiar_Parse::WormyLevel;
 161
 162 use strict;
 163 use warnings;
 164
 165 use List::Util qw(sum min max);
 166
 167 sub read {
 168         my ($self, $input) = @_;
 169         my ($psize, $ptype, $size, $type, $vsize, $dsize, $id, $subid) = unpack q{
 170                 x11 x42    # file signature and comment
 171                 S a2 S a2  # file size, type; data size, type
 172                 x8         # var name
 173                 S S        # var size; content size
 174                 CC         # wormy header
 175         }, $input;
 176         $ptype eq "\014\000"
 177                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 178         $size == $psize - 16
 179                 or warn "File size ($size) does not correspond with data size ($psize)\n";
 180         $type eq "\014\010"
 181                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 182         $size == $vsize and $vsize == $dsize+2
 183                 or warn "Mismatch in string data size declarations\n";
 184 #       substr($input, -2) eq $CHECKSUM
 185
 186         $input = substr $input, 73, -2;
 187         $id eq ord 'w'
 188                 or die "Wormy level identifier not found\n";
 189         my @FORMAT = (
 190                 magic       => 'a1',
 191                 version     => 'C',
 192                 name        => 'Z*',
 193                 description => 'Z*',
 194                 levelcount  => [1,
 195                         total  => 'S',
 196                 ],
 197                 moderef     => [1,
 198                         map { (
 199                                 offset => [1, map {$_ => 'S'} @$_], # byte location of start
 200                                 end    => [1, map {$_ => 'C'} @$_],
 201                         ) }
 202                         [qw/single peaworm tron deathmatch foodmatch multifood timematch race ctf/]
 203                 ],
 204                 theanswer => 'C', # 42
 205                 sprite     => ['C',
 206                         line => 'B8',
 207                 ],
 208                 leveldata => 'a*',
 209         );
 210         my @LEVELFORM = (
 211                 peas       => 'C',
 212                 delay      => 'C',
 213                 growth     => 'C',
 214                 bsize      => 'C',
 215                 sprite     => ['C',
 216                         line => 'B8',
 217                 ],
 218                 balls      => ['C',
 219                         y   => 'C',
 220                         x   => 'C',
 221                         dir => 'C',
 222                 ],
 223                 worms      => [1,
 224                         d => 'C',
 225                         y => 'C',
 226                         x => 'C',
 227                 ],
 228                 width      => 'C',
 229                 height     => 'C',
 230                 flags      => [0,
 231                         y => 'C',
 232                         x => 'C',
 233                 ],
 234                 #levels
 235                 #finish code
 236                 #levels-multi
 237                 #hinames
 238         );
 239         my @OBJECTFORM = (
 240                         type => 'C',
 241                         x1   => 'C',
 242                         y1   => 'C',
 243                         x2   => 'C',
 244                         y2   => 'C',
 245         );
 246
 247         given ($subid) {
 248                 when (97) {
 249                         # current @FORMAT
 250                 }
 251                 when (95) {
 252                         ref $_ and splice @$_, -2 for @{ $FORMAT[11] }; # only 8 moderefs
 253                         splice @FORMAT, 12, 2;  # no reserved byte
 254                 }
 255                 default {
 256                         die "Unsupported level version $subid\n";
 257                 }
 258         }
 259
 260         my $data = Shiar_Parse::Nested->unpack(\@FORMAT, $input);
 261         my $offset = 0;
 262         my $offsetbase = 0xF080 + @{ $data->{sprite} } + 1;
 263         $data->{moderef}->{offset}->{single} == $offsetbase
 264                 or warn "First singleplayer level is not in front\n";
 265
 266         my $slots = sum(
 267                 $data->{moderef}->{end}->{single} > 0,  # singleplayer slot if any levels
 268                 $data->{moderef}->{end}->{peaworm},     # one for each peaworm arena
 269                 $data->{moderef}->{end}->{tron},        # idem for tron
 270         );
 271         $data->{hinames} = [ unpack '(x2a3)*', substr($data->{leveldata}, -5 * $slots) ];
 272         $data->{format} = '86s';
 273
 274         my @VARMODES = (
 275                 [qw'single  single'],
 276                 [qw'multi   peaworm tron deathmatch foodmatch multifood timematch'],
 277                 [qw'race    race'],
 278                 [qw'ctf     ctf'],
 279         );
 280
 281         $data->{levels} = [];
 282         for my $modes (@VARMODES) {
 283                 my $variant = shift @$modes;
 284                 $offset = min(grep {$_} map { $data->{moderef}->{offset}->{$_} } @$modes)
 285                         or next;
 286                 $offset -= $offsetbase;
 287                 my $amount = $variant eq 'single' ? 100 : max(map { $data->{moderef}->{end}->{$_} } @$modes);
 288
 289                 my @varform = @LEVELFORM;
 290                 $varform[13]->[0] = $variant eq 'single' ? 1 : 4;
 291                 unshift @varform, name => 'Z*' unless $variant eq 'single';
 292                 $varform[-1]->[0] = 1 if $variant eq 'race';
 293                 $varform[-1]->[0] = 2 if $variant eq 'ctf';
 294
 295                 while ($offset < length $data->{leveldata}) {
 296                         last if substr($data->{leveldata}, $offset, 1) eq chr(255);
 297
 298                         # find references to this level offset, and set start number to matching modes
 299                         while (my ($mode, $location) = each %{ $data->{moderef}->{offset} }) {
 300                                 $location == $offset + $offsetbase or next;
 301                                 $data->{moderef}->{start}->{$mode} = 1 + scalar @{ $data->{levels} };
 302                         }
 303
 304                         my $level = Shiar_Parse::Nested->unpack(
 305                                 [@varform], substr $data->{leveldata}, $offset
 306                         );
 307                         my $size = 8  # unpack length (ugh, ugly recalculation)
 308                                 + (defined $level->{name} ? 1 + length $level->{name} : 0)
 309                                 + 3 * (ref $level->{worms} eq 'ARRAY' ? scalar @{$level->{worms}} : 1)
 310                                 + 2 * ($level->{flags} ? ref $level->{flags} eq 'ARRAY' ? scalar @{$level->{flags}} : 1 : 0)
 311                                 + ($level->{sprite} ? scalar @{$level->{sprite}} : 0)
 312                                 + ($level->{balls} ? 3 * scalar @{$level->{balls}} : 0);
 313                         $level->{size} = $size;
 314                         $level->{offset} = $offset + $offsetbase;
 315
 316                         # add objects until terminator
 317                         $level->{objects} = [];
 318                         while (my $object = ord substr($data->{leveldata}, $offset+$size, 1)) {
 319                                 push @{ $level->{objects} }, Shiar_Parse::Nested->unpack(
 320                                         [@OBJECTFORM], substr($data->{leveldata}, $offset+$size, 5)
 321                                 );
 322                                 $size += 5;
 323                         }
 324
 325                         # add parsed level and advance
 326                         push @{ $data->{levels} }, $level;
 327                         $offset += ++$size;
 328                         last if ++$data->{levelcount}->{$variant} >= $amount;
 329                 }
 330
 331                 if ($variant eq 'single') {
 332                         $offset++;
 333                         $data->{finish}->{code} =
 334                         my $code = substr delete($data->{leveldata}), $offset, -5*$slots;
 335
 336                         my %FINISHCODE = (
 337                                 0 => chr 0xC9, # ret
 338                                 1 => join('',
 339                                         chr 0x21,  # ld hl, MESSAGE
 340                                         pack('v', $offsetbase + $offset + 9),
 341                                         (map {chr}
 342                                                 0xCD, 0x37, 0x4A,  # call _puts
 343                                                 0xC3, 0xAA, 0x55,  # jp _getkey
 344                                         ),
 345                                 ),
 346                                 2 => join('',
 347                                         (map {chr}
 348                                                 0x21, 0, 0x1C,  # ld hl, $POS
 349                                                 0x22, 0x7C, 0xC3, # ld (_penCol), hl
 350                                                 0x21,  # ld hl, MESSAGE
 351                                         ),
 352                                         pack('v', $offsetbase + $offset + 15),
 353                                         (map {chr}
 354                                                 0xCD, 0xA5, 0x4A, # call _vputs
 355                                                 0xC3, 0xAA, 0x55, # jp _getkey
 356                                         ),
 357                                 ),
 358                         );
 359                         while (my ($finish, $match) = each %FINISHCODE) {
 360                                 $match eq substr $code, 0, length $match or next;
 361                                 $data->{finish}->{type} = $finish or last;
 362                                 $data->{finish}->{message} = unpack 'Z*', substr($code, length $match);
 363                                 last;
 364                         }
 365                 }
 366         }
 367
 368         return $data;
 369 }
 370
 371
 372 package Shiar_Parse::Nested;
 373
 374 sub template {
 375         my ($self, $format) = @_;
 376         # total (flattened) unpack template from nested format definitions
 377         return join '', map {
 378                 my $value = $format->[-($_ << 1) - 1];
 379                 if (ref $value eq 'ARRAY') {
 380                         my $count = $value->[0];
 381                         $value = $self->template($value);
 382                         $value = $count =~ s/^([*\d]+)// ? "$count($value)$1"
 383                                 : $count."X[$count]$count/($value)";
 384                 }
 385                 else {
 386                         $value =~ s/^C(a)(\d+)/$1 . ($2 + 1)/e;  # length prefix
 387                 }
 388                 $value;
 389         } reverse 0 .. ($#$format - 1) >> 1;
 390 }
 391
 392 sub convert {
 393         my ($self, $format, $data) = @_;
 394         # map flat results into a named and nested hash
 395         my %res;
 396         while (my ($field, $template) = splice @$format, 0, 2) {
 397                 if (ref $template eq 'ARRAY') {
 398                         my ($count, @subformat) = @$template;
 399                         my $max = $count =~ s/^(\d+)// ? $1 : 0;
 400                         $count = !$count ? $max
 401                                 : $count eq '*' ? $res{levelcount}->{total} : shift @$data;
 402                         $res{$field}->[$_] = $self->convert([@subformat], $data) for 0 .. ($max || $count)-1;
 403                         splice @{ $res{$field} }, $count if $max > $count;
 404                         $res{$field} = $res{$field}->[0] if $max == 1;
 405                         next;
 406                 }
 407                 elsif ($template =~ /^Ca/) {
 408                         $data->[0] = CORE::unpack 'C/a', $data->[0];
 409                 }
 410                 $res{$field} = shift @$data;
 411         }
 412         return \%res;
 413 }
 414
 415 sub unpack {
 416         my ($self, $format, $input) = @_;
 417         my @data = CORE::unpack $self->template($format), $input;
 418         return $self->convert($format, \@data);
 419 }
 420
 421
 422 package main;
 423
 424 my @OBJTYPE = ('none', 'line', 'fat line', 'bar', 'circle');
 425 my @ENDTYPE = ('none', 'message', 'small message');
 426
 427 sub objsummary {
 428         my ($objects) = @_;
 429         my @objtypes = map { $_->{type} } @$objects;
 430         my %count;
 431         $count{$_}++ for @objtypes;
 432         return (@objtypes > 1 && keys %count == 1 && 'all ') . join(', ',
 433                 map { $OBJTYPE[$_] ? $OBJTYPE[$_] . ($count{$_} > 1 && 's') : $_ }
 434                 sort keys %count
 435         );
 436 }
 437
 438 # read and parse all input data
 439 my $data;
 440 local $/;
 441 my $rawdata = readline;
 442 if (substr($rawdata, 0, 11) eq "**TI86**\032\012\000") {
 443         # compiled calculator file
 444         $data = Shiar_Parse::WormyLevel->read($rawdata);
 445 }
 446 elsif (substr($rawdata, 0, 8) eq 'WormEdit') {
 447         # original wormedit source
 448         $data = Shiar_Parse::WormEdit->read($rawdata);
 449 }
 450 else {
 451         die "Unrecognised file type\n";
 452 }
 453
 454 # output with user-preferred formatting
 455 if ($opt{raw}) {
 456         # full data in yaml (human-readable) formatting
 457         require YAML;
 458         local $YAML::CompressSeries;
 459               $YAML::CompressSeries = 0;
 460         my $yml = "# Wormy levelset\n" . YAML::Dump($data);
 461
 462         # inline format of short hashes
 463         $yml =~ s{
 464                 ^(\ *) - \n                          # array indicator
 465                 ((?:\1\ \ [a-z0-9]{1,5}:\ *\d+\n)+)  # simple hash declaration
 466                 (?!\1\ )                             # no further children
 467         }[
 468                 my ($indent, $value) = ($1, $2);
 469                 chop $value;
 470                 $value =~ s/^ +//gm;
 471                 $value =~ s/\n/, /g;
 472                 "$indent- {$value}\n";
 473         ]egmx;
 474
 475         print $yml;
 476 }
 477 else {
 478         print $data->{name};
 479         print " ($data->{description})" if defined $data->{description};
 480         print "\n";
 481         printf "File version: %s\n", "$data->{format} v$data->{version}";
 482         printf "Defaults: %s\n", join('; ',
 483                 'sprite ' . scalar @{ $data->{sprite} },
 484                 defined $data->{hiname} ? 'hiscore by ' . $data->{hiname} : (),
 485         );
 486
 487         my $startnr = 0;
 488         for my $variant (qw/single multi race ctf/) {
 489                 my $count = $data->{levelcount}->{$variant};
 490                 print "\n";
 491                 printf '%s (%s)', ucfirst $variant, $count // 'invalid';
 492                 $count or next;
 493                 print ":";
 494                 for (0 .. $count - 1) {
 495                         my $level = $data->{levels}->[$_ + $startnr];
 496                         printf("\n- %-22s%4s:%3s+%2s%3s %3sx%-3s%s",
 497                                 $level->{id} || $level->{name} || '#'.($_+1),
 498                                 @$level{qw/size bsize growth/},
 499                                 $variant eq 'single' && "x$level->{peas}",
 500                                 @$level{qw/width height/},
 501                                 join(';', map {" $_"} grep {$_}
 502                                         @{$level->{objects}} && sprintf('%2d object%s (%s)',
 503                                                 scalar @{$level->{objects}}, @{$level->{objects}} != 1 && 's',
 504                                                 objsummary($level->{objects}),
 505                                         ),
 506                                         $level->{sprite} && @{$level->{sprite}} && sprintf('sprite %d',
 507                                                 scalar @{$level->{sprite}},
 508                                         ),
 509                                         $level->{balls} && @{$level->{balls}} && sprintf('%d bounc%s',
 510                                                 scalar @{$level->{balls}}, @{$level->{balls}} == 1 ? 'y' : 'ies',
 511                                         ),
 512                                 ),
 513                         );
 514                 }
 515                 $startnr += $count;
 516         }
 517         continue {
 518                 print "\n";
 519                 printf("-- %-21s%4s: %s (%s)\n",
 520                         '(ending)',
 521                         defined $data->{finish}->{code}
 522                                 ? length $data->{finish}->{code} : '?',
 523                         defined $data->{finish}->{type}
 524                                 ? $ENDTYPE[$data->{finish}->{type}] || 'unknown' : 'code',
 525                         $data->{finish}->{message} // '?',
 526                 ) if $variant eq 'single';
 527         }
 528 }
 529
 530 __END__
 531
 532 =head1 NAME
 533
 534 parse-wormedit - Wormy level data parser
 535
 536 =head1 SYNOPSIS
 537
 538  parse-wormedit [--raw] <input.lvl>
 539
 540 =head1 DESCRIPTION
 541
 542 Reads Wormy levels (either original WormEdit source or compiled TI-86 string)
 543 from STDIN or given file, and outputs contents, summarised or in full.
 544
 545 =head1 AUTHOR
 546
 547 Mischa POSLAWSKY <wormy@shiar.org>
 548
 549 =head1 LICENSE
 550
 551 GPL version 3.
 552