tools/mkcharinfo

   1 #!/usr/bin/env perl
   2 use 5.010;
   3 use strict;
   4 use warnings;
   5 use utf8;
   6 no if $] >= 5.018, warnings => 'experimental::smartmatch';
   7
   8 use open OUT => ':utf8', ':std';
   9 use Data::Dump 'pp';
  10
  11 our $VERSION = '1.00';
  12
  13 my %info = (
  14         # prepare presentational string for some control(lish) entries
  15         "\xAD"     => {string => '-'},
  16         "\x{200E}" => {string => '→'},
  17         "\x{200F}" => {string => '←'},
  18         "\x{200B}" => {string => '␣'},
  19         "\x{200C}" => {string => '|'}, # ISO-9995-7-081 lookalike (alt: ∣ ⊺ ⟙)
  20         "\x{200D}" => {string => '⁀'}, # join (alt: ∤ |ͯ ⨝)
  21 );
  22 $info{chr $_} //= {} for 32 .. 126;
  23
  24 eval {
  25         my $tables = do 'unicode-table.inc.pl' or die $@ || $!;
  26         for (values %$tables) {
  27                 for (values %$_) {
  28                         for (@$_) {
  29                                 length $_ == 1 or next;  # ignore meta values
  30                                 s/\\//;  # unescape
  31                                 $info{$_} //= {};
  32                         }
  33                 }
  34         }
  35         1;
  36 } or warn "Failed reading unicode tables: $@";
  37
  38 eval {
  39         require HTML::Entities;
  40         our %char2entity;
  41         HTML::Entities->import('%char2entity');
  42         while (my ($char, $entity) = each %char2entity) {
  43                 $entity =~ /[a-zA-Z]/ or next;  # only actual aliases
  44                 $info{$char}->{html} = substr($entity, 1, -1);
  45         }
  46         1;
  47 } or warn "Failed importing html entities: $@";
  48
  49 my %diinc = (
  50         'data/digraphs-rfc.inc.pl' => 'u-di',
  51         'data/digraphs-shiar.inc.pl' => 'u-prop Xz',
  52 );
  53 for (keys %diinc) {
  54         -e $_ or next;
  55         my $di = do $_ or die "Error reading digraphs file $_: ", $@ || $!;
  56         while (my ($mnem, $cp) = each %$di) {
  57                 length $mnem == 2 or next;  # limit to digraphs
  58                 my $class = $diinc{$_};
  59                 $info{chr $cp}->{di} //= $mnem;
  60                 $info{chr $cp}->{class}->{$class}++;
  61         }
  62 }
  63
  64 eval {
  65         # read introducing unicode versions for known characters
  66         my $agemap = do 'unicode-age.inc.pl' or die $@ || $!;
  67         for my $chr (keys %info) {
  68                 my $version = $agemap->{ord $chr} or next;
  69                 $info{$chr}->{class}->{'u-v'.$version}++
  70         }
  71         1;
  72 } or warn "Failed including unicode version data $@";
  73
  74 for my $chr (keys %info) {
  75         my $cp = ord $chr;
  76         # attempt to get unicode character information
  77         my $info = eval {
  78                 require Unicode::UCD;
  79                 Unicode::UCD::charinfo($cp)
  80                         || { block => '?', category => 'Xn', name => '', script => '' }
  81         } or next;
  82
  83         $info->{$_} = $info{$chr}->{$_} for keys %{ $info{$chr} };
  84
  85         # categorise by unicode types and writing script
  86         $info->{class}->{$_}++ for $info->{category};
  87         $info->{class}->{$_}++ for $info->{script} || ();
  88
  89         # add custom categories for certain blocks
  90         $info->{class}->{Xa}++ if $info->{block} eq 'Basic Latin';
  91         $info->{class}->{Xl}++ if $info->{block} eq 'Latin-1 Supplement';
  92
  93         {
  94                 if ($info->{string}) {
  95                         # keep predefined presentational string
  96                 }
  97                 elsif ($info->{combining}) {
  98                         # overlay combining accents
  99                         $info->{string} = chr(9676) . $chr;
 100                 }
 101                 elsif (($cp & ~0b1001_1111) == 0 or $cp == 127) {
 102                         # control characters (first 32 chars from 0 and 128)
 103                         # rename to something more descriptive
 104                         $info->{name} = $info->{unicode10}
 105                                 ? '<'.$info->{unicode10}.'>'  # the old name was much more useful
 106                                 : sprintf('<control U+%04X>', $cp);  # at least identify by value
 107                         # show descriptive symbols instead of control chars themselves
 108                         $info->{string} = $cp < 32   ? chr($cp + 0x2400) :
 109                                           $cp == 127 ? chr(0x2421) :
 110                                                        chr(0xFFFD);
 111                 }
 112         }
 113
 114         $info{$chr} = $info;
 115 }
 116
 117 # output perl code of hash
 118 say "# automatically generated by $0";
 119 say 'use utf8;';
 120 say '+{';
 121 for my $cp (sort keys %info) {
 122         $info{$cp}->{classstr} = join(' ', sort keys %{ $info{$cp}->{class} });
 123         # convert info hashes into arrays of strings to output in display order
 124         my $row = [ map { $info{$cp}->{$_} } qw/classstr name di html string/ ];
 125         # strip off trailing missing values (especially string may be unknown)
 126         defined $row->[-1] ? last : pop @$row for 1 .. @$row;
 127         # final line (assume safe within single quotes)
 128         say sprintf '"\x{%X}" => [%s],',
 129                 ord $cp, join(',', map { escapeq($_) } @$row);
 130 }
 131 say '}';
 132
 133 sub escapeq {
 134         local $_ = shift;
 135         return 'undef' if not defined;
 136         s/(['\\])/\\$1/g;
 137         return "'$_'";
 138 }
 139
 140 __END__
 141
 142 =head1 NAME
 143
 144 mkcharinfo - Gather Unicode character details in Perl array
 145
 146 =head1 SYNOPSIS
 147
 148     mkcharinfo > unicode-char.inc.pl
 149
 150 Test by printing the description of U+0041 (latin A):
 151
 152     perl -e'$u = do "unicode-char.inc.pl"; print $u->{A}->[1]'
 153
 154 =head1 AUTHOR
 155
 156 Mischa POSLAWSKY <perl@shiar.org>
 157
 158 =head1 LICENSE
 159
 160 Licensed under the GNU Affero General Public License version 3.
 161