parse-wormedit

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use 5.010;
   5
   6 use Data::Dumper;
   7 use Getopt::Long 2.33 qw(HelpMessage :config bundling);
   8
   9 our $VERSION = '1.04';
  10
  11 GetOptions(\my %opt,
  12         'raw|r',  # full output
  13         'version=i',  # force version
  14 ) or HelpMessage(-exitval => 2);
  15
  16
  17 package Shiar_Parse::WormEdit;
  18
  19 use strict;
  20 use warnings;
  21
  22 use Parse::Binary::Nested qw(unpackf);
  23
  24 our %MAGICID = (
  25         "WormEdit053\000LVL" => 53,
  26         "WormEdit\34195\000LVL" => 95,
  27         "WormEdit\34194\000LVL" => 94,
  28         "WormEdit\34193\000LVL" => 93,
  29 );
  30
  31 my @FORMAT = (
  32         magic       => 'a15',
  33         version     => 'C',
  34         name        => 'C/a32',
  35         description => 'C/a64x256',
  36         levelcount  => [1,
  37                 single => 'C',
  38                 multi  => 'C',
  39                 race   => 'C',
  40                 ctf    => 'C',
  41                 total  => 'C',
  42         ],
  43         moderef     => [1,
  44                 map { (start => $_, end => $_) } [1,
  45                         single     => 'C',
  46                         peaworm    => 'C',
  47                         tron       => 'C',
  48                         deathmatch => 'C',
  49                         foodmatch  => 'C',
  50                         multifood  => 'C',
  51                         timematch  => 'C',
  52                         race       => 'C',
  53                         ctf        => 'C',
  54                         reserved   => 'x',
  55                 ],
  56         ],
  57         sprite     => ['8C',
  58                 line => 'B8',
  59         ],
  60         finish      => [1,
  61                 type    => 's',
  62                 message => 'C/a255',
  63                 code    => 'C/a255',
  64                 reserved=> 'x256',
  65         ],
  66         hiname      => 'a3',
  67         levels      => ['*', # levelcount->total actually
  68                 id         => 'C/a22',
  69                 name       => 'C/a22',
  70                 size       => 'C',
  71                 peas       => 'C',
  72                 delay      => 'C',
  73                 growth     => 'C',
  74                 bsize      => 'C',
  75                 sprite     => ['8C',
  76                         line => 'B8',
  77                 ],
  78                 balls      => ['32C',
  79                         y   => 'C',
  80                         x   => 'C',
  81                         dir => 'C',
  82                 ],
  83                 worms      => [4,
  84                         d => 'C',
  85                         y => 'C',
  86                         x => 'C',
  87                 ],
  88                 width      => 'C',
  89                 height     => 'C',
  90                 flags      => [2,
  91                         y => 'C',
  92                         x => 'C',
  93                 ],
  94                 objects    => ['128C',
  95                         type => 'C',
  96                         x1   => 'C',
  97                         y1   => 'C',
  98                         x2   => 'C',
  99                         y2   => 'C',
 100                 ],
 101         ],
 102 );
 103
 104 sub read {
 105         my ($self, $input) = @_;
 106         my ($id, $version) = (substr($input, 0, 15), ord substr($input, 15, 1));
 107         my $fileversion = $MAGICID{$id}
 108                 or die "File does not match any known WormEdit level header\n";
 109
 110         if ($opt{version}) {
 111                 warn "Override version $version to $opt{version}\n";
 112                 $version = $opt{version};
 113         }
 114         elsif ($version != $fileversion) {
 115                 warn "Unexpected version $version (expecting $fileversion)\n";
 116         }
 117         elsif ($version == 95) {
 118                 # auto-detect exact variant
 119                 if (ord substr($input, 70, 1) ~~ [1 .. 8]) {
 120                         # valid sprite length instead of description byte
 121                         # (which is usually a letter or nul)
 122                         $version = 94;
 123                 }
 124                 elsif (ord substr($input, 147, 1) == 0) {
 125                         # nul of finish type is 2 bytes later (unlike first char of message)
 126                         $version = 96;
 127                 }
 128                 warn "Ambiguous file version 95; guessing subversion $version\n";
 129         };
 130
 131         $fileversion += 100 if $fileversion < 90;  # 93..95 came before 50..53
 132         given ($fileversion) {
 133                 when (153) { } # current @FORMAT
 134                         $FORMAT[7] = 'C/a64'; # no reserved space after description
 135                         splice @{ $FORMAT[15] }, -2; # finish reserve
 136                         $FORMAT[-1]->[-1]->[0] = '32C'; # less objects
 137                         ref $_ and pop @$_ for @{ $FORMAT[11] }; # 9 moderefs
 138                 when ($version == 96) { }
 139                         ref $_ and pop @$_ for @{ $FORMAT[11] }; # only 8 moderefs (no ctf)
 140                         splice @FORMAT, 6, 2 if $version <= 94;  # earlier version without description
 141                 when (95) { }
 142                         splice @{ $FORMAT[7] }, 4, 2;  # no race
 143                         splice @{ $FORMAT[13] }, 4, 2; # no enddata
 144                         splice @{ $FORMAT[-1] }, 1, 2; # no name
 145                 when (94) { }
 146                         splice @FORMAT, 14, 2; # no hiname
 147                         $FORMAT[-1]->[0] = 64; # constant amount of levels
 148                 when (93) { }
 149                 default {
 150                         die "Cannot parse data for Wormedit $fileversion/$version\n";
 151                 }
 152         }
 153
 154         # convert to an easily accessible hash
 155         push @FORMAT, -trail => 'a*';
 156         my $data = unpackf(\@FORMAT, $input);
 157         warn "Trailing data left unparsed\n" if length delete $data->{-trail};
 158         $data->{format} = 'WormEdit';
 159         return $data;
 160 }
 161
 162
 163 package Shiar_Parse::WormyLevel;
 164
 165 use strict;
 166 use warnings;
 167
 168 use List::Util qw(sum min max);
 169 use Data::Dumper;
 170 use Parse::Binary::Nested qw(unpackf);
 171
 172 sub read {
 173         my ($self, $input) = @_;
 174         my ($psize, $ptype, $size, $type, $vsize, $dsize, $id, $version) = unpack q{
 175                 x11 x42    # file signature and comment
 176                 S a2 S a2  # file size, type; data size, type
 177                 x8         # var name
 178                 S S        # var size; content size
 179                 CC         # wormy header
 180         }, $input;
 181         $ptype eq "\014\000"
 182                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 183         $size == $psize - 16
 184                 or warn "File size ($size) does not correspond with data size ($psize)\n";
 185         $type eq "\014\010"
 186                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 187         $size == $vsize and $vsize == $dsize+2
 188                 or warn "Mismatch in string data size declarations\n";
 189 #       substr($input, -2) eq $CHECKSUM
 190
 191         $input = substr $input, 73, -2;
 192         $id eq ord 'w'
 193                 or die "Wormy level identifier not found\n";
 194
 195         if ($opt{version}) {
 196                 warn "Override version $version to $opt{version}\n";
 197                 $version = $opt{version};
 198         }
 199         elsif ($version == 95) {
 200                 # level offset instead of description byte
 201                 $version-- if (unpack('x2Z*x2xC', $input))[1] == 0xF4;
 202                 warn "Ambiguous file version 95; guessing subversion $version\n";
 203         }
 204
 205         my @FORMAT = (
 206                 magic       => 'a1',
 207                 version     => 'C',
 208                 name        => 'Z*',
 209                 description => 'Z*',
 210                 levelcount  => [1,
 211                         total  => 'S',
 212                 ],
 213                 moderef     => [1,
 214                         map { (
 215                                 offset => [1, map {$_ => 'S'} @$_], # byte location of start
 216                                 end    => [1, map {$_ => 'C'} @$_],
 217                         ) }
 218                         [qw/single peaworm tron deathmatch foodmatch multifood timematch race ctf/]
 219                 ],
 220                 theanswer => 'x', # 42
 221                 sprite     => ['C',
 222                         line => 'B8',
 223                 ],
 224                 leveldata => 'a*',
 225                 #levels
 226                 #finish code
 227                 #levels-multi
 228                 #hinames
 229         );
 230         my @LEVELFORM = (
 231                 peas       => 'C',
 232                 delay      => 'C',
 233                 growth     => 'C',
 234                 bsize      => 'C',
 235                 sprite     => ['C',
 236                         line => 'B8',
 237                 ],
 238                 balls      => ['C',
 239                         y   => 'C',
 240                         x   => 'C',
 241                         dir => 'C',
 242                 ],
 243                 worms      => [1,
 244                         d => 'C',
 245                         y => 'C',
 246                         x => 'C',
 247                 ],
 248                 width      => 'C',
 249                 height     => 'C',
 250                 flags      => [0,
 251                         y => 'C',
 252                         x => 'C',
 253                 ],
 254                 objects    => ['?0',
 255                         type => 'C',
 256                         x1   => 'C',
 257                         y1   => 'C',
 258                         x2   => 'C',
 259                         y2   => 'C',
 260                 ],
 261         );
 262         my $offsetbase = 0xF080;
 263
 264         given ($version) {
 265                 when (97) {
 266                         # current @FORMAT
 267                 }
 268                         $offsetbase = 0xF400;
 269                 when (96) {}
 270                         ref $_ and splice(@$_, -8, 2) for @{ $FORMAT[11] }; # no multifood
 271                         splice @FORMAT, 12, 2;  # no reserved byte
 272                 when (95) {}
 273                         splice @FORMAT, 6, 2;  # no description
 274                 when (94) {}
 275                 when (90) {
 276                         $FORMAT[5] = 'C/a';  # length-preceding name
 277                         splice @FORMAT, 10, 2;  # no default sprite
 278                         ref $_ and do {
 279                                 $_->[5] = $_->[7];  # no tron; deathmatch instead
 280                                 $_->[7] = $_->[9];  # foodmatch instead
 281                                 $_->[9] = 'linkmatch';  # replaces timematch
 282                                 $_->[11] = $_->[13];  # race
 283                                 $_->[13] = $_->[15];  # ctf
 284                                 $_->[15] = 'domination';
 285                         } for @{ $FORMAT[9] }; # no multifood
 286                         splice @LEVELFORM, -2;
 287                         push @LEVELFORM, "objects$_" => ['C',
 288                                 type => "=$_",
 289                                 map {$_ => 'C'} qw(x1 y1 x2 y2)
 290                         ] for 2, 3;
 291                 }
 292                 default {
 293                         die "Unsupported level version $version\n";
 294                 }
 295         }
 296
 297         my $data = unpackf(\@FORMAT, $input);
 298         my $offset = 0;
 299         $offsetbase += 1 + @{ $data->{sprite} } if $data->{sprite};
 300         $data->{moderef}->{offset}->{single} == $offsetbase
 301                 or warn "First singleplayer level is not in front\n";
 302
 303         my $slots = sum(
 304                 $data->{moderef}->{end}->{single} > 0,  # singleplayer slot if any levels
 305                 $data->{moderef}->{end}->{peaworm},     # one for each peaworm arena
 306                 $data->{moderef}->{end}->{tron},        # idem for tron
 307         );
 308         $data->{hinames} = [ unpack '(x2a3)*', substr($data->{leveldata}, -5 * $slots) ];
 309         $data->{format} = '86s';
 310
 311         my @VARMODES = (
 312                 [qw'single  single'],
 313                 [qw'multi   peaworm tron deathmatch foodmatch multifood timematch'],
 314                 [qw'race    race'],
 315                 [qw'ctf     ctf'],
 316         );
 317
 318         $data->{levels} = [];
 319         for my $modes (@VARMODES) {
 320                 my $variant = shift @$modes;
 321                 my @modeoffsets = grep {defined} #TODO: comment
 322                         map { $data->{moderef}->{offset}->{$_} } @$modes;
 323                 @modeoffsets or next;
 324                 $data->{levelcount}->{$variant} = 0;
 325                 $offset = min(grep {$_} @modeoffsets) or next;
 326                 $offset -= $offsetbase;
 327                 my $amount = $variant eq 'single' ? 100
 328                         : max(grep {defined} map { $data->{moderef}->{end}->{$_} } @$modes);
 329
 330                 my @varform = @LEVELFORM;
 331                 $varform[13]->[0] = $variant eq 'single' ? 1 : 4;
 332                 unshift @varform, name => 'Z*' unless $variant eq 'single' or $version <= 91;
 333                 $varform[-3]->[0] = 1 if $variant eq 'race' and $version > 91;
 334                 $varform[-3]->[0] = 2 if $variant eq 'ctf';
 335                 push @varform, size => '=.';
 336                 my $parselevel = Parse::Binary::Nested->new(\@varform);
 337
 338                 while ($offset < length $data->{leveldata}) {
 339                         last if substr($data->{leveldata}, $offset, 1) eq chr(255);
 340
 341                         # find references to this level offset, and set start number to matching modes
 342                         while (my ($mode, $location) = each %{ $data->{moderef}->{offset} }) {
 343                                 $location == $offset + $offsetbase or next;
 344                                 $data->{moderef}->{start}->{$mode} = 1 + scalar @{ $data->{levels} };
 345                         }
 346
 347                         my $level = $parselevel->unpackf(substr $data->{leveldata}, $offset);
 348                         $level->{offset} = $offset + $offsetbase;
 349
 350                         # add objects until terminator
 351                         $level->{objects} = [];
 352                 if ($version <= 91) {
 353                         ref $_ eq 'ARRAY' and push @{ $level->{objects} }, @$_
 354                                 for map { delete $level->{"objects$_"} } 2, 3;
 355                 }
 356
 357                         # add parsed level and advance
 358                         push @{ $data->{levels} }, $level;
 359                         $offset += $level->{size};
 360                         last if ++$data->{levelcount}->{$variant} >= $amount;
 361                 }
 362
 363                 if ($variant eq 'single') {
 364                         $offset++;
 365                         $data->{finish}->{code} =
 366                         my $code = substr $data->{leveldata}, $offset, -5*$slots;
 367
 368                         my %FINISHCODE = (
 369                                 0 => chr 0xC9, # ret
 370                                 1 => join('',
 371                                         chr 0x21,  # ld hl, MESSAGE
 372                                         pack('v', $offsetbase + $offset + 9),
 373                                         (map {chr}
 374                                                 0xCD, 0x37, 0x4A,  # call _puts
 375                                                 0xC3, 0xAA, 0x55,  # jp _getkey
 376                                         ),
 377                                 ),
 378                                 2 => join('',
 379                                         (map {chr}
 380                                                 0x21, 0, 0x1C,  # ld hl, $POS
 381                                                 0x22, 0x7C, 0xC3, # ld (_penCol), hl
 382                                                 0x21,  # ld hl, MESSAGE
 383                                         ),
 384                                         pack('v', $offsetbase + $offset + 15),
 385                                         (map {chr}
 386                                                 0xCD, 0xA5, 0x4A, # call _vputs
 387                                                 0xC3, 0xAA, 0x55, # jp _getkey
 388                                         ),
 389                                 ),
 390                         );
 391                         while (my ($finish, $match) = each %FINISHCODE) {
 392                                 $match eq substr $code, 0, length $match or next;
 393                                 $data->{finish}->{type} = $finish and
 394                                 $data->{finish}->{message} = unpack 'Z*', substr($code, length $match);
 395                                 last;
 396                         }
 397                 }
 398         }
 399
 400         return $data;
 401 }
 402
 403
 404 package main;
 405
 406 my @OBJTYPE = ('none', 'line', 'fat line', 'bar', 'circle');
 407 my @ENDTYPE = ('none', 'message', 'small message');
 408
 409 sub objsummary {
 410         my ($objects) = @_;
 411         my @objtypes = map { $_->{type} } @$objects;
 412         my %count;
 413         $count{$_}++ for @objtypes;
 414         return (@objtypes > 1 && keys %count == 1 && 'all ') . join(', ',
 415                 map { $OBJTYPE[$_] ? $OBJTYPE[$_] . ($count{$_} > 1 && 's') : $_ }
 416                 sort keys %count
 417         );
 418 }
 419
 420 # read and parse all input data
 421 my $data;
 422 local $/;
 423 my $rawdata = readline;
 424 if (substr($rawdata, 0, 11) eq "**TI86**\032\012\000") {
 425         # compiled calculator file
 426         $data = Shiar_Parse::WormyLevel->read($rawdata);
 427 }
 428 elsif (substr($rawdata, 0, 8) eq 'WormEdit') {
 429         # original wormedit source
 430         $data = Shiar_Parse::WormEdit->read($rawdata);
 431 }
 432 else {
 433         die "Unrecognised file type\n";
 434 }
 435
 436 # output with user-preferred formatting
 437 if ($opt{raw}) {
 438         # full data in yaml (human-readable) formatting
 439         require YAML;
 440         local $YAML::CompressSeries;
 441               $YAML::CompressSeries = 0;
 442         my $yml = "# Wormy levelset\n" . YAML::Dump($data);
 443
 444         # inline format of short hashes
 445         $yml =~ s{
 446                 ^(\ *) - \n                          # array indicator
 447                 ((?:\1\ \ [a-z0-9]{1,5}:\ *\d+\n)+)  # simple hash declaration
 448                 (?!\1\ )                             # no further children
 449         }[
 450                 my ($indent, $value) = ($1, $2);
 451                 chop $value;
 452                 $value =~ s/^ +//gm;
 453                 $value =~ s/\n/, /g;
 454                 "$indent- {$value}\n";
 455         ]egmx;
 456
 457         print $yml;
 458 }
 459 else {
 460         print $data->{name};
 461         print " ($data->{description})" if defined $data->{description};
 462         print "\n";
 463         printf "File version: %s\n", "$data->{format} v$data->{version}";
 464         printf "Defaults: %s\n", join('; ',
 465                 $data->{sprite} ? 'sprite ' . scalar @{ $data->{sprite} } : (),
 466                 defined $data->{hiname} ? 'hiscore by ' . $data->{hiname} : (),
 467         );
 468
 469         my $startnr = 0;
 470         for my $variant (qw/single multi race ctf/) {
 471                 my $count = $data->{levelcount}->{$variant};
 472                 print "\n";
 473                 printf '%s (%s)', ucfirst $variant, $count // 'invalid';
 474                 $count or next;
 475                 print ":";
 476                 for (0 .. $count - 1) {
 477                         my $level = $data->{levels}->[$_ + $startnr];
 478                         printf("\n- %-22s%4s:%3s+%2s%3s %3sx%-3s%s",
 479                                 $level->{id} || $level->{name} || '#'.($_+1),
 480                                 @$level{qw/size bsize growth/},
 481                                 $variant eq 'single' && "x$level->{peas}",
 482                                 @$level{qw/width height/},
 483                                 join(';', map {" $_"} grep {$_}
 484                                         @{$level->{objects}} && sprintf('%2d object%s (%s)',
 485                                                 scalar @{$level->{objects}}, @{$level->{objects}} != 1 && 's',
 486                                                 objsummary($level->{objects}),
 487                                         ),
 488                                         $level->{sprite} && @{$level->{sprite}} && sprintf('sprite %d',
 489                                                 scalar @{$level->{sprite}},
 490                                         ),
 491                                         $level->{balls} && @{$level->{balls}} && sprintf('%d bounc%s',
 492                                                 scalar @{$level->{balls}}, @{$level->{balls}} == 1 ? 'y' : 'ies',
 493                                         ),
 494                                 ),
 495                         );
 496                 }
 497                 $startnr += $count;
 498         }
 499         continue {
 500                 print "\n";
 501                 printf("-- %-21s%4s: %s (%s)\n",
 502                         '(ending)',
 503                         defined $data->{finish}->{code}
 504                                 ? length $data->{finish}->{code} : '?',
 505                         defined $data->{finish}->{type}
 506                                 ? $ENDTYPE[$data->{finish}->{type}] || 'unknown' : 'code',
 507                         $data->{finish}->{message} // '?',
 508                 ) if $variant eq 'single';
 509         }
 510 }
 511
 512 __END__
 513
 514 =head1 NAME
 515
 516 parse-wormedit - Wormy level data parser
 517
 518 =head1 SYNOPSIS
 519
 520  parse-wormedit [--raw] <input.lvl>
 521
 522 =head1 DESCRIPTION
 523
 524 Reads Wormy levels (either original WormEdit source or compiled TI-86 string)
 525 from STDIN or given file, and outputs contents, summarised or in full.
 526
 527 =head1 AUTHOR
 528
 529 Mischa POSLAWSKY <wormy@shiar.org>
 530
 531 =head1 LICENSE
 532
 533 GPL version 3.
 534