browser.plp

   1 <(common.inc.plp)><:
   2 use 5.010;
   3 use List::Util qw(sum max);
   4
   5 Html({
   6         title => 'browser compatibility cheat sheet',
   7         version => 'v1.0',
   8         description =>
   9                 "caniuse.",
  10         keywords => [qw'html css browser feature'],
  11         stylesheet => [qw'light dark circus mono red'],
  12         data => ['caniuse.js'],
  13 });
  14
  15 :>
  16 <h1>Browser compatibility</h1>
  17
  18 <p>Alternate view of Fyrd's <a href="http://caniuse.com/">when can I use...</a> page
  19 with <a href="http://stats.wikimedia.org/archive/squid_reports/">Wikimedia</a>
  20 browser usage statistics.</p>
  21
  22 <:
  23 use JSON;
  24 use File::Slurp 'read_file';
  25 my $source = read_file('caniuse.js');
  26 for ($source) { # cleanup
  27         # convert seperate variables to hash keys
  28         s/\A/{/;
  29         s/^caniuse\.(\w+) = /"$1":/gm;
  30         s/;$/,/gm;
  31         s/,\s*\Z/\n}/;
  32         # fractions not supported by barekey
  33         s/(?<=[,{]) (\d*\.\d) (?=:')/"$1"/gx;
  34         # escapes not supported in singlequote
  35         s{'((?:[^\\']+|\\.)*)'}{
  36                 my $_ = $1;
  37                 s/"/\\"/g;
  38                 s/\\'/'/g;
  39                 qq("$_");
  40         }ge;
  41 }
  42 my $caniuse = from_json($source, {
  43 #       allow_singlequote => 1,
  44         allow_barekey => 1,
  45 });
  46
  47 my %CSTATS = (
  48         n => 'di-b',
  49         y => 'di-aa',
  50         a     => 'di-d',
  51         'a x' => 'di-d',
  52         j     => 'di-prop',
  53         p     => 'di-prop',
  54         'p j' => 'di-prop',
  55         'y x' => 'di-a',
  56 );
  57 my %CSTATUS = (
  58         unoff => 'di-rare', # unofficial
  59         wd    => 'di-b', # draft
  60         pr    => 'di-prop', # proposed
  61         cr    => 'di-d', # candidate
  62         rec   => 'di-a', # recommendation
  63         ietf  => 'di-aa', # standard
  64 );
  65 my @browsers = qw(trident gecko webkit_saf webkit_chr presto);
  66 my %versions;
  67 if (my ($somerow) = values %{ $caniuse->{data} }) {
  68         while (my ($browser, $row) = each %{ $somerow->{stats} }) {
  69                 $versions{$browser} = [ sort { paddedver($a) cmp paddedver($b) } keys %$row ];
  70         }
  71 }
  72
  73 my $canihas = do 'browser-usage.inc.pl' or do {
  74         printf "<p>Browser usage data not found: <em>%s</em>.</p>\n", $_
  75                 for $! || $@;
  76 };
  77 my $scorediv = (max(map { sum(values %$_) } values %$canihas) // 1) / 100;
  78
  79 print '<table class="mapped">';
  80 print '<col>' x 3;
  81 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
  82 print "\n";
  83
  84 print '<thead><tr>';
  85 print '<th colspan="3">feature';
  86 printf '<th colspan="%d">%s',
  87         scalar @{ $versions{$_} }, $caniuse->{agents}->{$_}->{browser}
  88                 for @browsers;
  89 # preceding row without any colspan to work around gecko bug
  90 print '<tr>';
  91 print '<td>' x $_ for 3, (map { scalar @{ $versions{$_} } } @browsers), 1;
  92 print "</thead>\n";
  93
  94 sub featurescore {
  95         # relative amount of support for given feature
  96         state $statspts = { y=>10, 'y x'=>9, a=>5, 'a x'=>5, j=>2, 'p j'=>2, p=>1 };
  97         my $rank = 0;
  98         if (my $row = shift) {
  99                 while (my ($browser, $vercols) = each %versions) {
 100                         my $div = 0;  # multiplier exponent (decreased to lower value)
 101                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 102                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 103                                 my @future;  # find upcoming releases (after current)
 104                                 for (reverse @$vercols) {
 105                                         last if $_ eq $current;
 106                                         push @future, pop @vers;
 107                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 108                                 }
 109                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 110                         }
 111                         $rank += $statspts->{$_} * 2**($div--) for reverse @vers;
 112                 }
 113         }
 114         return $rank;
 115 }
 116
 117 for my $id (sort {
 118             featurescore($caniuse->{data}->{$b}->{stats})
 119         <=> featurescore($caniuse->{data}->{$a}->{stats})
 120 } keys %{ $caniuse->{data} }) {
 121         my $row = $caniuse->{data}->{$id};
 122         my $data = $row->{stats} or next;  # skip metadata [summary]
 123         printf '<tr id="%s">', $id;
 124         for ($row->{categories}) {
 125                 my $cell = $_ ? lc $_->[0] : '-';
 126                 print '<th>', $cell;
 127         }
 128         printf '<td title="%s">%s', $row->{description}, $row->{title};
 129         for ($row->{status}) {
 130                 my $cell = $_ // '-';
 131                 $cell = sprintf '<a href="%s">%s</a>', $_, $cell for $row->{spec} // ();
 132                 printf '<td title="%s" class="%s">%s',
 133                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 134         }
 135         for my $browser (@browsers) {
 136                 my ($prev, @span);
 137                 for my $ver (@{ $versions{$browser} }, undef) {
 138                         unless (!defined $prev
 139                         or $data->{$browser}->{$prev} ~~ $data->{$browser}->{$ver}) {
 140                                 my $usage = sum(map { $canihas->{$browser}->{$_} } @span);
 141                                 printf '<td class="%s" colspan="%d" title="%.1f%%">%s',
 142                                         join(' ',
 143                                                 $CSTATS{ $data->{$browser}->{$prev} },
 144                                                 sprintf('opacity%.0f', $usage / $scorediv),
 145                                         ),
 146                                         scalar @span,
 147                                         $usage,
 148                                         showversions(\@span),
 149                                 undef $prev;
 150                                 @span = ();
 151                         }
 152                         push @span, $ver;
 153                         $prev = $ver;
 154                 }
 155         }
 156         state $maxscore = featurescore({  # yes for every possible version
 157                 map { $_ => { map {$_ => 'y'} @{$versions{$_}} } } keys %versions
 158         });
 159         print '<td>', int featurescore($caniuse->{data}->{$id}->{stats}) / $maxscore * 100;
 160 }
 161 print '</table>';
 162
 163 sub paddedver {
 164         # normalised version number comparable as string (cmp)
 165         shift =~ /^(\d*)(.*)/;
 166         return sprintf('%02d', $1) . $2;
 167 }
 168
 169 sub showversions {
 170         my ($span) = @_;
 171         splice @$span, 1, -1;
 172         for (@$span) {
 173                 s/^\./0./;
 174                 s/x$/.*/;
 175         }
 176         return join('‒', @$span);
 177 }
 178
 179 :>
 180 <hr>
 181
 182 <div class="legend">
 183         <table class="glyphs"><tr>
 184         <td class="X di-aa">supported
 185         <td class="X di-a">prefixed
 186         <td class="X di-d">partial
 187         <td class="X di-prop">external (js/plugin)
 188         <td class="X di-b">missing
 189         </table>
 190
 191         <div class="right">
 192                 <ul class="legend legend-set">
 193                 <li>default <strong>style</strong> is
 194                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 195                 </ul>
 196         </div>
 197 </div>
 198