Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6 no  warnings 'uninitialized';  # save some useless checks for more legible code
   7 use Carp;
   8
   9 our $VERSION = 'v2.05';
  10
  11 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  12 my @rowdesc = qw(numeric top home bottom);
  13 my %keyrows = do 'keys.inc.pl';
  14 # add first two cases of each row again with each char prepended by + (alt)
  15 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  16
  17 my %keytrans = qw(
  18         ^@ NUL ^a SOH ^b STX ^c ETX  ^d EOT ^e ENQ ^f ACK ^g BEL
  19         ^h BS  ^i tab ^j LF  ^k VT   ^l FF  ^m CR  ^n SO  ^o SI
  20         ^p DLE ^q DC1 ^r DC2 ^s DC3  ^t DC4 ^u NAK ^v SYN ^w ETB
  21         ^x CAN ^y EM  ^z SUB ^[ ESC  ^\ FS  ^] GS  ^^ RS  ^_ US
  22         ^? DEL
  23 );
  24
  25 sub new {
  26         my $class = shift;
  27         my ($self) = @_;
  28
  29         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  30         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  31         $self->{map} ||= 'qwerty';
  32
  33         $self->{sign} ||= do {
  34                 require Shiar_Sheet::KeySigns;
  35                 Shiar_Sheet::KeySigns->VERSION(1.04);
  36                 \%Shiar_Sheet::KeySigns::sign;
  37         };
  38
  39         bless $self, $class;
  40 }
  41
  42 sub map {
  43         my $self = shift;
  44         my ($mapname) = @_;
  45
  46         return $self->{map} = $mapname if defined $keyrows{$mapname};
  47         return undef;
  48 }
  49
  50 sub escapeclass {
  51         local $_ = shift;
  52         s/\^/_c/g;
  53         s/\+/_m/g;
  54         s/\[/_sbo/g;
  55         s/\]/_sbc/g;
  56         s/^$/_/;
  57         return $_;
  58 }
  59
  60 sub escapehtml {
  61         local $_ = shift;
  62         s/</&lt;/g;
  63         s/>/&gt;/g;
  64         s/  / &nbsp;/g;
  65         return $_;
  66 }
  67
  68 sub escapedesc {
  69         my $self = shift;
  70         local $_ = shift;
  71         s{ (< ([^>]*) >) }{ $self->{sign}->{$2} // $1 }xeg;
  72         return $_;
  73 }
  74
  75 sub keyunalias {
  76         my $self = shift;
  77         my ($key, $ancestry) = @_;
  78
  79         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  80         my $mode = $1;
  81         my $keyinfo = $self->{def}->{$mode}->{$key};
  82
  83         return unless defined $keyinfo;
  84         $keyinfo =~ s/^=// or return $keyinfo;
  85         return '' if $ancestry->{$key}++;  # endless loop failsafe
  86         return $self->keyunalias($keyinfo, $ancestry);
  87 }
  88
  89 sub print_key {
  90         my $self = shift;
  91         my ($mode, $key, $flags) = @_;
  92         my ($desc, $mnem);
  93
  94         if (not defined $flags) {
  95                 $flags = $key eq '^0' ? 'ni' : 'no';
  96         }
  97         elsif ($flags =~ s/^=//) { # alias
  98                 $desc = $self->{sign}->{alias};
  99                 $desc .= $flags eq "\e" ? 'esc' : $flags;
 100                 $flags = $self->keyunalias($flags) . ' alias';
 101         }
 102         if (my $txt = $self->{key}->{$mode.$key}) {
 103                 ($desc, $mnem) = split /\n/, $self->escapedesc($txt);
 104         }
 105
 106 #       $key = $keytrans{$key} if defined $keytrans{$key};
 107         my $keytxt = $key eq "\e" ? 'Esc' : $self->{def}{$mode}{lead} . escapehtml($key) if $key ne '^0';
 108            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 109            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 110            $keytxt =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 111            $keytxt =~ s{\+(?=.)}{<small>+</small>};  # meta
 112         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 113            $keytxt  = "<b$keyhint>$keytxt</b>";
 114            $keytxt .= ' '.$desc if defined $desc;
 115            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 116         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 117                 ' onclick="setmode(%s)"',
 118                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 119         );
 120         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 121
 122         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 123         print "\n";
 124 }
 125
 126 sub print_rows {
 127         my $self = shift;
 128         my %moderows = (
 129                 -DEFAULT => !@_ ? '' : split(/(?:\s*([^=\s]*)=\s*)/, shift),
 130                 # plus specific mode overrides prefixed by '='
 131         );
 132         my $defrows = shift || [2, 1, 0];
 133         my @modes = sort keys %{ $self->{def} };
 134
 135         print '<table id="rows" class="keys">'."\n\n";
 136
 137         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 138                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 139
 140                 printf qq{<tbody class="row row%d">\n}, $row+1;
 141                 for my $basemode (@modes) {
 142                         my @moderows = split /\s+/,
 143                                 $row < 0 ? "0" :
 144                                 defined $moderows{$basemode} ? $moderows{$basemode} : $moderows{-DEFAULT};
 145
 146                 for my $submode (@moderows ? @moderows : '') {
 147                         my $mode = $basemode . $submode;
 148                         my @caserows = $mode =~ s/(\d+)(?:-(\d+))?$//
 149                                 ? (map {$_ - 1} split //, $row == 0 && $2 || $1)  # user override
 150                                 : @$defrows;  # default
 151                         my $modekeys = $self->{def}{$mode};
 152
 153                         for my $case (@caserows) {
 154                                 my $keycase = $keyrow->[$case] or next;
 155                                   @$keycase or next;
 156                                 my @caseclass;
 157                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 158                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 159                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 160
 161                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 162                                         ' class="%s"', join ' ', @caseclass
 163                                 );
 164                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 165                                                 $self->escapedesc($self->{mode}->{$mode} || "mode $basemode"),
 166                                                 "$rowdesc[$row] row $casedesc[$case]"
 167                                 ) unless $row < 0;
 168                                 print "\n";
 169                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 170                                 print qq{\t\t</tr>\n};
 171                         } # case
 172
 173                 } # submode
 174
 175                 } # basemode
 176                 print qq{\t</tbody>\n};
 177         } # row
 178
 179         print "</table>\n";
 180 }
 181
 182 sub print_legend {
 183         my $self = shift;
 184         my ($class, $flags) = @_;
 185
 186         print qq{\t\t<dl class="legend $class">\n};
 187         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s'."\n",
 188                 $_, map { $self->escapedesc($_) } @{ $self->{flag}->{$_} || ["($_)", '...'] }
 189         ) for @$flags;
 190         print "\t\t</dl>";
 191 }
 192
 193 1;
 194
 195 =head1 NAME
 196
 197 Shiar_Sheet::Keyboard - Output HTML for key sheets
 198
 199 =head1 SYNOPSIS
 200
 201         our %sign = (alias => 'see: ');
 202
 203         my $keys = Shiar_Sheet::Keyboard({
 204                 def => {
 205                         'lead' => {
 206                                 'A' => '=a', # alias
 207                                 'a' => 'classes',
 208                         },
 209                 },
 210                 key => {
 211                         'leada' => ['description', 'comments (on hover)'],
 212                 },
 213                 mode => {
 214                         'lead' => 'mode description',
 215                 },
 216         });
 217         $keys->map('dvorak') or die "Keyboard map not found";
 218
 219         $keys->print_rows;
 220
 221 =head1 DESCRIPTION
 222
 223 Used by http://sheet.shiar.nl to display keyboard sheets.
 224 Assumes specific stylesheets and javascript from this site,
 225 so probably not of much use elsewhere.
 226
 227 =head1 AUTHOR
 228
 229 Mischa POSLAWSKY <perl@shiar.nl>
 230
 231 =head1 LICENSE
 232
 233 Licensed under the GNU Affero General Public License version 3.
 234