charset: update bmp allocation to unicode v9.0 roadmap
[sheet.git] / browser.plp
1 <(common.inc.plp)><:
2 use 5.010;
3 use utf8;
4 use List::Util qw(sum max first);
5 no if $] >= 5.018, warnings => 'experimental::smartmatch';
6
7 Html({
8         title => 'browser compatibility cheat sheet',
9         version => '1.4',
10         description => [
11                 "Compatibility table of new web features (HTML5, CSS3, SVG, Javascript)",
12                 "comparing support and usage share for all popular browser versions.",
13         ],
14         keywords => [qw'
15                 web browser support compatibility usage matrix available feature
16                 html html5 css css3 svg javascript js dom mobile
17                 ie internet explorer firefox chrome safari webkit opera
18         '],
19         stylesheet => [qw'circus dark mono red light'],
20         data => ['data/browser/support.inc.pl'],
21 });
22
23 say "<h1>Browser compatibility</h1>\n";
24
25 my $caniuse = do 'data/browser/support.inc.pl' or die $@ || $!;
26 $_->{verrelease} = {
27         # mark last three (future) versions as unreleased, ensure current isn't
28         map {
29                 $_->[-1] => 0, $_->[-2] => 0, $_->[-3] => 0,
30                 $_->[-4] => undef,
31         } $_->{versions}
32 } for values %{ $caniuse->{agents} };
33
34 my %CSTATS = (
35         'n'   => 'l1',
36         'n d' => 'l2',
37         'n x d' => 'l2 ex',
38         'p d' => 'l2',
39         'a d' => 'l2',
40         'y'   => 'l5',
41         'y x' => 'l5 ex',
42         'a'   => 'l3',
43         'a x' => 'l3 ex',
44         'p j' => 'l2',
45         'j'   => 'l2',
46         'p'   => 'l2',
47         'p p' => 'l2',
48         'u'   => 'l0',
49 );
50 my %DSTATS = (
51         u => 'unknown',
52         n => 'unsupported',
53         p => 'plugin required',
54         j => 'javascript required',
55         a => 'partial',
56         y => 'supported',
57         d => 'disabled by default',
58         x => sub {
59                 join(' ',
60                         'requires prefix',
61                         map {"-$_-"}
62                         ($caniuse->{agents}->{$_[0]}->{prefix_exceptions} // {})->{$_[1]}
63                         // $caniuse->{agents}->{$_[0]}->{prefix} // (),
64                 );
65         },
66 );
67 my %PSTATS = (  # score percentage
68         y => 1,  'y x' => .9,
69         a => .5, 'a x' => .5, 'a d' => .1,
70         j => .2, 'p j' => .2, 'n d' => .2, 'n x d' => .2,
71         p => .2, 'p p' => .2, 'p d' => .1,
72         n => 0,   u => 0,
73 );
74 my %CSTATUS = (
75         unoff => 'l1', # unofficial
76         wd    => 'l2', # draft
77         cr    => 'l3', # candidate
78         pr    => 'l3', # proposed
79         rec   => 'l5', # recommendation
80         ls    => 'l4', # whatwg
81         ietf  => 'l0', # standard
82         other => 'l0', # non-w3
83 );
84 my %versions;
85 if (my ($somerow) = values %{ $caniuse->{data} }) {
86         while (my ($browser, $row) = each %{ $somerow->{stats} }) {
87                 $versions{$browser} = [ sort { paddedver($a) cmp paddedver($b) } keys %$row ];
88         }
89 }
90
91 print <<'';
92 <p id="intro">Alternate rendition of Fyrd's <a href="http://caniuse.com/">when can I use...</a> page
93
94 my ($canihas, $usage);
95 my $minusage = $get{threshold} // .7;
96 given ($get{usage} // 'wm') {
97         when (!$_) {
98                 # none
99         }
100         when (!m{ \A [a-z]\w+ (?:/\d[\d-]*\d)? \z }x) {
101                 printf "<p>Invalid browser usage data request: <em>%s</em>",
102                         'identifier must be alphanumeric name or <q>0</q>';
103         }
104         $canihas = do "data/browser/usage-$_.inc.pl" or do {
105                 printf "<p>Browser usage data not found: <em>%s</em>", $@ || $!;
106                 break;
107         };
108         $usage = $_;
109         my $ref = $canihas->{-title} || 'unknown';
110         $ref = sprintf '<a href="%s">%s</a>', $_, $ref
111                 for $canihas->{-site} || $canihas->{-source} || ();
112         $ref .= " $_" for $canihas->{-date} || ();
113         print "\nwith $ref browser usage statistics";
114 }
115
116 my @browsers;
117 if ($usage) { # first() does not work inside given >:(
118         # adapt version usage to actual support data
119         my %engineuse;  # prefix => usage sum
120         for my $browser (keys %versions) {
121                 my $row = $canihas->{$browser} // {};
122                 my $verlist = $versions{$browser} or next;
123                 if ($minusage and sum(values %$row) < $minusage) {
124                         delete $versions{$browser};
125                         next;
126                 }
127                 my %supported = map { $_ => 1 } @$verlist;
128
129                 # cascade unknown versions
130                 $row->{$_} //= undef for @$verlist;  # ensure stable keys during iteration
131                 while (my ($version, $usage) = each %$row) {
132                         next if defined $supported{$version};
133                         my $next = first { paddedver($_) ge paddedver($version) } @$verlist
134                                 or warn("No fallback found for $browser v$version; $usage% ignored"), next;
135                         $row->{$next} += $usage;
136                         $row->{$version} = 0;  # balance browser total
137                 }
138
139                 # build row list for each version
140                 if ($minusage) {
141                         my @vershown;  # $verlist replacement
142                         my ($rowusage, @verrow) = (0);  # replacement row tracking
143                         for (@$verlist) {
144                                 push @verrow, $_;  # queue each version
145                                 if (($rowusage += $row->{$_}) >= $minusage) {
146                                         push @vershown, [@verrow];   # add row
147                                         ($rowusage, @verrow) = (0);  # reset row tracking
148                                 }
149                         }
150                         push @vershown, \@verrow if @verrow;  # always add latest
151                         @$verlist = @vershown;
152                 }
153                 else {
154                         @$verlist = map { [$_] } @$verlist;
155                 }
156
157                 # reusable aggregates (grouped by prefix (engine) and browser)
158                 $engineuse{ $caniuse->{agents}->{$browser}->{prefix} } +=
159                 $row->{-total} = sum(values %$row);
160         }
161
162         # order browser columns by usage grouped by engine
163         @browsers = sort {
164                 $engineuse{ $caniuse->{agents}->{$b}->{prefix} } <=>
165                 $engineuse{ $caniuse->{agents}->{$a}->{prefix} }
166                         ||
167                 $canihas->{$b}->{-total} <=> $canihas->{$a}->{-total}
168         } keys %versions;
169 }
170 else {
171         # order browser columns by name grouped by engine
172         @{$_} = map { [$_] } @{$_} for values %versions;
173         @browsers = sort {
174                 $caniuse->{agents}->{$b}->{prefix} cmp
175                 $caniuse->{agents}->{$a}->{prefix}
176                         ||
177                 $a cmp $b
178         } keys %versions;
179 }
180 :>.
181 </p>
182
183 <:
184 $canihas ||= {
185         map {
186                 $_ => +{
187                         map {
188                                 my $zero = $#$_ - 2;  # baseline index
189                                 ($_->[$zero - 2] =>  .5), # past
190                                 ($_->[$zero - 1] => 10 ), # previous
191                                 ($_->[$zero + 2] =>  0 ), # future
192                                 ($_->[$zero + 1] =>  .5), # next
193                                 ($_->[$zero    ] => 30 ), # current
194                         } $caniuse->{agents}->{$_}->{versions}
195                 }
196         } @browsers
197 }; # fallback hash based on release semantics
198 my $usagemax = (max(map { ref $_ eq 'HASH' && sum(values %$_) } values %$canihas) // 1) / 100;
199
200 my $usagepct = 1;  # score multiplier for 0..100 result
201 # normalise usage percentage to only include shown browsers
202 $usagepct = 100.01 / featurescore({  # yes for every possible version
203         map { $_ => { map {$_ => 'y'} map { @{$_} } @{$versions{$_}} } } keys %versions
204 });
205
206 print '<table class="mapped">';
207 print '<col span="3">';  # should match first thead row
208 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
209 say '</colgroup><col>';
210
211 my $header = join('',
212         '<tr>',
213         '<th colspan="3" rowspan="2">feature',
214         (map {
215                 my $name = $caniuse->{agents}->{$_}->{browser};
216                 sprintf('<th colspan="%d" class="%s" title="%s">%s',
217                         scalar @{ $versions{$_} },
218                         join(' ', map {"b-a-$_"} grep {$_}
219                                 $_, @{ $caniuse->{agents}->{$_} }{'prefix', 'type'},
220                         ),
221                         join(' ',
222                                 sprintf('%.1f%%', $canihas->{$_}->{-total} * $usagepct),
223                                 $name,
224                         ),
225                         do {
226                                 length $name <= (3 * @{ $versions{$_} }) ? $name
227                                         : $caniuse->{agents}->{$_}->{abbr};
228                         },
229                 )
230         } @browsers),
231         '<th rowspan="2">%',
232 );
233 print '<thead>', $header;
234 # preceding row without any colspan to work around gecko bug
235 print "\n<tr>";
236 for my $browser (@browsers) {
237         for (@{ $versions{$browser} }) {
238                 my $lastver = $_->[-1];
239                 my $release = $caniuse->{agents}->{$browser}->{verrelease}->{$lastver};
240                 my $future = defined $release;
241                 printf('<td title="%s"%s>%s',
242                         join(' ',
243                                 sprintf('%.1f%%', sum(@{ $canihas->{$browser} }{@$_}) * $usagepct),
244                                 $future ? 'development' : (),
245                                 'version ' . join(', ', @{$_}),
246                         ),
247                         $future && ' class="ex"',
248                         showversions($lastver),
249                 );
250         }
251 }
252 say '</thead>';
253 say '<tfoot>', $header;
254 {
255         # prefix indicates browser family; count adjacent families
256         my (@families, %familycount);
257         for my $browser (@browsers) {
258                 my $family = $caniuse->{agents}->{$browser}->{prefix};
259                 push @families, $family unless $familycount{$family};
260                 $familycount{$family} += @{ $versions{$browser} };
261         }
262
263         print "\n", '<tr class="cat">';
264         printf '<th colspan="%d">%s', $familycount{$_}, $_ for @families;
265 }
266 say '</tfoot>';
267
268 sub featurescore {
269         # relative amount of support for given feature
270         my $rank = 0;
271         if (my $row = shift) {
272                 if ($canihas) {
273                         while (my ($browser, $versions) = each %$row) {
274                                 ref $versions eq 'HASH' or next;
275                                 while (my ($version, $status) = each %$versions) {
276                                         $status =~ s/\h\#\d+//g;
277                                         $rank += ($canihas->{$browser}->{$version} || .001) * $PSTATS{$status};
278                                 }
279                         }
280                         return $rank;
281                 }
282
283                 while (my ($browser, $vercols) = each %versions) {
284                         my $div = 0;  # multiplier exponent (decreased to lower value)
285                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
286                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
287                                 my @future;  # find upcoming releases (after current)
288                                 for (reverse @$vercols) {
289                                         last if $_ eq $current;
290                                         push @future, pop @vers;
291                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
292                                 }
293                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
294                         }
295                         $rank += $PSTATS{$_} * 2**($div--) for reverse @vers;
296                 }
297         }
298         return $rank;
299 }
300
301 sub formatnotes {
302         my @html = @_;
303         for (@html) {
304                 s/\r\n?/\n/g;  # windows returns
305                 s/\h* $//gmx;  # trailing whitespace
306                 s/(?<= [^.\n]) $/./gmx;  # consistently end each line by a period
307                 Entity($_);
308                 s{  ` ([^`]*)  ` }{<code>$1</code>}gx;
309                 s{ \[ ([^]]*) \] \( ([^)]*) \) }{<a href="$2">$1</a>}gx;
310         }
311         return @html;
312 }
313
314 sub saytitlecol {
315         my ($id) = @_;
316         my $row = $caniuse->{data}->{$id};
317
318         for ($row->{categories}) {
319                 my $cell = $_ ? lc $_->[0] : '-';
320                 $cell =~ s/ api$//;  # trim unessential fluff in 'js api'
321                 printf '<th title="%s">%s', join(' + ', @$_), $cell;
322         }
323
324         print '<td>', map {
325                 sprintf('<a href="%s" onclick="%s">%s</a>',
326                         "#$id",
327                         sprintf("try { %s; return false } catch(err) { return true }",
328                                 "document.getElementById('$id').classList.toggle('target')",
329                         ),
330                         Entity($_),
331                 );
332         } $row->{title};
333         print '<div class=aside>';
334         print "<p>$_</p>"
335                 for formatnotes($row->{description}, $row->{notes} || ());
336         if (my %notes = %{ $row->{notes_by_num} }) {
337                 say '<p>Browser-specific notes:';
338                 say "<br>#$_: ", formatnotes($notes{$_}) for sort keys %notes;
339                 say '</p>';
340         }
341         printf 'Resources: %s.', join(', ', map {
342                 sprintf '<a href="%s">%s</a>', EscapeHTML($_->{url}), EscapeHTML($_->{title})
343         } @$_) for grep { @$_ } $row->{links} // ();
344         printf '<br>Parent feature: %s.', join(', ', map {
345                 sprintf '<a href="%s">%s</a>', EscapeHTML("#$_"), $caniuse->{data}->{$_}->{title}
346         } $_) for $row->{parent} || ();
347         print '</div>';
348 }
349
350 sub saystatuscol {
351         my ($id) = @_;
352         my $row = $caniuse->{data}->{$id};
353
354         for ($row->{status}) {
355                 my $cell = $_ // '-';
356                 $cell = sprintf '<a href="%s">%s</a>', $_, $cell for $row->{spec} // ();
357                 printf '<td title="%s" class="l %s">%s',
358                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
359         }
360 }
361
362 sub saybrowsercols {
363         my ($id, $browser) = @_;
364         my $feature = $caniuse->{data}->{$id};
365         my $data = $feature->{stats}->{$browser};
366         if (ref $data eq 'ARRAY') {
367                 # special case for unsupported
368                 my $release = $caniuse->{agents}->{$browser}->{verrelease};
369                 $data = {
370                         map { $_ => defined $release->{$_} ? 'u' : 'n' } keys %$release
371                 };
372         }
373
374         my ($prev, @span);
375         for my $ver (@{ $versions{$browser} }, undef) {
376                 my $compare = (
377                         !defined $ver ? undef :      # last column if nameless
378                         ref $data ne 'HASH' ? '' :   # unclassified if no support hash
379                         $data->{ $ver->[-1] } // $prev  # known or inherit from predecessor
380                         // (grep { defined } @{$data}{ map { $_->[0] } @{ $versions{$browser} } })[0]
381                            ~~ 'n' && 'n'             # first known version is unsupported
382                         || 'u'                       # unsure
383                 );
384                 unless (!defined $prev or $prev ~~ $compare) {
385                         my $usage = sum(@{ $canihas->{$browser} }{ map { @{$_} } @span });
386
387                         # strip #\d note references from support class
388                         my @notes;
389                         push @notes, $feature->{notes_by_num}->{$1}
390                                 while $prev =~ s/\h \# (\d+) \b//x;
391
392                         # prepare version hover details
393                         my $title = sprintf('%.1f%% %s', $usage * $usagepct, join(', ',
394                                 map { ref $_ eq 'CODE' ? $_->($browser, $span[0]->[0]) : $_ }
395                                 map { $DSTATS{$_} // () }
396                                 map { split / /, $_ }
397                                 $prev
398                         ));
399                         $title .= "\n".EscapeHTML($_) for @notes;
400
401                         printf('<td class="%s" colspan="%d" title="%s">%s',
402                                 join(' ',
403                                         X => $CSTATS{$prev},
404                                         !$usage ? ('p0') : ('p',
405                                                 sprintf('p%01d', $usage * ($usagepct - .0001) / 10),
406                                                 sprintf('p%02d', $usage * ($usagepct - .0001)),
407                                         ),
408                                         sprintf('pp%02d', $usage / $usagemax),
409                                 ),
410                                 scalar @span,
411                                 $title,
412                                 showversions($span[0]->[0], @span > 1 ? ($span[-1]->[-1]) : ()),
413                         );
414                         undef $prev;
415                         @span = ();
416                 }
417                 push @span, $ver && [ grep { $data->{ $_ } eq $data->{ $ver->[-1] } } @{$ver} ];
418                 $prev = $compare;
419         }
420 }
421
422 sub sayusagecol {
423         my ($id) = @_;
424         print '<td>', int featurescore($caniuse->{data}->{$id}->{stats}) * $usagepct;
425 }
426
427 say '<tbody>';
428 for my $id (sort {
429             featurescore($caniuse->{data}->{$b}->{stats})
430         <=> featurescore($caniuse->{data}->{$a}->{stats})
431 } keys %{ $caniuse->{data} }) {
432         $caniuse->{data}->{$id}->{stats} or next;  # skip metadata [summary]
433         printf '<tr id="%s">', $id;
434         saytitlecol($id);
435         saystatuscol($id);
436         saybrowsercols($id, $_) for @browsers;
437         sayusagecol($id);
438         say '</tr>';
439 }
440 say '</tbody>';
441 say '</table>';
442
443 sub paddedver {
444         # normalised version number comparable as string (cmp)
445         shift =~ /(?:.*-|^)(\d*)(.*)/;
446         # matched (major)(.minor) of last value in range (a-B)
447         return sprintf('%02d', $1 || 99) . $2;
448 }
449
450 sub showversions {
451         my @span = ($_[0], @_>1 ? $_[-1] : ());
452         s/-.*// for $span[0];
453         for (@span) {
454                 s/^\./0./;
455                 s/x$/.*/;
456                 s/.*-//;
457         }
458         return join('‒', @span);
459 }
460
461 :>
462 <hr>
463
464 <div class="legend">
465         <table class="glyphs"><tr>
466         <td class="X l5">supported
467         <td class="X l3">partial
468         <td class="X l2">optional
469         <td class="X l1">missing
470         <td class="X l0">unknown
471         <td class="X ex">prefixed
472         </table>
473
474         <p><: if ($usage) { :>
475                 Usage percentage:
476                 <span class="  p0">0</span> -
477                 <span class="p p0 p00">.01</span> -
478                 <span class="p p0 p05">1-9</span> -
479                 <span class="p p1">10</span> -
480                 <span class="p p2">20</span> -
481                 <span class="p p5">majority</span>
482 <: } else { :>
483                 <table class="glyphs"><tr>
484                         <td class="p p1">previous version</td>
485                         <td class="p p3">current</td>
486                         <td class="p p0 p00">upcoming (within months)</td>
487                         <td class="  p0">future (within a year)</td>
488                 </table>
489 <: } :> </p>
490
491         <div class="right">
492                 <ul class="legend legend-set">
493                 <li>default <strong>style</strong> is
494                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
495                 <li><strong>usage</strong> source is
496                         <:= !defined $get{usage} && 'default ' :><:= defined $usage ? "<em>$usage</em>" : 'not included (<em>0</em>)' :>
497                 <li>usage <strong>threshold</strong> is
498                         <:= defined $get{threshold} && 'changed to ' :><em><:= $minusage :>%</em>
499                 </ul>
500         </div>
501 </div>
502
503 <script type="text/javascript" src="/searchlocal.js"></script>
504 <script type="text/javascript"> prependsearch(document.getElementById('intro')) </script>
505