#!/usr/bin/env perl
use 5.014;
use warnings;

our $VERSION = '1.00';

use File::stat;
use Time::Piece;

my @pages = (
	[qw( index )],
	[qw( vi digraphs charset browser writing sc/2 termcol )],
	[qw( readline latin unicode countries emoji perl )],
	[qw( vimperator mutt nethack mplayer font )],
	[qw( apl less screen brahmi digits sc termcol/legacy )],
	[qw( chars/table/html source )],
);

my %freq = (
	(map { $_ => 'yearly' } qw[ readline nethack mplayer apl ]),
	(map { $_ => 'weekly' } qw[ browser ]),
);

my %known = map { s{/.*}{}r => 1 } map { @{$_} } @pages;
$known{$_} or warn "page $_ undeclared\n"
	for grep { !/\./ } map { s/\.plp\z//r } glob '*.plp';

say '<?xml version="1.0" encoding="UTF-8"?>';
say '<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9">';
for my $group (@pages) {
	state $prio = 1;
	for my $file (@{$group}) {
		(my $page = $file) =~ s/\Aindex\z//;
		$file =~ s{/.*}{};
		$file .= '.plp';
		print '<url>';
		print "<loc>http://sheet.shiar.nl/$page</loc>";
		printf '<changefreq>%s</changefreq>', $freq{$page} // 'monthly';
		printf '<priority>%.2f</priority>', $prio;
		printf '<lastmod>%s</lastmod>', localtime(stat($file)->mtime)->date;
		say '</url>';
	}
	$prio -= .1;
}
say '</urlset>';