#!/usr/bin/env perl
use 5.014;
use strict;
use warnings;

use Data::Dump 'pp';
use Font::TTF::Font;
use Getopt::Long;
use Cwd 'abs_path';

our $VERSION = '1.01';

GetOptions(\my %opt,
	'verbose|v!',
);

my ($ttfuri, $outfile) = @ARGV;
$ttfuri or do {
	warn "usage error: input font not specified\n";
	exit 64; # EX_USAGE
};
-e $ttfuri or do {
	warn "font not found: $ttfuri\n";
	exit 66; # EX_NOINPUT
};

for ($outfile || ()) {
	open my $output, '>', $_ or die "Cannot write to $outfile: $!\n";
	select $output;
}

{
	my $ttf = eval {
		if ($ttfuri =~ /\.ttc\z/) {
			require Font::TTF::Ttc;
			my $collection = Font::TTF::Ttc->open($ttfuri) or die $!;
			return $collection->{directs}->[0];  # first sub-font object
		}
		return Font::TTF::Font->open($ttfuri);
	} or do {
		warn "Cannot open font file $ttfuri: ", $@ // $!;
		exit 65; # EX_DATAERR
	};

	my ($ttfname, @ttfext) = split /\./, ($ttfuri =~ m{([^/]+)\z}ms)[0];
	my $ttfmeta = $ttf->{name}->read;
	my %meta = (
		source   => abs_path($ttfuri) =~ m{(^/usr/.+ | [^/]+) \z}msx,
		name     => $ttfmeta->find_name(4) || $ttfname,
		revision => sprintf('%g', $ttf->{head}->{fontRevision}),
		version  => $ttfmeta->find_name(5) =~ s/\Aversion //ri =~ s/\s+\z//r,
		copyright=> scalar $ttfmeta->find_name(0),
		license  => $ttfmeta->find_name(14) || undef,
		date     => (map {
			$_ && eval {
				require Time::Piece;
				Time::Piece->new($_)->datetime;
			}
		} $ttf->{head}->getdate),
	);
	$meta{abbr} = lc join '', $meta{name} =~ s/ MS$//r =~ m{
		(?!Sans) (?<! [0-9]) ([[:upper:]0-9])
	}gx;
	$meta{os} = $_ for "@ttfext[0 .. $#ttfext-1]" || (
		$meta{copyright} =~ /\bGoogle\b/ ? "Android" :
		$ttfname eq 'arialuni' ? 'win2k' :
		()
	);
	$meta{oscorp} = (
		s/^mac10/OS X 10./ ? 'Apple' :
		s/^win(.+)/'Windows '.($1 eq '2k' ? 2000 : $1)/e ? 'Microsoft' :
		m/^Android/ ? 'Google' :
		undef
	) for $meta{os} || ();

	say "# automatically generated by $0";
	say '+', pp(\%meta), ',';

	my $support = $ttf->{cmap}->find_ms->{val};
	warn scalar keys %$support, " characters read from $ttfuri\n"
		if $opt{verbose};
	say pp(sort { $a <=> $b } keys %$support);
}

__END__

=head1 NAME

mkttfinfo - Extract character coverage and metadata in TrueType font

=head1 SYNOPSIS

    mkttfinfo [-v] <font.ttf> [<output.inc.pl>]

=head1 AUTHOR

Mischa POSLAWSKY <perl@shiar.org>

=head1 LICENSE

Licensed under the GNU Affero General Public License version 3.