Shiar_Sheet/Colour.pm

   1 package Shiar_Sheet::Colour;
   2
   3 use strict;
   4 use warnings;
   5 use List::Util qw( min max );
   6
   7 our $VERSION = '1.04';
   8
   9 # ITU-R recommendation 601 luma co-efficients
  10 our $kr = .299;
  11 our $kb = .114;
  12 our $kg = 1 - $kb - $kr;
  13
  14 my $PI = 2 * atan2 1, 0;
  15
  16 sub new {
  17         my $class = shift;
  18         my @rgb = @_ >= 3 ? @_ : (map {hex} $_[0] =~ /(..)/g);
  19         bless \@rgb, $class;
  20 }
  21
  22 sub newyuv {
  23         # convert from YPbPr values 0..255 (or hex string)
  24         my $class = shift;
  25         my ($y, $cb, $cr) = @_ >= 3 ? @_ : (map {hex} $_[0] =~ /(..)/g);
  26
  27         $_ -= 128 for $cb, $cr;
  28         $_ /= 255 for $y, $cb, $cr;
  29
  30         my @rgb = map { max(0, min(255, $_ * 255)) } (
  31                 $y                             + $cr,
  32                 $y - $cb * (1 - $kb) * $kb/$kg - $cr * $kr/$kg,
  33                 $y + $cb * (1 - $kb)           ,
  34         );
  35         bless \@rgb, $class;
  36 }
  37
  38 sub luminance {
  39         # perceived brightness
  40         my ($r, $g, $b) = @{ $_[0] };
  41         return $r*$kr + $g*$kg + $b*$kb;
  42 }
  43
  44 sub hue {
  45         # colour shift (red = 0 .. 1)
  46         my ($r, $g, $b) = @{ $_[0] };
  47         my $hue = atan2 sqrt(3) * ($g - $b), $r*2 - $g - $b;
  48         $hue /= $PI * 2;  # -.5 .. .5
  49         $hue++ if $hue < 0;  # fp $hue %= 1
  50         return $hue;
  51 }
  52
  53 sub hsv {
  54         my ($rgb) = @_;
  55         my $v = max(@{$rgb});
  56         return $rgb->hue, abs(min(@{$rgb}) - $v), $v;
  57 }
  58
  59 sub rgb24 {
  60         my $str = '';
  61         $str .= sprintf '%X', min($_ / 17 + .5, 15) for @{ $_[0] };
  62         return $str;
  63 }
  64
  65 sub rgb48 {
  66         my $str = '';
  67         $str .= sprintf '%02X', $_ for @{ $_[0] };
  68         return $str;
  69 }
  70
  71 1;
  72