#!/usr/bin/env perl
use 5.014;
use warnings;

use Data::Dump 'pp';
use Text::CSV;

our $VERSION = '1.01';

my %BROWSERID = qw(
	IE          edge
	Edge        edge
	Firefox     firefox
	Safari      safari
	Safari-iPad ios_saf
	Safari-iPod-Touch  ios_saf
	Safari-iPhone      ios_saf
	Chrome      chrome
	Chrome-iPad chrome
	Chrome-for-iPhone  chrome
	Chromium    chrome
	Opera       opera
	Opera-Mini  op_mini
	BlackBerry  bb

	IEMobile    ie_mob
	Android     and_chr
	Chrome-for-Android and_chr
	UC-Browser  and_uc
	QQ-Browser  and_qq
	iPhone      ios_saf
	iPod-Touch  ios_saf
	Samsung-Internet   samsung
);

my %count = (
	-title  => 'StatCounter',
	-site   => 'http://gs.statcounter.com/',
);

if (@ARGV) {
	my %param = (
		bar             => 1,
		region_hidden   => 'ww', # Worldwide
		device_hidden   => 'desktop%2Bmobile%2Btablet%2Bconsole',
		'multi-device'  => 'true',
		granularity     => 'monthly',
		fromMonthYear   => $ARGV[0],
		toMonthYear     => $ARGV[1] // $ARGV[0],
		csv             => 1,
	);
	my $site = $count{-site};
	$site .= 'chart.php?'.join('&', map "$_=$param{$_}", keys %param);
	$site .= '&statType_hidden=';
	$count{-source} = $site;

	require LWP::Simple;
	{
		my $url = $site.'browser_version';
		my $download = LWP::Simple::get($url) or die "No data from $url\n";
		open my $input, '<', \$download or die $!;
		parsecsv($input);
	}
}
else {
	parsecsv(\*STDIN);
}

sub parsecsv {
	my ($input) = @_;
	my $csv = Text::CSV->new or die Text::CSV->error_diag;
	while (my $row = $csv->getline($input)) {
		my ($browser, $pct) = @$row;
		$browser and $pct or next;

		my $version = $browser =~ s/ (\d\S*)$// ? $1 : 0;
		given ($browser) {
			when ('Browser Version') {
				$pct =~ s/^Market Share (?:%|Perc\.) // or break;
				$pct =~ s/\A\((.*)\)\z/$1/;
				$count{-date} = $pct;
			}
			$browser =~ tr/ /-/;
			$browser = $_ for $BROWSERID{$browser} // ();
			$version =~ s/\.0$//;

			# desktop variant has version, mobile doesn't
			if ($version eq '0') {
				$browser = 'op_mini' if $browser eq 'opera';
				$browser = 'and_ff'  if $browser eq 'firefox';
			}

			$count{$browser}->{$version} += $pct;
		}
	}
	$csv->eof or $csv->error_diag;
}

print pp(\%count);

__END__

=head1 USAGE

cat <csv data> | F<mkusage-statcounter> > browser-usage-gs.inc.pl

F<mkusage-statcounter> <year-month>