Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use strict;
   4 use warnings;
   5 no  warnings 'uninitialized';  # save some useless checks for more legible code
   6 use Carp;
   7
   8 our $VERSION = 'v2.03';
   9
  10 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  11 my @rowdesc = qw(numeric top home bottom);
  12 my %keyrows = do 'keys.inc.pl';
  13 # add first two cases of each row again with each char prepended by + (alt)
  14 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  15
  16 my %keytrans = qw(
  17         ^@ NUL ^a SOH ^b STX ^c ETX  ^d EOT ^e ENQ ^f ACK ^g BEL
  18         ^h BS  ^i tab ^j LF  ^k VT   ^l FF  ^m CR  ^n SO  ^o SI
  19         ^p DLE ^q DC1 ^r DC2 ^s DC3  ^t DC4 ^u NAK ^v SYN ^w ETB
  20         ^x CAN ^y EM  ^z SUB ^[ ESC  ^\ FS  ^] GS  ^^ RS  ^_ US
  21         ^? DEL
  22 );
  23
  24 sub new {
  25         my $class = shift;
  26         my ($self) = @_;
  27
  28         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  29         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  30         $self->{map} ||= 'qwerty';
  31
  32         $self->{sign} ||= do {
  33                 require Shiar_Sheet::KeySigns;
  34                 Shiar_Sheet::KeySigns->VERSION(1.03);
  35                 \%Shiar_Sheet::KeySigns::sign;
  36         };
  37
  38         bless $self, $class;
  39 }
  40
  41 sub map {
  42         my $self = shift;
  43         my ($mapname) = @_;
  44
  45         return $self->{map} = $mapname if defined $keyrows{$mapname};
  46         return undef;
  47 }
  48
  49 sub escapeclass {
  50         local $_ = shift;
  51         s/\^/_c/g;
  52         s/\+/_m/g;
  53         s/\[/_sbo/g;
  54         s/\]/_sbc/g;
  55         s/^$/_/;
  56         return $_;
  57 }
  58
  59 sub escapehtml {
  60         local $_ = shift;
  61         s/</&lt;/g;
  62         s/>/&gt;/g;
  63         s/  / &nbsp;/g;
  64         return $_;
  65 }
  66
  67 sub keyunalias {
  68         my $self = shift;
  69         my ($key, $ancestry) = @_;
  70
  71         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  72         my $mode = $1;
  73         my $keyinfo = $self->{def}->{$mode}->{$key};
  74
  75         return unless defined $keyinfo;
  76         return $keyinfo->[0] if ref $keyinfo;
  77         return '' if $ancestry->{$key}++;  # endless loop failsafe
  78         return $self->keyunalias($keyinfo, $ancestry);
  79 }
  80
  81 sub print_key {
  82         my $self = shift;
  83         my ($mode, $key, $flags) = @_;
  84
  85         if (not defined $flags) {
  86                 $flags = [$key eq '^0' ? 'ni' : 'no'];
  87         }
  88         elsif (not ref $flags) { # alias
  89                 my $desc = $self->{sign}->{alias};
  90                 $desc .= $flags eq "\e" ? 'esc' : $flags;
  91                 $flags = [$self->keyunalias($flags) . ' alias', $desc];
  92         }
  93         my ($flags, $desc, $mnem) = @{$flags};
  94         if (my $txt = $self->{key}->{$mode.$key}) {
  95                 ($desc, $mnem) = split /\n/, $txt;
  96         }
  97
  98 #       $key = $keytrans{$key} if defined $keytrans{$key};
  99         my $keytxt = $key eq "\e" ? 'Esc' : $self->{def}{$mode}{lead} . escapehtml($key) if $key ne '^0';
 100            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 101            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 102            $keytxt =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 103            $keytxt =~ s{\+(?=.)}{<small>+</small>};  # meta
 104         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 105            $keytxt  = "<b$keyhint>$keytxt</b>";
 106            $keytxt .= ' '.$desc if defined $desc;
 107            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 108         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 109                 ' onclick="setmode(%s)"',
 110                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 111         );
 112         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 113
 114         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 115         print "\n";
 116 }
 117
 118 sub print_rows {
 119         my $self = shift;
 120         my %moderows = (
 121                 -DEFAULT => !@_ ? '' : split(/(?:\s*([^=\s]*)=\s*)/, shift),
 122                 # plus specific mode overrides prefixed by '='
 123         );
 124         my $defrows = shift || [2, 1, 0];
 125         my @modes = sort keys %{ $self->{def} };
 126
 127         print '<table id="rows" class="keys">'."\n\n";
 128
 129         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 130                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 131
 132                 printf qq{<tbody class="row row%d">\n}, $row+1;
 133                 for my $basemode (@modes) {
 134                         my @moderows = split /\s+/,
 135                                 $row < 0 ? "0" :
 136                                 defined $moderows{$basemode} ? $moderows{$basemode} : $moderows{-DEFAULT};
 137
 138                 for my $submode (@moderows ? @moderows : '') {
 139                         my $mode = $basemode . $submode;
 140                         my @caserows = $mode =~ s/(\d+)(?:-(\d+))?$//
 141                                 ? (map {$_ - 1} split //, $row == 0 && $2 || $1)  # user override
 142                                 : @$defrows;  # default
 143                         my $modekeys = $self->{def}{$mode};
 144
 145                         for my $case (@caserows) {
 146                                 my $keycase = $keyrow->[$case] or next;
 147                                   @$keycase or next;
 148                                 my @caseclass;
 149                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 150                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 151                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 152
 153                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 154                                         ' class="%s"', join ' ', @caseclass
 155                                 );
 156                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 157                                                 $self->{mode}->{$mode} || "mode $basemode",
 158                                                 "$rowdesc[$row] row $casedesc[$case]"
 159                                 ) unless $row < 0;
 160                                 print "\n";
 161                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 162                                 print qq{\t\t</tr>\n};
 163                         } # case
 164
 165                 } # submode
 166
 167                 } # basemode
 168                 print qq{\t</tbody>\n};
 169         } # row
 170
 171         print "</table>\n";
 172 }
 173
 174 sub print_legend {
 175         my $self = shift;
 176         my ($class, $flags) = @_;
 177
 178         print qq{\t\t<dl class="legend $class">\n};
 179         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s'."\n",
 180                 $_, @{ $self->{flag}->{$_} || ["($_)", '...'] }
 181         ) for @$flags;
 182         print "\t\t</dl>";
 183 }
 184
 185 1;
 186
 187 =head1 NAME
 188
 189 Shiar_Sheet::Keyboard - Output HTML for key sheets
 190
 191 =head1 SYNOPSIS
 192
 193         our %sign = (alias => 'see: ');
 194
 195         my $keys = Shiar_Sheet::Keyboard({
 196                 def => {
 197                         'lead' => {
 198                                 'A' => 'a', # alias
 199                                 'a' => ['classes'],
 200                         },
 201                 },
 202                 key => {
 203                         'leada' => ['description', 'comments (on hover)'],
 204                 },
 205                 mode => {
 206                         'lead' => 'mode description',
 207                 },
 208         });
 209         $keys->map('dvorak') or die "Keyboard map not found";
 210
 211         $keys->print_rows;
 212
 213 =head1 DESCRIPTION
 214
 215 Used by http://sheet.shiar.nl to display keyboard sheets.
 216 Assumes specific stylesheets and javascript from this site,
 217 so probably not of much use elsewhere.
 218
 219 =head1 AUTHOR
 220
 221 Mischa POSLAWSKY <perl@shiar.nl>
 222
 223 =head1 LICENSE
 224
 225 Licensed under the GNU Affero General Public License version 3.
 226