package Shiar_Sheet::ImagePrep;

use 5.014;
use warnings;

our $VERSION = '1.00';

sub new {
	my ($class, $target) = @_;
	bless \$target, $class;
}

sub download {
	# copy changed remote url to local file
	my $target = shift;
	unlink $$target if -e $$target;
	my $download = shift or return 1;
	require LWP::UserAgent;
	my $ua = LWP::UserAgent->new;
	$ua->agent('/');
	my $status = $ua->mirror($download, $$target);
	$status->is_success
		or die "Download from <q>$download</q> failed: ".$status->status_line."\n";
}

sub convert {
	my ($imgpath, $thumbpath, $cmds) = @_;
	if (not -e $$imgpath) {
		return unlink $thumbpath;
	}

	my $xyres = 0 ? '600x400' : '300x200'; # cover
	my @cmds = @{ $cmds // [] };
	if (my ($cmdarg) = grep { $cmds[$_] eq '-area' } 0 .. $#cmds) {
		# replace option by permillage crop
		my @dim = map { $_ / 1000 } split /\D/, $cmds[$cmdarg + 1];
		splice @cmds, $cmdarg, 2, (
			-set => 'option:distort:viewport' => sprintf(
				'%%[fx:w*%s]x%%[fx:h*%s]+%%[fx:w*%s]+%%[fx:h*%s]',
				($dim[2] || 1) - $dim[0], # width  = x2 - x1
				($dim[3] || 1) - $dim[1], # height = y2 - y1
				@dim[0, 1]                # offset = x1,y1
			),
			-distort => SRT => 0, # noop transform to apply viewport
		);
	}
	@cmds = (
		'convert',
		$$imgpath,
		-delete => '1--1', -background => 'white',
		-gravity => defined $cmds ? 'northwest' : 'center',
		@cmds,
		-resize => "$xyres^", -extent => $xyres,
		'-strip', -quality => '60%', -interlace => 'plane',
		$thumbpath
	);

	require IPC::Run;
	my $output;
	IPC::Run::run(\@cmds, '<' => \undef, '>&' => \$output) or die [
		"Failed to convert source image.",
		"@cmds\n" .
		($output || ($? & 127 ? "signal $?" : "error code ".($? >> 8))),
	];
}

1;
