Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6 no  warnings 'uninitialized';  # save some useless checks for more legible code
   7 use Carp;
   8
   9 our $VERSION = '2.07';
  10
  11 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  12 my @rowdesc = qw(numeric top home bottom);
  13 my %keyrows = do 'keys.inc.pl';
  14 # add first two cases of each row again with each char prepended by + (alt)
  15 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  16
  17 my %keytrans = qw(
  18         ^@ NUL ^a SOH ^b STX ^c ETX  ^d EOT ^e ENQ ^f ACK ^g BEL
  19         ^h BS  ^i tab ^j LF  ^k VT   ^l FF  ^m CR  ^n SO  ^o SI
  20         ^p DLE ^q DC1 ^r DC2 ^s DC3  ^t DC4 ^u NAK ^v SYN ^w ETB
  21         ^x CAN ^y EM  ^z SUB ^[ ESC  ^\ FS  ^] GS  ^^ RS  ^_ US
  22         ^? DEL
  23 );
  24
  25 sub new {
  26         my $class = shift;
  27         my ($self) = @_;
  28
  29         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  30         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  31         $self->{map} ||= 'qwerty';
  32
  33         $self->{sign} ||= do {
  34                 require Shiar_Sheet::KeySigns;
  35                 Shiar_Sheet::KeySigns->VERSION(1.04);
  36                 \%Shiar_Sheet::KeySigns::sign;
  37         };
  38
  39         $self->{showkeys} = $PLP::Script::showkeys;
  40         $self->{style   } = $PLP::Script::style;
  41
  42         bless $self, $class;
  43 }
  44
  45 sub map {
  46         my $self = shift;
  47         my ($mapname) = @_;
  48
  49         return $self->{map} = $mapname if defined $keyrows{$mapname};
  50         return undef;
  51 }
  52
  53 sub escapeclass {
  54         local $_ = shift;
  55         s/\^/_c/g;
  56         s/\+/_m/g;
  57         s/\[/_sbo/g;
  58         s/\]/_sbc/g;
  59         s/^$/_/;
  60         return $_;
  61 }
  62
  63 sub escapehtml {
  64         local $_ = shift;
  65         s/</&lt;/g;
  66         s/>/&gt;/g;
  67         s/  / &nbsp;/g;
  68         return $_;
  69 }
  70
  71 sub escapedesc {
  72         my $self = shift;
  73         local $_ = shift;
  74         s{ (< ([^>]*) >) }{ $self->{sign}->{$2} // $1 }xeg;
  75         return $_;
  76 }
  77
  78 sub keyunalias {
  79         my $self = shift;
  80         my ($key, $ancestry) = @_;
  81
  82         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  83         my $mode = $1;
  84         my $keyinfo = $self->{def}->{$mode}->{$key};
  85
  86         return unless defined $keyinfo;
  87         $keyinfo =~ s/^=// or return $keyinfo;
  88         return '' if $ancestry->{$key}++;  # endless loop failsafe
  89         return $self->keyunalias($keyinfo, $ancestry);
  90 }
  91
  92 sub print_letter {
  93         my $self = shift;
  94         my ($key, $mode) = @_;
  95
  96         return if $key eq '^0';
  97         return 'Esc' if $key eq "\e";
  98 #       return $keytrans{$key} if defined $keytrans{$key};
  99         my $html = $self->{def}{$mode}{lead} . escapehtml($key);
 100            $html =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 101            $html =~ s{\+(?=.)}{<small>+</small>};  # meta
 102         return $html;
 103 }
 104
 105 sub print_key {
 106         my $self = shift;
 107         my ($mode, $key, $flags) = @_;
 108         my ($desc, $mnem);
 109
 110         if (not defined $flags) {
 111                 $flags = $key eq '^0' ? 'ni' : 'no';
 112         }
 113         elsif ($flags =~ s/^=//) { # alias
 114                 $desc = $self->{sign}->{alias};
 115                 $desc .= $flags eq "\e" ? 'esc' : $flags;
 116                 $flags = $self->keyunalias($flags) . ' alias';
 117         }
 118         if (my $txt = $self->{key}->{$mode.$key}) {
 119                 ($desc, $mnem) = split /\n/, $self->escapedesc($txt);
 120         }
 121
 122         my $keytxt = $self->print_letter($key, $mode);
 123            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 124            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 125         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 126            $keytxt  = "<b$keyhint>$keytxt</b>";
 127            $keytxt .= ' '.$desc if defined $desc;
 128            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 129         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 130                 ' onclick="setmode(%s)"',
 131                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 132         );
 133         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 134
 135         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 136         print "\n";
 137 }
 138
 139 sub print_rows {
 140         my $self = shift;
 141         my ($rowsspec, $defrows) = @_;
 142         $defrows ||= [2, 1, 0];
 143         my %moderows = (
 144                 -DEFAULT => defined $rowsspec && $rowsspec ne '' &&
 145                         split(/\s* ([^=\s]*) = \s*/x, $rowsspec),
 146                 # plus specific mode overrides prefixed by '='
 147         );
 148         my @modes = sort keys %{ $self->{def} };
 149
 150         print '<table id="rows" class="keys">'."\n\n";
 151
 152         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 153                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 154
 155                 printf qq{<tbody class="row row%d">\n}, $row+1;
 156                 for my $basemode (@modes) {
 157                         my @moderows = split /\s+/,
 158                                 $row < 0 ? '1' : # top row (esc key) always unshifted
 159                                 $moderows{$basemode} // $moderows{-DEFAULT};
 160
 161                 for my $submode (@moderows ? @moderows : '') {
 162                         my $mode = $basemode . $submode;
 163                         my @caserows = $mode =~ s/(\d+)(?:-(\d+))?$//
 164                                 ? (map {$_ - 1} split //, $row == 0 && $2 || $1)  # user override
 165                                 : @$defrows;  # default
 166                         my $modekeys = $self->{def}{$mode};
 167
 168                         for my $case (@caserows) {
 169                                 my $keycase = $keyrow->[$case] or next;
 170                                   @$keycase or next;
 171                                 my @caseclass;
 172                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 173                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 174                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 175
 176                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 177                                         ' class="%s"', join ' ', @caseclass
 178                                 );
 179                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 180                                                 $self->escapedesc($self->{mode}->{$mode} || "mode $basemode"),
 181                                                 "$rowdesc[$row] row $casedesc[$case]"
 182                                 ) unless $row < 0;
 183                                 print "\n";
 184                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 185                                 print qq{\t\t</tr>\n};
 186                         } # case
 187
 188                 } # submode
 189
 190                 } # basemode
 191                 print qq{\t</tbody>\n};
 192         } # row
 193
 194         print "</table>\n";
 195 }
 196
 197 sub print_legend {
 198         my $self = shift;
 199         my ($class, $flags) = @_;
 200
 201         say qq{\t\t<dl class="legend $class">};
 202         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s'."\n",
 203                 $_, map { $self->escapedesc($_) } @{ $self->{flag}->{$_} || ["($_)", '...'] }
 204         ) for @$flags;
 205         say "\t\t</dl>";
 206 }
 207
 208 sub print_legends {
 209         my $self = shift;
 210         my ($input) = @_;
 211
 212         say "<hr/>\n";
 213         say '<div class="help">';
 214
 215         say "\t", '<div class="left">';
 216         my @groups = sort grep {/^g\d/} keys %{ $self->{flag} };
 217         $self->print_legend('legend-types', \@groups);
 218         say "\t</div>\n";
 219
 220         say "\t", '<div class="right">';
 221         my @attr = sort grep {!/^g\d/} keys %{ $self->{flag} };
 222         $self->print_legend('legend-options', \@attr);
 223         say '';
 224
 225         say "\t\t", '<ul class="legend legend-set">';
 226
 227         say "\t\t<li>keyboard <strong>map</strong> is ",
 228                 ($input->{map} ? 'set to ' : ''), "<em>$self->{map}</em>";
 229         say "\t\t<li><strong>keys</strong> are ",
 230                 "<em>", ($self->{showkeys} ? 'always shown' : 'hidden if unassigned'), "</em>",
 231                 (!defined $self->{showkeys} && ' by default');
 232         say "\t\t<li>default <strong>style</strong> is ",
 233                 (defined $input->{style} && 'set to '), "<em>$self->{style}</em>";
 234
 235         say "\t\t</ul>";
 236         say "\t</div>\n";
 237         say "</div>\n";
 238 }
 239
 240 1;
 241
 242 =head1 NAME
 243
 244 Shiar_Sheet::Keyboard - Output HTML for key sheets
 245
 246 =head1 SYNOPSIS
 247
 248         our %sign = (alias => 'see: ');
 249
 250         my $keys = Shiar_Sheet::Keyboard({
 251                 def => {
 252                         'lead' => {
 253                                 'A' => '=a', # alias
 254                                 'a' => 'classes',
 255                         },
 256                 },
 257                 key => {
 258                         'leada' => ['description', 'comments (on hover)'],
 259                 },
 260                 mode => {
 261                         'lead' => 'mode description',
 262                 },
 263         });
 264         $keys->map('dvorak') or die "Keyboard map not found";
 265
 266         $keys->print_rows;
 267
 268 =head1 DESCRIPTION
 269
 270 Used by http://sheet.shiar.nl to display keyboard sheets.
 271 Assumes specific stylesheets and javascript from this site,
 272 so probably not of much use elsewhere.
 273
 274 =head1 AUTHOR
 275
 276 Mischa POSLAWSKY <perl@shiar.nl>
 277
 278 =head1 LICENSE
 279
 280 Licensed under the GNU Affero General Public License version 3.
 281