browser.plp

   1 <(common.inc.plp)><:
   2 use List::Util qw(sum max first);
   3 no if $] >= 5.018, warnings => 'experimental::smartmatch';
   4
   5 Html({
   6         title => 'browser compatibility cheat sheet',
   7         version => '1.4',
   8         description => [
   9                 "Compatibility table of new web features (HTML5, CSS3, SVG, Javascript)",
  10                 "comparing support and usage share for all popular browser versions.",
  11         ],
  12         keywords => [qw'
  13                 web browser support compatibility usage matrix available feature
  14                 html html5 css css3 svg javascript js dom mobile
  15                 ie internet explorer firefox chrome safari webkit opera
  16         '],
  17         stylesheet => [qw'circus dark mono red light'],
  18         data => ['data/browser/support.inc.pl'],
  19 });
  20
  21 say "<h1>Browser compatibility</h1>\n";
  22
  23 my $caniuse = do 'data/browser/support.inc.pl' or die $@ || $!;
  24 $_->{verrelease} = {
  25         # mark last three (future) versions as unreleased, ensure current isn't
  26         map {
  27                 $_->[-1] => 0, $_->[-2] => 0, $_->[-3] => 0,
  28                 $_->[-4] => undef,
  29         } $_->{versions}
  30 } for values %{ $caniuse->{agents} };
  31
  32 my %CSTATS = (
  33         'n'   => 'l1',
  34         'n d' => 'l2',
  35         'n x d' => 'l2 ex',
  36         'p d' => 'l2',
  37         'a d' => 'l2',
  38         'y'   => 'l5',
  39         'y x' => 'l5 ex',
  40         'a'   => 'l3',
  41         'a x' => 'l3 ex',
  42         'p j' => 'l2',
  43         'j'   => 'l2',
  44         'p'   => 'l2',
  45         'p p' => 'l2',
  46         'u'   => 'l0',
  47 );
  48 my %DSTATS = (
  49         u => 'unknown',
  50         n => 'unsupported',
  51         p => 'plugin required',
  52         j => 'javascript required',
  53         a => 'partial',
  54         y => 'supported',
  55         d => 'disabled by default',
  56         x => sub {
  57                 join(' ',
  58                         'requires prefix',
  59                         map {"-$_-"}
  60                         ($caniuse->{agents}->{$_[0]}->{prefix_exceptions} // {})->{$_[1]}
  61                         // $caniuse->{agents}->{$_[0]}->{prefix} // (),
  62                 );
  63         },
  64 );
  65 my %PSTATS = (  # score percentage
  66         y => 1,  'y x' => .9,
  67         a => .5, 'a x' => .5, 'a d' => .1,
  68         j => .2, 'p j' => .2, 'n d' => .2, 'n x d' => .2,
  69         p => .2, 'p p' => .2, 'p d' => .1,
  70         n => 0,   u => 0,
  71 );
  72 my %CSTATUS = (
  73         unoff => 'l1', # unofficial
  74         wd    => 'l2', # draft
  75         cr    => 'l3', # candidate
  76         pr    => 'l3', # proposed
  77         rec   => 'l5', # recommendation
  78         ls    => 'l4', # whatwg
  79         ietf  => 'l0', # standard
  80         other => 'l0', # non-w3
  81 );
  82 my %versions;
  83 while (my ($browser, $row) = each %{ $caniuse->{agents} }) {
  84         $versions{$browser} = [
  85                 sort { paddedver($a) cmp paddedver($b) } grep { defined }
  86                 @{ $row->{versions} }
  87         ];
  88 }
  89
  90 print <<'';
  91 <p id="intro">Alternate rendition of Fyrd's <a href="http://caniuse.com/">when can I use...</a> page
  92
  93 my ($canihas, $usage);
  94 my $minusage = $get{threshold} // 1;
  95 given ($get{usage} // 'wm') {
  96         when (!$_) {
  97                 # none
  98         }
  99         when (!m{ \A [a-z]\w+ (?:/\d[\d-]*\d)? \z }x) {
 100                 Alert([
 101                         'Invalid browser usage data request',
 102                         'Identifier must be alphanumeric name or <q>0</q>.',
 103                 ]);
 104         }
 105         $canihas = do "data/browser/usage-$_.inc.pl" or do {
 106                 Alert('Browser usage data not found', $@ || $!);
 107                 break;
 108         };
 109         $usage = $_;
 110         my $ref = $canihas->{-title} || 'unknown';
 111         $ref = showlink($ref, $_)
 112                 for $canihas->{-site} || $canihas->{-source} || ();
 113         $ref .= " $_" for $canihas->{-date} || ();
 114         print "\nwith $ref browser usage statistics";
 115 }
 116
 117 my @browsers;
 118 if ($usage) { # first() does not work inside given >:(
 119         # adapt version usage to actual support data
 120         my %engineuse;  # prefix => usage sum
 121         for my $browser (keys %versions) {
 122                 my $row = $canihas->{$browser} // {};
 123                 my $verlist = $versions{$browser} or next;
 124                 if ($minusage and sum(values %$row) < $minusage) {
 125                         delete $versions{$browser};
 126                         next;
 127                 }
 128                 my %supported = map { $_ => 1 } @$verlist;
 129
 130                 # cascade unknown versions
 131                 $row->{$_} //= undef for @$verlist;  # ensure stable keys during iteration
 132                 while (my ($version, $usage) = each %$row) {
 133                         next if defined $supported{$version};
 134                         my $next = first { paddedver($_) ge paddedver($version) } @$verlist
 135                                 or warn("No fallback found for $browser v$version; $usage% ignored"), next;
 136                         $row->{$next} += $usage;
 137                         $row->{$version} = 0;  # balance browser total
 138                 }
 139
 140                 # build row list for each version
 141                 if ($minusage) {
 142                         my @vershown;  # $verlist replacement
 143                         my ($rowusage, @verrow) = (0);  # replacement row tracking
 144                         for (@$verlist) {
 145                                 push @verrow, $_;  # queue each version
 146                                 if (($rowusage += $row->{$_}) >= $minusage) {
 147                                         push @vershown, [@verrow];   # add row
 148                                         ($rowusage, @verrow) = (0);  # reset row tracking
 149                                 }
 150                         }
 151                         push @vershown, \@verrow if @verrow;  # always add latest
 152                         @$verlist = @vershown;
 153                 }
 154                 else {
 155                         @$verlist = map { [$_] } @$verlist;
 156                 }
 157
 158                 # reusable aggregates (grouped by prefix (engine) and browser)
 159                 $engineuse{ $caniuse->{agents}->{$browser}->{prefix} } +=
 160                 $row->{-total} = sum(values %$row);
 161         }
 162
 163         # order browser columns by usage grouped by engine
 164         @browsers = sort {
 165                 $engineuse{ $caniuse->{agents}->{$b}->{prefix} } <=>
 166                 $engineuse{ $caniuse->{agents}->{$a}->{prefix} }
 167                         ||
 168                 $canihas->{$b}->{-total} <=> $canihas->{$a}->{-total}
 169         } keys %versions;
 170 }
 171 else {
 172         # order browser columns by name grouped by engine
 173         @{$_} = map { [$_] } @{$_} for values %versions;
 174         @browsers = sort {
 175                 $caniuse->{agents}->{$b}->{prefix} cmp
 176                 $caniuse->{agents}->{$a}->{prefix}
 177                         ||
 178                 $a cmp $b
 179         } keys %versions;
 180 }
 181 :>.
 182 </p>
 183
 184 <:
 185 $canihas ||= {
 186         map {
 187                 $_ => +{
 188                         map {
 189                                 my $zero = $#$_ - 2;  # baseline index
 190                                 ($_->[$zero - 2] =>  .5), # past
 191                                 ($_->[$zero - 1] => 10 ), # previous
 192                                 ($_->[$zero + 2] =>  0 ), # future
 193                                 ($_->[$zero + 1] =>  .5), # next
 194                                 ($_->[$zero    ] => 30 ), # current
 195                         } $caniuse->{agents}->{$_}->{versions}
 196                 }
 197         } @browsers
 198 }; # fallback hash based on release semantics
 199 my $usagemax = (max(map { ref $_ eq 'HASH' && sum(values %$_) } values %$canihas) // 1) / 100;
 200
 201 my $usagepct = 1;  # score multiplier for 0..100 result
 202 # normalise usage percentage to only include shown browsers
 203 $usagepct = 100.01 / featurescore({  # yes for every possible version
 204         map { $_ => { map {$_ => 'y'} map { @{$_} } @{$versions{$_}} } } keys %versions
 205 });
 206
 207 print '<table class="mapped">';
 208 print '<col span="3">';  # should match first thead row
 209 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
 210 say '</colgroup><col>';
 211
 212 my $header = join('',
 213         '<tr>',
 214         '<th colspan="3" rowspan="2">feature',
 215         (map {
 216                 my $name = $caniuse->{agents}->{$_}->{browser};
 217                 sprintf('<th colspan="%d" class="%s" title="%s">%s',
 218                         scalar @{ $versions{$_} },
 219                         join(' ', map {"b-a-$_"} grep {$_}
 220                                 $_, @{ $caniuse->{agents}->{$_} }{'prefix', 'type'},
 221                         ),
 222                         join(' ',
 223                                 sprintf('%.1f%%', $canihas->{$_}->{-total} * $usagepct),
 224                                 $name,
 225                         ),
 226                         do {
 227                                 length $name <= (3 * @{ $versions{$_} }) ? $name
 228                                         : $caniuse->{agents}->{$_}->{abbr};
 229                         },
 230                 )
 231         } @browsers),
 232         '<th rowspan="2">%',
 233 );
 234 print '<thead>', $header;
 235 # preceding row without any colspan to work around gecko bug
 236 print "\n<tr>";
 237 for my $browser (@browsers) {
 238         for (@{ $versions{$browser} }) {
 239                 my $lastver = $_->[-1];
 240                 my $release = $caniuse->{agents}->{$browser}->{verrelease}->{$lastver};
 241                 my $future = defined $release;
 242                 printf('<td title="%s"%s>%s',
 243                         join(' ',
 244                                 sprintf('%.1f%%', sum(@{ $canihas->{$browser} }{@$_}) * $usagepct),
 245                                 $future ? 'development' : (),
 246                                 'version ' . join(', ', @{$_}),
 247                         ),
 248                         $future && ' class="ex"',
 249                         showversions($lastver),
 250                 );
 251         }
 252 }
 253 say '</thead>';
 254 say '<tfoot>', $header;
 255 {
 256         # prefix indicates browser family; count adjacent families
 257         my (@families, %familycount);
 258         for my $browser (@browsers) {
 259                 my $family = $caniuse->{agents}->{$browser}->{prefix};
 260                 push @families, $family unless $familycount{$family};
 261                 $familycount{$family} += @{ $versions{$browser} };
 262         }
 263
 264         print "\n", '<tr class="cat">';
 265         printf '<th colspan="%d">%s', $familycount{$_}, $_ for @families;
 266 }
 267 say '</tfoot>';
 268
 269 sub featurescore {
 270         # relative amount of support for given feature
 271         my $rank = 0;
 272         if (my $row = shift) {
 273                 if ($canihas) {
 274                         while (my ($browser, $versions) = each %$row) {
 275                                 ref $versions eq 'HASH' or next;
 276                                 while (my ($version, $status) = each %$versions) {
 277                                         $status =~ s/\h\#\d+//g;
 278                                         $rank += ($canihas->{$browser}->{$version} || .001) * $PSTATS{$status};
 279                                 }
 280                         }
 281                         return $rank;
 282                 }
 283
 284                 while (my ($browser, $vercols) = each %versions) {
 285                         my $div = 0;  # multiplier exponent (decreased to lower value)
 286                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 287                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 288                                 my @future;  # find upcoming releases (after current)
 289                                 for (reverse @$vercols) {
 290                                         last if $_ eq $current;
 291                                         push @future, pop @vers;
 292                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 293                                 }
 294                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 295                         }
 296                         $rank += $PSTATS{$_} * 2**($div--) for reverse @vers;
 297                 }
 298         }
 299         return $rank;
 300 }
 301
 302 sub formatnotes {
 303         my @html = @_;
 304         for (@html) {
 305                 s/\r\n?/\n/g;  # windows returns
 306                 s/\h* $//gmx;  # trailing whitespace
 307                 s/(?<= [^.\n]) $/./gmx;  # consistently end each line by a period
 308                 Entity($_);
 309                 s{  ` ([^`]*)  ` }{<code>$1</code>}gx;
 310                 s{ \[ ([^]]*) \] \( ([^)]*) \) }{<a href="$2">$1</a>}gx;
 311         }
 312         return @html;
 313 }
 314
 315 sub notestotitle {
 316         my @notes = @_;
 317         for (@notes) {
 318                 EscapeHTML($_);
 319                 s{ \[ ([^]]*) \] \( [^)]* \) }{$1}gx;  # strip link urls
 320         }
 321         return @notes;
 322 }
 323
 324 sub saytitlecol {
 325         my ($id) = @_;
 326         my $row = $caniuse->{data}->{$id};
 327
 328         for ($row->{categories}) {
 329                 my $cell = $_ ? lc $_->[0] : '-';
 330                 $cell =~ s/ api$//;  # trim unessential fluff in 'js api'
 331                 printf '<th title="%s">%s', join(' + ', @$_), $cell;
 332         }
 333
 334         print '<td>', map {
 335                 sprintf('<a href="%s" onclick="%s">%s</a>',
 336                         "#$id",
 337                         sprintf("try { %s; return false } catch(err) { return true }",
 338                                 "document.getElementById('$id').classList.toggle('target')",
 339                         ),
 340                         Entity($_),
 341                 );
 342         } $row->{title};
 343         print '<div class=aside>';
 344         print "<p>$_</p>"
 345                 for formatnotes($row->{description}, $row->{notes} || ());
 346         if (my %notes = %{ $row->{notes_by_num} }) {
 347                 say '<p>Browser-specific notes:';
 348                 say "<br>#$_: ", formatnotes($notes{$_}) for sort keys %notes;
 349                 say '</p>';
 350         }
 351         printf 'Resources: %s.', join(', ', map {
 352                 showlink($_->{title}, $_->{url})
 353         } @$_) for grep { @$_ } $row->{links} // ();
 354         printf '<br>Parent feature: %s.', join(', ', map {
 355                 showlink($caniuse->{data}->{$_}->{title}, "#$_")
 356         } $_) for $row->{parent} || ();
 357         print '</div>';
 358 }
 359
 360 sub saystatuscol {
 361         my ($id) = @_;
 362         my $row = $caniuse->{data}->{$id};
 363
 364         for ($row->{status}) {
 365                 my $cell = $_ // '-';
 366                 $cell = showlink($cell, $_) for $row->{spec} // ();
 367                 printf '<td title="%s" class="l %s">%s',
 368                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 369         }
 370 }
 371
 372 sub saybrowsercols {
 373         my ($id, $browser) = @_;
 374         my $feature = $caniuse->{data}->{$id};
 375         my $data = $feature->{stats}->{$browser};
 376         if (ref $data eq 'ARRAY') {
 377                 # special case for unsupported
 378                 my $release = $caniuse->{agents}->{$browser}->{verrelease};
 379                 $data = {
 380                         map { $_ => defined $release->{$_} ? 'u' : 'n' } keys %$release
 381                 };
 382         }
 383
 384         my ($prev, @span);
 385         for my $ver (@{ $versions{$browser} }, undef) {
 386                 my $compare = (
 387                         !defined $ver ? undef :      # last column if nameless
 388                         ref $data ne 'HASH' ? '' :   # unclassified if no support hash
 389                         $data->{ $ver->[-1] } // $prev  # known or inherit from predecessor
 390                         // (grep { defined } @{$data}{ map { $_->[0] } @{ $versions{$browser} } })[0]
 391                            ~~ 'n' && 'n'             # first known version is unsupported
 392                         || 'u'                       # unsure
 393                 );
 394                 unless (!defined $prev or $prev ~~ $compare) {
 395                         my $usage = sum(@{ $canihas->{$browser} }{ map { @{$_} } @span });
 396
 397                         # strip #\d note references from support class
 398                         my @notes;
 399                         push @notes, $feature->{notes_by_num}->{$1}
 400                                 while $prev =~ s/\h \# (\d+) \b//x;
 401
 402                         # prepare version hover details
 403                         my $title = sprintf('%.1f%% %s', $usage * $usagepct, join(', ',
 404                                 map { ref $_ eq 'CODE' ? $_->($browser, $span[0]->[0]) : $_ }
 405                                 map { $DSTATS{$_} // () }
 406                                 map { split / /, $_ }
 407                                 $prev
 408                         ));
 409                         $title .= "\n$_" for notestotitle(@notes);
 410
 411                         printf('<td class="%s" colspan="%d" title="%s">%s',
 412                                 join(' ',
 413                                         X => $CSTATS{$prev},
 414                                         !$usage ? ('p0') : ('p',
 415                                                 sprintf('p%01d', $usage * ($usagepct - .0001) / 10),
 416                                                 sprintf('p%02d', $usage * ($usagepct - .0001)),
 417                                         ),
 418                                         sprintf('pp%02d', $usage / $usagemax),
 419                                 ),
 420                                 scalar @span,
 421                                 $title,
 422                                 showversions($span[0]->[0], @span > 1 ? ($span[-1]->[-1]) : ()),
 423                         );
 424                         undef $prev;
 425                         @span = ();
 426                 }
 427                 push @span, $ver && [ grep { $data->{ $_ } eq $data->{ $ver->[-1] } } @{$ver} ];
 428                 $prev = $compare;
 429         }
 430 }
 431
 432 sub sayusagecol {
 433         my ($id) = @_;
 434         print '<td>', int featurescore($caniuse->{data}->{$id}->{stats}) * $usagepct;
 435 }
 436
 437 say '<tbody>';
 438 for my $id (sort {
 439             featurescore($caniuse->{data}->{$b}->{stats})
 440         <=> featurescore($caniuse->{data}->{$a}->{stats})
 441 } keys %{ $caniuse->{data} }) {
 442         $caniuse->{data}->{$id}->{stats} or next;  # skip metadata [summary]
 443         printf '<tr id="%s">', $id;
 444         saytitlecol($id);
 445         saystatuscol($id);
 446         saybrowsercols($id, $_) for @browsers;
 447         sayusagecol($id);
 448         say '</tr>';
 449 }
 450 say '</tbody>';
 451 say '</table>';
 452
 453 sub paddedver {
 454         # normalised version number comparable as string (cmp)
 455         shift =~ /(?:.*-|^)(\d*)(.*)/;
 456         # matched (major)(.minor) of last value in range (a-B)
 457         return sprintf('%02d', $1 || 99) . $2;
 458 }
 459
 460 sub showversions {
 461         my @span = ($_[0], @_>1 ? $_[-1] : ());
 462         s/-.*// for $span[0];
 463         for (@span) {
 464                 s/^\./0./;
 465                 s/x$/.*/;
 466                 s/.*-//;
 467         }
 468         return join('‒', @span);
 469 }
 470
 471 :>
 472 <hr>
 473
 474 <div class="legend">
 475         <table class="glyphs"><tr>
 476         <td class="X l5">supported
 477         <td class="X l3">partial
 478         <td class="X l2">optional
 479         <td class="X l1">missing
 480         <td class="X l0">unknown
 481         <td class="X ex">prefixed
 482         </table>
 483
 484         <p><: if ($usage) { :>
 485                 Usage percentage:
 486                 <span class="  p0">0</span> -
 487                 <span class="p p0 p00">.01</span> -
 488                 <span class="p p0 p05">1-9</span> -
 489                 <span class="p p1">10</span> -
 490                 <span class="p p2">20</span> -
 491                 <span class="p p5">majority</span>
 492 <: } else { :>
 493                 <table class="glyphs"><tr>
 494                         <td class="p p1">previous version</td>
 495                         <td class="p p3">current</td>
 496                         <td class="p p0 p00">upcoming (within months)</td>
 497                         <td class="  p0">future (within a year)</td>
 498                 </table>
 499 <: } :> </p>
 500
 501         <div class="right">
 502                 <ul class="legend legend-set">
 503                 <li>default <strong>style</strong> is
 504                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 505                 <li><strong>usage</strong> source is
 506                         <:= !defined $get{usage} && 'default ' :><:= defined $usage ? "<em>$usage</em>" : 'not included (<em>0</em>)' :>
 507                 <li>usage <strong>threshold</strong> is
 508                         <:= defined $get{threshold} && 'changed to ' :><em><:= $minusage :>%</em>
 509                 </ul>
 510         </div>
 511 </div>
 512
 513 <script type="text/javascript" src="/searchlocal.js"></script>
 514 <script type="text/javascript"> prependsearch(document.getElementById('intro')) </script>
 515