Shiar_Sheet/Colour.pm

   1 package Shiar_Sheet::Colour;
   2
   3 use strict;
   4 use warnings;
   5 use List::Util qw( min max );
   6
   7 our $VERSION = '1.05';
   8
   9 # ITU-R recommendation 601 luma co-efficients
  10 our $kr = .299;
  11 our $kb = .114;
  12 our $kg = 1 - $kb - $kr;
  13
  14 my $PI = 2 * atan2 1, 0;
  15
  16 sub new {
  17         my $class = shift;
  18         my @rgb = @_ >= 3 ? @_ : (map {hex} $_[0] =~ /(..)/g);
  19         bless \@rgb, $class;
  20 }
  21
  22 sub newyuv {
  23         # convert from YPbPr values -1..1
  24         my $class = shift;
  25         my ($y, $cb, $cr) = @_;
  26
  27         my @rgb = map { max(0, min(255, $_ * 255)) } (
  28                 $y                             + $cr,
  29                 $y - $cb * (1 - $kb) * $kb/$kg - $cr * $kr/$kg,
  30                 $y + $cb * (1 - $kb)           ,
  31         );
  32         bless \@rgb, $class;
  33 }
  34
  35 sub newyuv8 {
  36         # convert from YPbPr values 0..255 (or hex string)
  37         my $class = shift;
  38         my ($y, $cb, $cr) = @_ >= 3 ? @_ : (map {hex} $_[0] =~ /(..)/g);
  39
  40         $_ -= 128 for $cb, $cr;
  41         $_ /= 255 for $y, $cb, $cr;
  42
  43         $class->newyuv($y, $cb, $cr);
  44 }
  45
  46 sub luminance {
  47         # perceived brightness
  48         my ($r, $g, $b) = @{ $_[0] };
  49         return $r*$kr + $g*$kg + $b*$kb;
  50 }
  51
  52 sub hue {
  53         # colour shift (red = 0 .. 1)
  54         my ($r, $g, $b) = @{ $_[0] };
  55         my $hue = atan2 sqrt(3) * ($g - $b), $r*2 - $g - $b;
  56         $hue /= $PI * 2;  # -.5 .. .5
  57         $hue++ if $hue < 0;  # fp $hue %= 1
  58         return $hue;
  59 }
  60
  61 sub hsv {
  62         my ($rgb) = @_;
  63         my $v = max(@{$rgb});
  64         return $rgb->hue, abs(min(@{$rgb}) - $v), $v;
  65 }
  66
  67 sub rgb24 {
  68         my $str = '';
  69         $str .= sprintf '%X', min($_ / 17 + .5, 15) for @{ $_[0] };
  70         return $str;
  71 }
  72
  73 sub rgb48 {
  74         my $str = '';
  75         $str .= sprintf '%02X', $_ for @{ $_[0] };
  76         return $str;
  77 }
  78
  79 1;
  80