Shiar_Sheet/Colour.pm

   1 package Shiar_Sheet::Colour;
   2
   3 use strict;
   4 use warnings;
   5 use List::Util qw( min max );
   6
   7 our $VERSION = '1.01';
   8
   9 # ITU-R recommendation 601 luma co-efficients
  10 our $kr = .299;
  11 our $kb = .114;
  12 our $kg = 1 - $kb - $kr;
  13
  14 sub new {
  15         my $class = shift;
  16         my @rgb = @_ >= 3 ? @_ : (map {hex} $_[0] =~ /(..)/g);
  17         bless \@rgb, $class;
  18 }
  19
  20 sub newyuv {
  21         # convert from YPbPr values 0..255 (or hex string)
  22         my $class = shift;
  23         my ($y, $cb, $cr) = @_ >= 3 ? @_ : (map {hex} $_[0] =~ /(..)/g);
  24
  25         $_ -= 128 for $cb, $cr;
  26         $_ /= 255 for $y, $cb, $cr;
  27
  28         my @rgb = map { max(0, min(255, $_ * 255)) } (
  29                 $y                             + $cr,
  30                 $y - $cb * (1 - $kb) * $kb/$kg - $cr * $kr/$kg,
  31                 $y + $cb * (1 - $kb)           ,
  32         );
  33         bless \@rgb, $class;
  34 }
  35
  36 sub luminance {
  37         # perceived brightness
  38         my ($r, $g, $b) = @{ $_[0] };
  39         return $r*$kr + $g*$kg + $b*$kb;
  40 }
  41
  42 sub rgb24 {
  43         my $str = '';
  44         $str .= sprintf '%X', min($_ / 17 + .5, 15) for @{ $_[0] };
  45         return $str;
  46 }
  47
  48 sub rgb48 {
  49         my $str = '';
  50         $str .= sprintf '%02X', $_ for @{ $_[0] };
  51         return $str;
  52 }
  53
  54 1;
  55