parse-wormedit

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use 5.010;
   5
   6 use Data::Dumper;
   7 use Getopt::Long 2.33 qw(HelpMessage :config bundling);
   8
   9 our $VERSION = '1.03';
  10
  11 GetOptions(\my %opt,
  12         'raw|r',  # full output
  13         'version=i',  # force version
  14 ) or HelpMessage(-exitval => 2);
  15
  16
  17 package Shiar_Parse::WormEdit;
  18
  19 use strict;
  20 use warnings;
  21
  22 our %MAGICID = (
  23         "WormEdit053\000LVL" => 53,
  24         "WormEdit\34195\000LVL" => 95,
  25         "WormEdit\34194\000LVL" => 94,
  26         "WormEdit\34193\000LVL" => 93,
  27 );
  28
  29 my @FORMAT = (
  30         magic       => 'a15',
  31         version     => 'C',
  32         name        => 'Ca32',
  33         description => 'Ca64x256',
  34         levelcount  => [1,
  35                 single => 'C',
  36                 multi  => 'C',
  37                 race   => 'C',
  38                 ctf    => 'C',
  39                 total  => 'C',
  40         ],
  41         moderef     => [1,
  42                 map { (start => $_, end => $_) } [1,
  43                         single     => 'C',
  44                         peaworm    => 'C',
  45                         tron       => 'C',
  46                         deathmatch => 'C',
  47                         foodmatch  => 'C',
  48                         multifood  => 'C',
  49                         timematch  => 'C',
  50                         race       => 'C',
  51                         ctf        => 'Cx',
  52                 ],
  53         ],
  54         sprite     => ['8C',
  55                 line => 'B8',
  56         ],
  57         endtype     => 's',
  58         endstr      => 'Ca255',
  59         enddata     => 'Ca255x256',
  60         hiname      => 'a3',
  61         levels      => ['*', # levelcount->total actually
  62                 id         => 'Ca22',
  63                 name       => 'Ca22',
  64                 size       => 'C',
  65                 peas       => 'C',
  66                 delay      => 'C',
  67                 growth     => 'C',
  68                 bsize      => 'C',
  69                 sprite     => ['8C',
  70                         line => 'B8',
  71                 ],
  72                 balls      => ['32C',
  73                         y   => 'C',
  74                         x   => 'C',
  75                         dir => 'C',
  76                 ],
  77                 worms      => [4,
  78                         d => 'C',
  79                         y => 'C',
  80                         x => 'C',
  81                 ],
  82                 width      => 'C',
  83                 height     => 'C',
  84                 flags      => [2,
  85                         y => 'C',
  86                         x => 'C',
  87                 ],
  88                 objects    => ['128C',
  89                         type => 'C',
  90                         x1   => 'C',
  91                         y1   => 'C',
  92                         x2   => 'C',
  93                         y2   => 'C',
  94                 ],
  95         ],
  96 );
  97
  98 sub read {
  99         my ($self, $input) = @_;
 100         my ($id, $version) = (substr($input, 0, 15), ord substr($input, 15, 1));
 101         my $fileversion = $MAGICID{$id}
 102                 or die "File does not match any known WormEdit level header\n";
 103
 104         if ($opt{version}) {
 105                 warn "Override version $version to $opt{version}\n";
 106                 $version = $opt{version};
 107         }
 108         elsif ($version != $fileversion) {
 109                 warn "Unexpected version $version (expecting $fileversion)\n";
 110         }
 111         elsif ($version == 95) {
 112                 # auto-detect exact variant
 113                 if (ord substr($input, 70, 1) ~~ [1 .. 8]) {
 114                         # valid sprite length instead of description byte
 115                         # (which is usually a letter or nul)
 116                         $version = 94;
 117                 }
 118                 elsif (ord substr($input, 147, 1) == 0) {
 119                         # nul of end type is 2 bytes later (unlike first char of endstr)
 120                         $version = 96;
 121                 }
 122                 warn "Ambiguous file version 95; guessing subversion $version\n";
 123         };
 124
 125         $fileversion += 100 if $fileversion < 90;  # 93..95 came before 50..53
 126         given ($fileversion) {
 127                 when (153) { } # current @FORMAT
 128                         $FORMAT[7] = 'Ca64'; # no reserved space after description
 129                         $FORMAT[19] = 'Ca255'; # enddata
 130                         $FORMAT[-1]->[-1]->[0] = '32C'; # less objects
 131                 when ($version == 96) {
 132                         ref $_ and $_->[-1] = 'C' for @{ $FORMAT[11] }; # 9 moderefs
 133                 }
 134                         ref $_ and pop @$_ for @{ $FORMAT[11] }; # only 8 moderefs
 135                         splice @FORMAT, 6, 2 if $version <= 94;  # earlier version without description
 136                 when (95) { }
 137                         splice @{ $FORMAT[7] }, 4, 2;  # no race
 138                         splice @FORMAT, 16, 2; # no enddata
 139                         splice @{ $FORMAT[-1] }, 1, 2; # no name
 140                 when (94) { }
 141                         splice @FORMAT, 16, 2; # no hiname
 142                         $FORMAT[-1]->[0] = 64; # constant amount of levels
 143                 when (93) { }
 144                 default {
 145                         die "Cannot parse data for Wormedit $fileversion/$version\n";
 146                 }
 147         }
 148
 149         # convert to an easily accessible hash
 150         my @values = unpack Shiar_Parse::Nested->template(\@FORMAT).'a*', $input;
 151         my $data = Shiar_Parse::Nested->convert(\@FORMAT, \@values);
 152         warn "Trailing data left unparsed\n" if grep {length} @values;
 153         $data->{format} = 'WormEdit';
 154         return $data;
 155 }
 156
 157
 158 package Shiar_Parse::WormyLevel;
 159
 160 use strict;
 161 use warnings;
 162
 163 use List::Util qw(sum min max);
 164
 165 sub read {
 166         my ($self, $input) = @_;
 167         my ($psize, $ptype, $size, $type, $vsize, $dsize, $id, $subid) = unpack q{
 168                 x11 x42    # file signature and comment
 169                 S a2 S a2  # file size, type; data size, type
 170                 x8         # var name
 171                 S S        # var size; content size
 172                 CC         # wormy header
 173         }, $input;
 174         $ptype eq "\014\000"
 175                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 176         $size == $psize - 16
 177                 or warn "File size ($size) does not correspond with data size ($psize)\n";
 178         $type eq "\014\010"
 179                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 180         $size == $vsize and $vsize == $dsize+2
 181                 or warn "Mismatch in string data size declarations\n";
 182 #       substr($input, -2) eq $CHECKSUM
 183
 184         $input = substr $input, 73, -2;
 185         $id eq ord 'w'
 186                 or die "Wormy level identifier not found\n";
 187         my @FORMAT = (
 188                 magic       => 'a1',
 189                 version     => 'C',
 190                 name        => 'Z*',
 191                 description => 'Z*',
 192                 levelcount  => [1,
 193                         total  => 'S',
 194                 ],
 195                 moderef     => [1,
 196                         map { (
 197                                 offset => [1, map {$_ => 'S'} @$_], # byte location of start
 198                                 end    => [1, map {$_ => 'C'} @$_],
 199                         ) }
 200                         [qw/single peaworm tron deathmatch foodmatch multifood timematch race ctf/]
 201                 ],
 202                 theanswer => 'C', # 42
 203                 sprite     => ['C',
 204                         line => 'B8',
 205                 ],
 206                 leveldata => 'a*',
 207         );
 208         my @LEVELFORM = (
 209                 peas       => 'C',
 210                 delay      => 'C',
 211                 growth     => 'C',
 212                 bsize      => 'C',
 213                 sprite     => ['C',
 214                         line => 'B8',
 215                 ],
 216                 balls      => ['C',
 217                         y   => 'C',
 218                         x   => 'C',
 219                         dir => 'C',
 220                 ],
 221                 worms      => [1,
 222                         d => 'C',
 223                         y => 'C',
 224                         x => 'C',
 225                 ],
 226                 width      => 'C',
 227                 height     => 'C',
 228                 flags      => [0,
 229                         y => 'C',
 230                         x => 'C',
 231                 ],
 232                 #levels
 233                 #enddata
 234                 #levels-multi
 235                 #hinames
 236         );
 237         my @OBJECTFORM = (
 238                         type => 'C',
 239                         x1   => 'C',
 240                         y1   => 'C',
 241                         x2   => 'C',
 242                         y2   => 'C',
 243         );
 244
 245         given ($subid) {
 246                 when (97) {
 247                         # current @FORMAT
 248                 }
 249                 when (95) {
 250                         ref $_ and splice @$_, -2 for @{ $FORMAT[11] }; # only 8 moderefs
 251                         splice @FORMAT, 12, 2;  # no reserved byte
 252                 }
 253                 default {
 254                         die "Unsupported level version $subid\n";
 255                 }
 256         }
 257
 258         my $data = Shiar_Parse::Nested->unpack(\@FORMAT, $input);
 259         my $offset = 0;
 260         my $offsetbase = 0xF080 + @{ $data->{sprite} } + 1;
 261         $data->{moderef}->{offset}->{single} == $offsetbase
 262                 or warn "First singleplayer level is not in front\n";
 263
 264         my @VARMODES = (
 265                 [qw'single  single'],
 266                 [qw'multi   peaworm tron deathmatch foodmatch multifood timematch'],
 267                 [qw'race    race'],
 268                 [qw'ctf     ctf'],
 269         );
 270
 271         $data->{levels} = [];
 272         for my $modes (@VARMODES) {
 273                 my $variant = shift @$modes;
 274                 $offset = min(map { $data->{moderef}->{offset}->{$_} } @$modes) - $offsetbase;
 275                 my $amount = $variant eq 'single' ? 100 : max(map { $data->{moderef}->{end}->{$_} } @$modes);
 276
 277                 my @varform = @LEVELFORM;
 278                 $varform[13]->[0] = $variant eq 'single' ? 1 : 4;
 279                 unshift @varform, name => 'Z*' unless $variant eq 'single';
 280                 $varform[-1]->[0] = 1 if $variant eq 'race';
 281                 $varform[-1]->[0] = 2 if $variant eq 'ctf';
 282
 283                 while ($offset < length $data->{leveldata}) {
 284                         last if substr($data->{leveldata}, $offset, 1) eq chr(255);
 285
 286                         # find references to this level offset, and set start number to matching modes
 287                         while (my ($mode, $location) = each %{ $data->{moderef}->{offset} }) {
 288                                 $location == $offset + $offsetbase or next;
 289                                 $data->{moderef}->{start}->{$mode} = 1 + scalar @{ $data->{levels} };
 290                         }
 291
 292                         my $level = Shiar_Parse::Nested->unpack(
 293                                 [@varform], substr $data->{leveldata}, $offset
 294                         );
 295                         my $size = 8  # unpack length (ugh, ugly recalculation)
 296                                 + (defined $level->{name} ? 1 + length $level->{name} : 0)
 297                                 + 3 * (ref $level->{worms} eq 'ARRAY' ? scalar @{$level->{worms}} : 1)
 298                                 + 2 * ($level->{flags} ? ref $level->{flags} eq 'ARRAY' ? scalar @{$level->{flags}} : 1 : 0)
 299                                 + ($level->{sprite} ? scalar @{$level->{sprite}} : 0)
 300                                 + ($level->{balls} ? 3 * scalar @{$level->{balls}} : 0);
 301                         $level->{size} = $size;
 302                         $level->{offset} = $offset + $offsetbase;
 303
 304                         # add objects until terminator
 305                         $level->{objects} = [];
 306                         while (my $object = ord substr($data->{leveldata}, $offset+$size, 1)) {
 307                                 push @{ $level->{objects} }, Shiar_Parse::Nested->unpack(
 308                                         [@OBJECTFORM], substr($data->{leveldata}, $offset+$size, 5)
 309                                 );
 310                                 $size += 5;
 311                         }
 312
 313                         # add parsed level and advance
 314                         push @{ $data->{levels} }, $level;
 315                         $offset += ++$size;
 316                         last if ++$data->{levelcount}->{$variant} >= $amount;
 317                 }
 318         }
 319
 320         my $slots = sum(
 321                 $data->{moderef}->{end}->{single} > 0,  # singleplayer slot if any levels
 322                 $data->{moderef}->{end}->{peaworm},     # one for each peaworm arena
 323                 $data->{moderef}->{end}->{tron},        # idem for tron
 324         );
 325         $data->{hinames} = [ unpack '(x2a3)*', substr($data->{leveldata}, -5 * $slots) ];
 326         $data->{enddata} = substr delete($data->{leveldata}), $offset, -5 * $slots; #XXX
 327         $data->{format} = '86s';
 328         return $data;
 329 }
 330
 331
 332 package Shiar_Parse::Nested;
 333
 334 sub template {
 335         my ($self, $format) = @_;
 336         # total (flattened) unpack template from nested format definitions
 337         return join '', map {
 338                 my $value = $format->[-($_ << 1) - 1];
 339                 if (ref $value eq 'ARRAY') {
 340                         my $count = $value->[0];
 341                         $value = $self->template($value);
 342                         $value = $count =~ s/^([*\d]+)// ? "$count($value)$1"
 343                                 : $count."X[$count]$count/($value)";
 344                 }
 345                 else {
 346                         $value =~ s/^C(a)(\d+)/$1 . ($2 + 1)/e;  # length prefix
 347                 }
 348                 $value;
 349         } reverse 0 .. ($#$format - 1) >> 1;
 350 }
 351
 352 sub convert {
 353         my ($self, $format, $data) = @_;
 354         # map flat results into a named and nested hash
 355         my %res;
 356         while (my ($field, $template) = splice @$format, 0, 2) {
 357                 if (ref $template eq 'ARRAY') {
 358                         my ($count, @subformat) = @$template;
 359                         my $max = $count =~ s/^(\d+)// ? $1 : 0;
 360                         $count = !$count ? $max
 361                                 : $count eq '*' ? $res{levelcount}->{total} : shift @$data;
 362                         $res{$field}->[$_] = $self->convert([@subformat], $data) for 0 .. ($max || $count)-1;
 363                         splice @{ $res{$field} }, $count if $max > $count;
 364                         $res{$field} = $res{$field}->[0] if $max == 1;
 365                         next;
 366                 }
 367                 elsif ($template =~ /^Ca/) {
 368                         $data->[0] = CORE::unpack 'C/a', $data->[0];
 369                 }
 370                 $res{$field} = shift @$data;
 371         }
 372         return \%res;
 373 }
 374
 375 sub unpack {
 376         my ($self, $format, $input) = @_;
 377         my @data = CORE::unpack $self->template($format), $input;
 378         return $self->convert($format, \@data);
 379 }
 380
 381
 382 package main;
 383
 384 my @OBJTYPE = ('none', 'line', 'fat line', 'bar', 'circle');
 385 my @ENDTYPE = ('none', 'message', 'small message');
 386
 387 sub objsummary {
 388         my ($objects) = @_;
 389         my @objtypes = map { $_->{type} } @$objects;
 390         my %count;
 391         $count{$_}++ for @objtypes;
 392         return (@objtypes > 1 && keys %count == 1 && 'all ') . join(', ',
 393                 map { $OBJTYPE[$_] ? $OBJTYPE[$_] . ($count{$_} > 1 && 's') : $_ }
 394                 sort keys %count
 395         );
 396 }
 397
 398 # read and parse all input data
 399 my $data;
 400 local $/;
 401 my $rawdata = readline;
 402 if (substr($rawdata, 0, 11) eq "**TI86**\032\012\000") {
 403         # compiled calculator file
 404         $data = Shiar_Parse::WormyLevel->read($rawdata);
 405 }
 406 elsif (substr($rawdata, 0, 8) eq 'WormEdit') {
 407         # original wormedit source
 408         $data = Shiar_Parse::WormEdit->read($rawdata);
 409 }
 410 else {
 411         die "Unrecognised file type\n";
 412 }
 413
 414 # output with user-preferred formatting
 415 if ($opt{raw}) {
 416         # full data in yaml (human-readable) formatting
 417         require YAML;
 418         local $YAML::CompressSeries;
 419               $YAML::CompressSeries = 0;
 420         my $yml = "# Wormy levelset\n" . YAML::Dump($data);
 421
 422         # inline format of short hashes
 423         $yml =~ s{
 424                 ^(\ *) - \n                          # array indicator
 425                 ((?:\1\ \ [a-z0-9]{1,5}:\ *\d+\n)+)  # simple hash declaration
 426                 (?!\1\ )                             # no further children
 427         }[
 428                 my ($indent, $value) = ($1, $2);
 429                 chop $value;
 430                 $value =~ s/^ +//gm;
 431                 $value =~ s/\n/, /g;
 432                 "$indent- {$value}\n";
 433         ]egmx;
 434
 435         print $yml;
 436 }
 437 else {
 438         print $data->{name};
 439         print " ($data->{description})" if defined $data->{description};
 440         print "\n";
 441         printf "File version: %s\n", "$data->{format} v$data->{version}";
 442         printf "Defaults: %s\n", join('; ',
 443                 'sprite ' . scalar @{ $data->{sprite} },
 444                 defined $data->{hiname} ? 'hiscore by ' . $data->{hiname} : (),
 445         );
 446
 447         my $startnr = 0;
 448         for my $variant (qw/single multi race ctf/) {
 449                 my $count = $data->{levelcount}->{$variant};
 450                 print "\n";
 451                 printf '%s (%s)', ucfirst $variant, $count // 'invalid';
 452                 $count or next;
 453                 print ":";
 454                 for (0 .. $count - 1) {
 455                         my $level = $data->{levels}->[$_ + $startnr];
 456                         printf("\n- %-22s%4s:%3s+%2s%3s %3sx%-3s%s",
 457                                 $level->{id} || $level->{name} || '#'.($_+1),
 458                                 @$level{qw/size bsize growth/},
 459                                 $variant eq 'single' && "x$level->{peas}",
 460                                 @$level{qw/width height/},
 461                                 join(';', map {" $_"} grep {$_}
 462                                         @{$level->{objects}} && sprintf('%2d object%s (%s)',
 463                                                 scalar @{$level->{objects}}, @{$level->{objects}} != 1 && 's',
 464                                                 objsummary($level->{objects}),
 465                                         ),
 466                                         $level->{sprite} && @{$level->{sprite}} && sprintf('sprite %d',
 467                                                 scalar @{$level->{sprite}},
 468                                         ),
 469                                         $level->{balls} && @{$level->{balls}} && sprintf('%d bounc%s',
 470                                                 scalar @{$level->{balls}}, @{$level->{balls}} == 1 ? 'y' : 'ies',
 471                                         ),
 472                                 ),
 473                         );
 474                 }
 475                 $startnr += $count;
 476         }
 477         continue {
 478                 print "\n";
 479                 printf("-- %-21s%4s: %s (%s)\n",
 480                         '(ending)',
 481                         defined $data->{enddata} ? length $data->{enddata} : '?',
 482                         defined $data->{endtype} ? $ENDTYPE[$data->{endtype}] || 'unknown' : 'code',
 483                         $data->{endstr} // '?',
 484                 ) if $variant eq 'single';
 485         }
 486 }
 487
 488 __END__
 489
 490 =head1 NAME
 491
 492 parse-wormedit - Wormy level data parser
 493
 494 =head1 SYNOPSIS
 495
 496  parse-wormedit [--raw] <input.lvl>
 497
 498 =head1 DESCRIPTION
 499
 500 Reads Wormy levels (either original WormEdit source or compiled TI-86 string)
 501 from STDIN or given file, and outputs contents, summarised or in full.
 502
 503 =head1 AUTHOR
 504
 505 Mischa POSLAWSKY <wormy@shiar.org>
 506
 507 =head1 LICENSE
 508
 509 GPL version 3.
 510