#!/usr/bin/env perl
use 5.014;
use warnings;

use Data::Dump 'pp';
use JSON::PP;
use File::stat;
use Time::Piece;
use List::Util 'uniq';

our $VERSION = '1.04';

my %BROWSERJOIN = (
	edge    => 'ie',
	and_chr => 'android',
);

local $/;  # slurp
my $source = readline;

$JSON::PP::false = 0;
$JSON::PP::true  = 1;

my $data = decode_json($source);
$data->{-date} = Time::Piece->new($_)->datetime
	for delete $data->{updated} || ();

delete $data->{eras};
for (values %{ $data->{data} }) {
	delete @{$_}{qw[ usage_perc_a usage_perc_y ]};
}
for (values %{ $data->{agents} }) {
	delete $_->{usage_global};
	for (@{ $_->{version_list} }) {
		delete $_->{era};
		delete $_->{prefix} unless $_->{prefix};
	}
}

while (my ($browser, $target) = each %BROWSERJOIN) {
	my $agent1 = delete $data->{agents}->{$browser} or next;
	my $agent2 =        $data->{agents}->{$target}  or next;
	push @{ $agent2->{version_list} }, @{ $agent1->{version_list} };
	$agent2->{browser} = sprintf '%s (former %s)',
		$agent1->{browser}, $agent2->{browser};

	for (values %{ $data->{data} }) {
		my $stats = delete $_->{stats}->{$browser} or next;
		$_ = { %{$_}, %{$stats} } for $_->{stats}->{$target};
	}
}

for my $feature (values %{ $data->{data} }) {
	while (my ($attr, $row) = each %{$feature}) {
		delete $feature->{$attr} if ref $row eq '' and $row eq '';
	}
}

while (my ($agent, $row) = each %{ $data->{agents} }) {
	$row->{versions} = [ uniq map { $_->{version} } @{ $row->{version_list} } ];

	# omit identical values from subsequent versions
	for my $feature (values %{ $data->{data} }) {
		my $cmp;  # same value to be omitted
		my $verstats = $feature->{stats}->{$agent};
		for my $version (@{ $row->{versions} }) {
			defined $verstats->{$version}
				or warn "missing feature $feature->{title} for $agent $version";
			if (defined $cmp and $verstats->{$version} eq $cmp) {
				delete $verstats->{$version};
			}
			else {
				$cmp = $verstats->{$version};
			}
		}
	}
}

say "# automatically generated by $0";
print '+', pp($data);

__END__

=head1 NAME

mkcaniuse - Turn Javascript data into an equivalent Perl structure

=head1 SYNOPSIS

	tools/mkcaniuse data.json >browser-support.inc.pl