parse-wormedit

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use 5.010;
   5
   6 use Data::Dumper;
   7 use Getopt::Long 2.33 qw(HelpMessage :config bundling);
   8
   9 our $VERSION = '1.04';
  10
  11 GetOptions(\my %opt,
  12         'raw|r',  # full output
  13         'version=i',  # force version
  14 ) or HelpMessage(-exitval => 2);
  15
  16
  17 package Shiar_Parse::WormEdit;
  18
  19 use strict;
  20 use warnings;
  21
  22 use Parse::Binary::Nested;
  23
  24 our %MAGICID = (
  25         "WormEdit053\000LVL" => 53,
  26         "WormEdit\34195\000LVL" => 95,
  27         "WormEdit\34194\000LVL" => 94,
  28         "WormEdit\34193\000LVL" => 93,
  29 );
  30
  31 my @FORMAT = (
  32         magic       => 'a15',
  33         version     => 'C',
  34         name        => 'Ca32',
  35         description => 'Ca64x256',
  36         levelcount  => [1,
  37                 single => 'C',
  38                 multi  => 'C',
  39                 race   => 'C',
  40                 ctf    => 'C',
  41                 total  => 'C',
  42         ],
  43         moderef     => [1,
  44                 map { (start => $_, end => $_) } [1,
  45                         single     => 'C',
  46                         peaworm    => 'C',
  47                         tron       => 'C',
  48                         deathmatch => 'C',
  49                         foodmatch  => 'C',
  50                         multifood  => 'C',
  51                         timematch  => 'C',
  52                         race       => 'C',
  53                         ctf        => 'C',
  54                         reserved   => 'x',
  55                 ],
  56         ],
  57         sprite     => ['8C',
  58                 line => 'B8',
  59         ],
  60         finish      => [1,
  61                 type    => 's',
  62                 message => 'Ca255',
  63                 code    => 'Ca255',
  64                 reserved=> 'x256',
  65         ],
  66         hiname      => 'a3',
  67         levels      => ['*', # levelcount->total actually
  68                 id         => 'Ca22',
  69                 name       => 'Ca22',
  70                 size       => 'C',
  71                 peas       => 'C',
  72                 delay      => 'C',
  73                 growth     => 'C',
  74                 bsize      => 'C',
  75                 sprite     => ['8C',
  76                         line => 'B8',
  77                 ],
  78                 balls      => ['32C',
  79                         y   => 'C',
  80                         x   => 'C',
  81                         dir => 'C',
  82                 ],
  83                 worms      => [4,
  84                         d => 'C',
  85                         y => 'C',
  86                         x => 'C',
  87                 ],
  88                 width      => 'C',
  89                 height     => 'C',
  90                 flags      => [2,
  91                         y => 'C',
  92                         x => 'C',
  93                 ],
  94                 objects    => ['128C',
  95                         type => 'C',
  96                         x1   => 'C',
  97                         y1   => 'C',
  98                         x2   => 'C',
  99                         y2   => 'C',
 100                 ],
 101         ],
 102 );
 103
 104 sub read {
 105         my ($self, $input) = @_;
 106         my ($id, $version) = (substr($input, 0, 15), ord substr($input, 15, 1));
 107         my $fileversion = $MAGICID{$id}
 108                 or die "File does not match any known WormEdit level header\n";
 109
 110         if ($opt{version}) {
 111                 warn "Override version $version to $opt{version}\n";
 112                 $version = $opt{version};
 113         }
 114         elsif ($version != $fileversion) {
 115                 warn "Unexpected version $version (expecting $fileversion)\n";
 116         }
 117         elsif ($version == 95) {
 118                 # auto-detect exact variant
 119                 if (ord substr($input, 70, 1) ~~ [1 .. 8]) {
 120                         # valid sprite length instead of description byte
 121                         # (which is usually a letter or nul)
 122                         $version = 94;
 123                 }
 124                 elsif (ord substr($input, 147, 1) == 0) {
 125                         # nul of finish type is 2 bytes later (unlike first char of message)
 126                         $version = 96;
 127                 }
 128                 warn "Ambiguous file version 95; guessing subversion $version\n";
 129         };
 130
 131         $fileversion += 100 if $fileversion < 90;  # 93..95 came before 50..53
 132         given ($fileversion) {
 133                 when (153) { } # current @FORMAT
 134                         $FORMAT[7] = 'Ca64'; # no reserved space after description
 135                         splice @{ $FORMAT[15] }, -2; # finish reserve
 136                         $FORMAT[-1]->[-1]->[0] = '32C'; # less objects
 137                         ref $_ and pop @$_ for @{ $FORMAT[11] }; # 9 moderefs
 138                 when ($version == 96) { }
 139                         ref $_ and pop @$_ for @{ $FORMAT[11] }; # only 8 moderefs (no ctf)
 140                         splice @FORMAT, 6, 2 if $version <= 94;  # earlier version without description
 141                 when (95) { }
 142                         splice @{ $FORMAT[7] }, 4, 2;  # no race
 143                         splice @{ $FORMAT[13] }, 4, 2; # no enddata
 144                         splice @{ $FORMAT[-1] }, 1, 2; # no name
 145                 when (94) { }
 146                         splice @FORMAT, 14, 2; # no hiname
 147                         $FORMAT[-1]->[0] = 64; # constant amount of levels
 148                 when (93) { }
 149                 default {
 150                         die "Cannot parse data for Wormedit $fileversion/$version\n";
 151                 }
 152         }
 153
 154         # convert to an easily accessible hash
 155         push @FORMAT, -trail => 'a*';
 156         my $data = Parse::Binary::Nested->new(\@FORMAT)->unpackf($input);
 157         warn "Trailing data left unparsed\n" if length delete $data->{-trail};
 158         $data->{format} = 'WormEdit';
 159         return $data;
 160 }
 161
 162
 163 package Shiar_Parse::WormyLevel;
 164
 165 use strict;
 166 use warnings;
 167
 168 use List::Util qw(sum min max);
 169 use Data::Dumper;
 170 use Parse::Binary::Nested;
 171
 172 sub read {
 173         my ($self, $input) = @_;
 174         my ($psize, $ptype, $size, $type, $vsize, $dsize, $id, $version) = unpack q{
 175                 x11 x42    # file signature and comment
 176                 S a2 S a2  # file size, type; data size, type
 177                 x8         # var name
 178                 S S        # var size; content size
 179                 CC         # wormy header
 180         }, $input;
 181         $ptype eq "\014\000"
 182                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 183         $size == $psize - 16
 184                 or warn "File size ($size) does not correspond with data size ($psize)\n";
 185         $type eq "\014\010"
 186                 or die "Not a calculator string, thus cannot be a Wormy level file\n";
 187         $size == $vsize and $vsize == $dsize+2
 188                 or warn "Mismatch in string data size declarations\n";
 189 #       substr($input, -2) eq $CHECKSUM
 190
 191         $input = substr $input, 73, -2;
 192         $id eq ord 'w'
 193                 or die "Wormy level identifier not found\n";
 194
 195         if ($opt{version}) {
 196                 warn "Override version $version to $opt{version}\n";
 197                 $version = $opt{version};
 198         }
 199         elsif ($version == 95) {
 200                 # level offset instead of description byte
 201                 $version-- if (unpack('x2Z*x2xC', $input))[1] == 0xF4;
 202                 warn "Ambiguous file version 95; guessing subversion $version\n";
 203         }
 204
 205         my @FORMAT = (
 206                 magic       => 'a1',
 207                 version     => 'C',
 208                 name        => 'Z*',
 209                 description => 'Z*',
 210                 levelcount  => [1,
 211                         total  => 'S',
 212                 ],
 213                 moderef     => [1,
 214                         map { (
 215                                 offset => [1, map {$_ => 'S'} @$_], # byte location of start
 216                                 end    => [1, map {$_ => 'C'} @$_],
 217                         ) }
 218                         [qw/single peaworm tron deathmatch foodmatch multifood timematch race ctf/]
 219                 ],
 220                 theanswer => 'x', # 42
 221                 sprite     => ['C',
 222                         line => 'B8',
 223                 ],
 224                 leveldata => 'a*',
 225         );
 226         my @LEVELFORM = (
 227                 peas       => 'C',
 228                 delay      => 'C',
 229                 growth     => 'C',
 230                 bsize      => 'C',
 231                 sprite     => ['C',
 232                         line => 'B8',
 233                 ],
 234                 balls      => ['C',
 235                         y   => 'C',
 236                         x   => 'C',
 237                         dir => 'C',
 238                 ],
 239                 worms      => [1,
 240                         d => 'C',
 241                         y => 'C',
 242                         x => 'C',
 243                 ],
 244                 width      => 'C',
 245                 height     => 'C',
 246                 flags      => [0,
 247                         y => 'C',
 248                         x => 'C',
 249                 ],
 250                 #levels
 251                 #finish code
 252                 #levels-multi
 253                 #hinames
 254         );
 255         my @OBJECTFORM = (
 256                         type => 'C',
 257                         x1   => 'C',
 258                         y1   => 'C',
 259                         x2   => 'C',
 260                         y2   => 'C',
 261         );
 262         my $offsetbase = 0xF080;
 263
 264         given ($version) {
 265                 when (97) {
 266                         # current @FORMAT
 267                 }
 268                         $offsetbase = 0xF400;
 269                 when (96) {}
 270                         ref $_ and splice(@$_, -8, 2) for @{ $FORMAT[11] }; # no multifood
 271                         splice @FORMAT, 12, 2;  # no reserved byte
 272                 when (95) {}
 273                         splice @FORMAT, 6, 2;  # no description
 274                 when (94) {}
 275                 when (90) {
 276                         $FORMAT[5] = 'C/a';  # length-preceding name
 277                         splice @FORMAT, 10, 2;  # no default sprite
 278                         ref $_ and do {
 279                                 $_->[5] = $_->[7];  # no tron; deathmatch instead
 280                                 $_->[7] = $_->[9];  # foodmatch instead
 281                                 $_->[9] = 'linkmatch';  # replaces timematch
 282                                 $_->[11] = $_->[13];  # race
 283                                 $_->[13] = $_->[15];  # ctf
 284                                 $_->[15] = 'domination';
 285                         } for @{ $FORMAT[9] }; # no multifood
 286                         push @LEVELFORM, "object$_" => ['C',
 287                                 map {$_ => 'C'} qw(x1 y1 x2 y2)
 288                         ] for qw(lines boxes);
 289                 }
 290                 default {
 291                         die "Unsupported level version $version\n";
 292                 }
 293         }
 294
 295         my $data = Parse::Binary::Nested->new(\@FORMAT)->unpackf($input);
 296         my $offset = 0;
 297         $offsetbase += 1 + @{ $data->{sprite} } if $data->{sprite};
 298         $data->{moderef}->{offset}->{single} == $offsetbase
 299                 or warn "First singleplayer level is not in front\n";
 300
 301         my $slots = sum(
 302                 $data->{moderef}->{end}->{single} > 0,  # singleplayer slot if any levels
 303                 $data->{moderef}->{end}->{peaworm},     # one for each peaworm arena
 304                 $data->{moderef}->{end}->{tron},        # idem for tron
 305         );
 306         $data->{hinames} = [ unpack '(x2a3)*', substr($data->{leveldata}, -5 * $slots) ];
 307         $data->{format} = '86s';
 308
 309         my @VARMODES = (
 310                 [qw'single  single'],
 311                 [qw'multi   peaworm tron deathmatch foodmatch multifood timematch'],
 312                 [qw'race    race'],
 313                 [qw'ctf     ctf'],
 314         );
 315
 316         $data->{levels} = [];
 317         for my $modes (@VARMODES) {
 318                 my $variant = shift @$modes;
 319                 my @modeoffsets = grep {defined} #TODO: comment
 320                         map { $data->{moderef}->{offset}->{$_} } @$modes;
 321                 @modeoffsets or next;
 322                 $data->{levelcount}->{$variant} = 0;
 323                 $offset = min(grep {$_} @modeoffsets) or next;
 324                 $offset -= $offsetbase;
 325                 my $amount = $variant eq 'single' ? 100
 326                         : max(grep {defined} map { $data->{moderef}->{end}->{$_} } @$modes);
 327
 328                 my @varform = @LEVELFORM;
 329                 $varform[13]->[0] = $variant eq 'single' ? 1 : 4;
 330                 unshift @varform, name => 'Z*' unless $variant eq 'single' or $version <= 91;
 331                 $varform[-1]->[0] = 1 if $variant eq 'race' and $version > 91;
 332                 $varform[-1]->[0] = 2 if $variant eq 'ctf';
 333                 my $parselevel = Parse::Binary::Nested->new(\@varform);
 334
 335                 while ($offset < length $data->{leveldata}) {
 336                         last if substr($data->{leveldata}, $offset, 1) eq chr(255);
 337
 338                         # find references to this level offset, and set start number to matching modes
 339                         while (my ($mode, $location) = each %{ $data->{moderef}->{offset} }) {
 340                                 $location == $offset + $offsetbase or next;
 341                                 $data->{moderef}->{start}->{$mode} = 1 + scalar @{ $data->{levels} };
 342                         }
 343
 344                         my $level = $parselevel->unpackf(substr $data->{leveldata}, $offset);
 345                         my $size = 8  # unpack length (ugh, ugly recalculation)
 346                                 + (defined $level->{name} ? 1 + length $level->{name} : 0)
 347                                 + 3 * (ref $level->{worms} eq 'ARRAY' ? scalar @{$level->{worms}} : 1)
 348                                 + 2 * ($level->{flags} ? ref $level->{flags} eq 'ARRAY' ? scalar @{$level->{flags}} : 1 : 0)
 349                                 + ($level->{sprite} ? scalar @{$level->{sprite}} : 0)
 350                                 + ($level->{balls} ? 3 * scalar @{$level->{balls}} : 0);
 351                         $level->{size} = $size;
 352                         $level->{offset} = $offset + $offsetbase;
 353
 354                         # add objects until terminator
 355                         $level->{objects} = [];
 356                 if ($version <= 91) {
 357                         push @{ $level->{objects} }, { %$_, type => 2 } for map { $level->{$_} ? @{ $level->{$_} } : () } qw(objectlines);
 358                         push @{ $level->{objects} }, { %$_, type => 3 } for map { $level->{$_} ? @{ $level->{$_} } : () } qw(objectboxes);
 359                         $size += 1 + 4 * scalar @{ $level->{objects} };
 360                 }
 361                 else {
 362                         while (my $object = ord substr($data->{leveldata}, $offset+$size, 1)) {
 363                                 push @{ $level->{objects} }, Parse::Binary::Nested->new([@OBJECTFORM])->unpackf(
 364                                         substr $data->{leveldata}, $offset+$size, 5
 365                                 );
 366                                 $size += 5;
 367                         }
 368                 }
 369
 370                         # add parsed level and advance
 371                         push @{ $data->{levels} }, $level;
 372                         $offset += ++$size;
 373                         last if ++$data->{levelcount}->{$variant} >= $amount;
 374                 }
 375
 376                 if ($variant eq 'single') {
 377                         $offset++;
 378                         $data->{finish}->{code} =
 379                         my $code = substr $data->{leveldata}, $offset, -5*$slots;
 380
 381                         my %FINISHCODE = (
 382                                 0 => chr 0xC9, # ret
 383                                 1 => join('',
 384                                         chr 0x21,  # ld hl, MESSAGE
 385                                         pack('v', $offsetbase + $offset + 9),
 386                                         (map {chr}
 387                                                 0xCD, 0x37, 0x4A,  # call _puts
 388                                                 0xC3, 0xAA, 0x55,  # jp _getkey
 389                                         ),
 390                                 ),
 391                                 2 => join('',
 392                                         (map {chr}
 393                                                 0x21, 0, 0x1C,  # ld hl, $POS
 394                                                 0x22, 0x7C, 0xC3, # ld (_penCol), hl
 395                                                 0x21,  # ld hl, MESSAGE
 396                                         ),
 397                                         pack('v', $offsetbase + $offset + 15),
 398                                         (map {chr}
 399                                                 0xCD, 0xA5, 0x4A, # call _vputs
 400                                                 0xC3, 0xAA, 0x55, # jp _getkey
 401                                         ),
 402                                 ),
 403                         );
 404                         while (my ($finish, $match) = each %FINISHCODE) {
 405                                 $match eq substr $code, 0, length $match or next;
 406                                 $data->{finish}->{type} = $finish and
 407                                 $data->{finish}->{message} = unpack 'Z*', substr($code, length $match);
 408                                 last;
 409                         }
 410                 }
 411         }
 412
 413         return $data;
 414 }
 415
 416
 417 package main;
 418
 419 my @OBJTYPE = ('none', 'line', 'fat line', 'bar', 'circle');
 420 my @ENDTYPE = ('none', 'message', 'small message');
 421
 422 sub objsummary {
 423         my ($objects) = @_;
 424         my @objtypes = map { $_->{type} } @$objects;
 425         my %count;
 426         $count{$_}++ for @objtypes;
 427         return (@objtypes > 1 && keys %count == 1 && 'all ') . join(', ',
 428                 map { $OBJTYPE[$_] ? $OBJTYPE[$_] . ($count{$_} > 1 && 's') : $_ }
 429                 sort keys %count
 430         );
 431 }
 432
 433 # read and parse all input data
 434 my $data;
 435 local $/;
 436 my $rawdata = readline;
 437 if (substr($rawdata, 0, 11) eq "**TI86**\032\012\000") {
 438         # compiled calculator file
 439         $data = Shiar_Parse::WormyLevel->read($rawdata);
 440 }
 441 elsif (substr($rawdata, 0, 8) eq 'WormEdit') {
 442         # original wormedit source
 443         $data = Shiar_Parse::WormEdit->read($rawdata);
 444 }
 445 else {
 446         die "Unrecognised file type\n";
 447 }
 448
 449 # output with user-preferred formatting
 450 if ($opt{raw}) {
 451         # full data in yaml (human-readable) formatting
 452         require YAML;
 453         local $YAML::CompressSeries;
 454               $YAML::CompressSeries = 0;
 455         my $yml = "# Wormy levelset\n" . YAML::Dump($data);
 456
 457         # inline format of short hashes
 458         $yml =~ s{
 459                 ^(\ *) - \n                          # array indicator
 460                 ((?:\1\ \ [a-z0-9]{1,5}:\ *\d+\n)+)  # simple hash declaration
 461                 (?!\1\ )                             # no further children
 462         }[
 463                 my ($indent, $value) = ($1, $2);
 464                 chop $value;
 465                 $value =~ s/^ +//gm;
 466                 $value =~ s/\n/, /g;
 467                 "$indent- {$value}\n";
 468         ]egmx;
 469
 470         print $yml;
 471 }
 472 else {
 473         print $data->{name};
 474         print " ($data->{description})" if defined $data->{description};
 475         print "\n";
 476         printf "File version: %s\n", "$data->{format} v$data->{version}";
 477         printf "Defaults: %s\n", join('; ',
 478                 $data->{sprite} ? 'sprite ' . scalar @{ $data->{sprite} } : (),
 479                 defined $data->{hiname} ? 'hiscore by ' . $data->{hiname} : (),
 480         );
 481
 482         my $startnr = 0;
 483         for my $variant (qw/single multi race ctf/) {
 484                 my $count = $data->{levelcount}->{$variant};
 485                 print "\n";
 486                 printf '%s (%s)', ucfirst $variant, $count // 'invalid';
 487                 $count or next;
 488                 print ":";
 489                 for (0 .. $count - 1) {
 490                         my $level = $data->{levels}->[$_ + $startnr];
 491                         printf("\n- %-22s%4s:%3s+%2s%3s %3sx%-3s%s",
 492                                 $level->{id} || $level->{name} || '#'.($_+1),
 493                                 @$level{qw/size bsize growth/},
 494                                 $variant eq 'single' && "x$level->{peas}",
 495                                 @$level{qw/width height/},
 496                                 join(';', map {" $_"} grep {$_}
 497                                         @{$level->{objects}} && sprintf('%2d object%s (%s)',
 498                                                 scalar @{$level->{objects}}, @{$level->{objects}} != 1 && 's',
 499                                                 objsummary($level->{objects}),
 500                                         ),
 501                                         $level->{sprite} && @{$level->{sprite}} && sprintf('sprite %d',
 502                                                 scalar @{$level->{sprite}},
 503                                         ),
 504                                         $level->{balls} && @{$level->{balls}} && sprintf('%d bounc%s',
 505                                                 scalar @{$level->{balls}}, @{$level->{balls}} == 1 ? 'y' : 'ies',
 506                                         ),
 507                                 ),
 508                         );
 509                 }
 510                 $startnr += $count;
 511         }
 512         continue {
 513                 print "\n";
 514                 printf("-- %-21s%4s: %s (%s)\n",
 515                         '(ending)',
 516                         defined $data->{finish}->{code}
 517                                 ? length $data->{finish}->{code} : '?',
 518                         defined $data->{finish}->{type}
 519                                 ? $ENDTYPE[$data->{finish}->{type}] || 'unknown' : 'code',
 520                         $data->{finish}->{message} // '?',
 521                 ) if $variant eq 'single';
 522         }
 523 }
 524
 525 __END__
 526
 527 =head1 NAME
 528
 529 parse-wormedit - Wormy level data parser
 530
 531 =head1 SYNOPSIS
 532
 533  parse-wormedit [--raw] <input.lvl>
 534
 535 =head1 DESCRIPTION
 536
 537 Reads Wormy levels (either original WormEdit source or compiled TI-86 string)
 538 from STDIN or given file, and outputs contents, summarised or in full.
 539
 540 =head1 AUTHOR
 541
 542 Mischa POSLAWSKY <wormy@shiar.org>
 543
 544 =head1 LICENSE
 545
 546 GPL version 3.
 547