parse-wormedit

   1 #!/usr/bin/env perl
   2 use 5.010;
   3 use strict;
   4 use warnings;
   5 use experimental 'switch';
   6 use lib 'lib';  # make runnable for simple cases
   7
   8 use Data::Dumper;
   9 use Getopt::Long 2.33 qw(HelpMessage :config bundling);
  10 use Games::Wormy::TICalcLevels;
  11 use Games::Wormy::WormEdit;
  12
  13 our $VERSION = '1.07';
  14
  15 GetOptions(\my %opt,
  16         'format|f=s', # output type
  17         'raw|r!',  # compatibility for yaml format
  18         'version=i',  # force version
  19         'levels|render:i',  # image of level(s)
  20         'output|o=s',  # output file
  21 ) or HelpMessage(-exitval => 2);
  22 $opt{format} //= 'yaml' if $opt{raw};
  23 $opt{format} //= 'pnm'  if defined $opt{levels};
  24
  25 my @OBJTYPE = ('none', 'line', 'fat line', 'bar', 'circle');
  26 my @ENDTYPE = ('none', 'message', 'small message');
  27
  28 sub objsummary {
  29         my ($objects) = @_;
  30         my @objtypes = map { $_->{type} } @$objects;
  31         my %count;
  32         $count{$_}++ for @objtypes;
  33         return (@objtypes > 1 && keys %count == 1 && 'all ') . join(', ',
  34                 map { $OBJTYPE[$_] ? $OBJTYPE[$_] . ($count{$_} > 1 && 's') : $_ }
  35                 sort keys %count
  36         );
  37 }
  38
  39 # read and parse all input data
  40 my $data;
  41 local $/;
  42 my $rawdata = readline;
  43 if (substr($rawdata, 0, 11) eq "**TI86**\032\012\000") {
  44         # compiled calculator file
  45         $data = Games::Wormy::TICalcLevels->read($rawdata, $opt{version});
  46 }
  47 elsif (substr($rawdata, 0, 8) eq 'WormEdit') {
  48         # original wormedit source
  49         $data = Games::Wormy::WormEdit->read($rawdata, $opt{version});
  50 }
  51 else {
  52         die "Unrecognised file type\n";
  53 }
  54
  55 if ($opt{output}) {{
  56         # derive format from file extension
  57         if ($opt{output} =~ /\.(yaml|json|txt)$/) {
  58                 $opt{format} //= $1
  59         }
  60         else {
  61                 # images are written directly to file
  62                 last;
  63         }
  64
  65         # redirect standard output to given file
  66         open my $output, '>', $opt{output}
  67                 or die "Cannot output to '$opt{output}': $!";
  68         select $output;
  69 }}
  70
  71 # output with user-preferred formatting
  72 given ($opt{format}) {
  73 when ('json') {
  74         require JSON;
  75         say JSON->new->encode($data);
  76 }
  77 when ('yaml') {
  78         # full data in yaml (human-readable) formatting
  79         require YAML;
  80         local $YAML::CompressSeries;
  81               $YAML::CompressSeries = 0;
  82         my $yml = "# Wormy levelset\n" . YAML::Dump($data);
  83
  84         # inline format of short hashes
  85         $yml =~ s{
  86                 ^(\ *) - \n                          # array indicator
  87                 ((?:\1\ \ [a-z0-9]{1,5}:\ *\d+\n)+)  # simple hash declaration
  88                 (?!\1\ )                             # no further children
  89         }[
  90                 my ($indent, $value) = ($1, $2);
  91                 chop $value;
  92                 $value =~ s/^ +//gm;
  93                 $value =~ s/\n/, /g;
  94                 "$indent- {$value}\n";
  95         ]egmx;
  96
  97         print $yml;
  98 }
  99 when ('txt') {
 100         print $data->{name};
 101         print " ($data->{description})" if defined $data->{description};
 102         print "\n";
 103         printf "File version: %s\n", "$data->{format} v$data->{version}";
 104         printf "Defaults: %s\n", join('; ',
 105                 $data->{sprite} ? 'sprite ' . scalar @{ $data->{sprite} } : (),
 106                 defined $data->{hiname} ? 'hiscore by ' . $data->{hiname} : (),
 107         );
 108
 109         my $startnr = 0;
 110         for my $variant (qw/single peaworm multi race ctf/) {
 111                 my $count = $data->{levelcount}->{$variant};
 112                 defined $count or next;
 113                 print "\n";
 114                 printf '%s (%s)', ucfirst $variant, $count;
 115                 $count or next;
 116                 print ":";
 117                 for (0 .. $count - 1) {
 118                         my $level = $data->{levels}->[$_ + $startnr];
 119                         printf("\n- %-22s%4s:%3s+%2s%3s %3sx%-3s%s",
 120                                 $level->{id} || $level->{name} || '#'.($_+1),
 121                                 @$level{qw/size bsize growth/},
 122                                 $variant eq 'single' && "x$level->{peas}",
 123                                 @$level{qw/width height/},
 124                                 join(';', map {" $_"} grep {$_}
 125                                         @{$level->{objects}} && sprintf('%2d object%s (%s)',
 126                                                 scalar @{$level->{objects}}, @{$level->{objects}} != 1 && 's',
 127                                                 objsummary($level->{objects}),
 128                                         ),
 129                                         $level->{sprite} && @{$level->{sprite}} && sprintf('sprite %d',
 130                                                 scalar @{$level->{sprite}},
 131                                         ),
 132                                         $level->{balls} && @{$level->{balls}} && sprintf('%d bounc%s',
 133                                                 scalar @{$level->{balls}}, @{$level->{balls}} == 1 ? 'y' : 'ies',
 134                                         ),
 135                                 ),
 136                         );
 137                 }
 138                 $startnr += $count;
 139
 140                 print "\n";
 141                 printf("-- %-21s%4s: %s (%s)\n",
 142                         '(ending)',
 143                         defined $data->{finish}->{code}
 144                                 ? length $data->{finish}->{code} : '?',
 145                         defined $data->{finish}->{type}
 146                                 ? $ENDTYPE[$data->{finish}->{type}] || 'unknown' : 'code',
 147                         $data->{finish}->{message} // '?',
 148                 ) if $variant eq 'single';
 149         }
 150         print "\n";
 151 }
 152 default {
 153         require Games::Wormy::Render;
 154
 155         my @request;
 156         if ($opt{levels}) {
 157                 # find all numeric values in argument
 158                 @request = $opt{levels} =~ /(\d+)/g;
 159         }
 160         else {
 161                 # default to all singleplayer levels
 162                 @request = 0 .. $data->{levelcount}->{single} - 1;
 163         }
 164         @request or die "no levels found or specified\n";
 165
 166         my $img = Games::Wormy::Render->composite(
 167                 map { $data->{levels}->[$_] } @request
 168         ) or die "empty result for levels\n";
 169         if ($opt{format} ~~ 'pbm') {
 170                 $img = $img->to_paletted({make_colors => 'mono'});
 171                 $opt{format} = 'pnm';
 172         }
 173         $img->write(
 174                 $opt{output} ? (file => $opt{output}) : (fh => \*STDOUT),
 175                 type => $opt{format} // 'pnm',
 176         ) or die $img->errstr;
 177 }
 178 }
 179
 180 __END__
 181
 182 =head1 NAME
 183
 184 parse-wormedit - Wormy level data parser
 185
 186 =head1 SYNOPSIS
 187
 188  parse-wormedit [--format=<type>] [--levels=<number>] [--output=<file.ext>] <input.lvl>
 189
 190 =head1 DESCRIPTION
 191
 192 Reads Wormy levels (either original WormEdit source or compiled TI-86 string)
 193 from STDIN or given file, and prints parsed data to STDOUT.
 194
 195 If an I<output> file name is given, its extension determines the format,
 196 otherwise explicitly given by the I<format> option:
 197
 198 =over 6
 199
 200 =item txt
 201
 202 Plain text summary of levelpack contents.
 203
 204 =item yaml
 205
 206 All parsed data in YAML syntax.
 207
 208 =item json
 209
 210 Parsed data in JSON syntax.
 211
 212 =item pnm, png, bmp, ...
 213
 214 Image drawing of rendered levels.
 215 Unrecognised values are interpreted as file type and converted by Imager.
 216
 217 =back
 218
 219 =head1 AUTHOR
 220
 221 Mischa POSLAWSKY <wormy@shiar.org>
 222
 223 =head1 LICENSE
 224
 225 GPL version 3.
 226